1/* SPDX-License-Identifier: GPL-2.0+ */
2/*
3 * Copyright (c) 2014 Xilinx, Inc. Michal Simek
4 * Copyright (c) 2004-2008 Texas Instruments
5 *
6 * (C) Copyright 2002
7 * Gary Jennejohn, DENX Software Engineering, <garyj@denx.de>
8 */
9
10MEMORY { .sram : ORIGIN = IMAGE_TEXT_BASE,\
11		LENGTH = IMAGE_MAX_SIZE }
12MEMORY { .sdram : ORIGIN = CONFIG_SPL_BSS_START_ADDR, \
13		LENGTH = CONFIG_SPL_BSS_MAX_SIZE }
14
15OUTPUT_FORMAT("elf32-littlearm", "elf32-littlearm", "elf32-littlearm")
16OUTPUT_ARCH(arm)
17ENTRY(_start)
18SECTIONS
19{
20	. = ALIGN(4);
21	__image_copy_start = ADDR(.text);
22	.text :
23	{
24		*(.vectors)
25		CPUDIR/start.o (.text*)
26		*(.text*)
27	} > .sram
28
29	. = ALIGN(4);
30	.rodata : {
31		*(SORT_BY_ALIGNMENT(SORT_BY_NAME(.rodata*)))
32	} > .sram
33
34	. = ALIGN(4);
35	.data : {
36		*(.data*)
37	} > .sram
38
39	. = ALIGN(4);
40	__u_boot_list : {
41		KEEP(*(SORT(__u_boot_list*)));
42	} > .sram
43
44	. = ALIGN(4);
45
46	_image_binary_end = .;
47
48	_end = .;
49
50	/* Move BSS section to RAM because of FAT */
51	.bss (NOLOAD) : {
52		__bss_start = .;
53		*(.bss*)
54		 . = ALIGN(4);
55		__bss_end = .;
56	} > .sdram
57
58	/DISCARD/ : { *(.dynsym) }
59	/DISCARD/ : { *(.dynstr*) }
60	/DISCARD/ : { *(.dynamic*) }
61	/DISCARD/ : { *(.plt*) }
62	/DISCARD/ : { *(.interp*) }
63	/DISCARD/ : { *(.gnu*) }
64}
65