1#	$OpenBSD: Server.pm,v 1.14 2021/12/22 15:14:13 bluhm Exp $
2
3# Copyright (c) 2010-2021 Alexander Bluhm <bluhm@openbsd.org>
4#
5# Permission to use, copy, modify, and distribute this software for any
6# purpose with or without fee is hereby granted, provided that the above
7# copyright notice and this permission notice appear in all copies.
8#
9# THE SOFTWARE IS PROVIDED "AS IS" AND THE AUTHOR DISCLAIMS ALL WARRANTIES
10# WITH REGARD TO THIS SOFTWARE INCLUDING ALL IMPLIED WARRANTIES OF
11# MERCHANTABILITY AND FITNESS. IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR
12# ANY SPECIAL, DIRECT, INDIRECT, OR CONSEQUENTIAL DAMAGES OR ANY DAMAGES
13# WHATSOEVER RESULTING FROM LOSS OF USE, DATA OR PROFITS, WHETHER IN AN
14# ACTION OF CONTRACT, NEGLIGENCE OR OTHER TORTIOUS ACTION, ARISING OUT OF
15# OR IN CONNECTION WITH THE USE OR PERFORMANCE OF THIS SOFTWARE.
16
17use strict;
18use warnings;
19
20package Server;
21use parent 'Proc';
22use Carp;
23use Socket;
24use Socket6;
25use IO::Socket;
26use IO::Socket::SSL;
27
28sub new {
29	my $class = shift;
30	my %args = @_;
31	$args{ktracepid} = "ktrace" if $args{ktrace};
32	$args{ktracepid} = $ENV{KTRACE} if $ENV{KTRACE};
33	$args{ktracefile} ||= "server.ktrace";
34	$args{logfile} ||= "server.log";
35	$args{up} ||= "Accepted";
36	my $self = Proc::new($class, %args);
37	$self->{listenproto} ||= "udp";
38	defined($self->{listendomain})
39	    or croak "$class listen domain not given";
40	return $self->listen();
41}
42
43sub listen {
44	my $self = shift;
45	$SSL_ERROR = "";
46	my $iosocket = $self->{listenproto} eq "tls" ?
47	    "IO::Socket::SSL" : "IO::Socket::IP";
48	my $proto = $self->{listenproto};
49	$proto = "tcp" if $proto eq "tls";
50	my $ls = $iosocket->new(
51	    Proto		=> $proto,
52	    ReuseAddr		=> 1,
53	    Domain		=> $self->{listendomain},
54	    $self->{listenaddr}	? (LocalAddr => $self->{listenaddr}) : (),
55	    $self->{listenport}	? (LocalPort => $self->{listenport}) : (),
56	    SSL_server          => 1,
57	    SSL_key_file	=> "server.key",
58	    SSL_cert_file	=> "server.crt",
59	    SSL_ca_file		=> ($self->{sslca} || "ca.crt"),
60	    SSL_verify_mode     => ($self->{sslca} ?
61		SSL_VERIFY_PEER : SSL_VERIFY_NONE),
62	    $self->{sslca}	? (SSL_verifycn_scheme => "none") : (),
63	    $self->{sslversion}	? (SSL_version => $self->{sslversion}) : (),
64	    $self->{sslciphers}	? (SSL_cipher_list => $self->{sslciphers}) : (),
65	) or die ref($self), " $iosocket socket failed: $!,$SSL_ERROR";
66	if ($self->{sndbuf}) {
67		setsockopt($ls, SOL_SOCKET, SO_SNDBUF,
68		    pack('i', $self->{sndbuf}))
69		    or die ref($self), " set SO_SNDBUF failed: $!";
70	}
71	if ($self->{rcvbuf}) {
72		setsockopt($ls, SOL_SOCKET, SO_RCVBUF,
73		    pack('i', $self->{rcvbuf}))
74		    or die ref($self), " set SO_RCVBUF failed: $!";
75	}
76	if ($self->{listenproto} ne "udp") {
77		listen($ls, 1)
78		    or die ref($self), " socket listen failed: $!";
79	}
80	my $log = $self->{log};
81	print $log "listen sock: ",$ls->sockhost()," ",$ls->sockport(),"\n";
82	$self->{listenaddr} = $ls->sockhost() unless $self->{listenaddr};
83	$self->{listenport} = $ls->sockport() unless $self->{listenport};
84	$self->{ls} = $ls;
85	return $self;
86}
87
88sub close {
89	my $self = shift;
90	$self->{ls}->close()
91	    or die ref($self)," ",ref($self->{ls}),
92	    " socket close failed: $!,$SSL_ERROR";
93	delete $self->{ls};
94	return $self;
95}
96
97sub run {
98	my $self = shift;
99	Proc::run($self, @_);
100	return $self->close();
101}
102
103sub child {
104	my $self = shift;
105
106	# TLS 1.3 writes multiple messages without acknowledgement.
107	# If the other side closes early, we want broken pipe error.
108	$SIG{PIPE} = 'IGNORE' if $self->{listenproto} eq "tls";
109
110	my $as = $self->{ls};
111	if ($self->{listenproto} ne "udp") {
112		$as = $self->{ls}->accept()
113		    or die ref($self)," ",ref($self->{ls}),
114		    " socket accept failed: $!,$SSL_ERROR";
115		print STDERR "accept sock: ",$as->sockhost()," ",
116		    $as->sockport(),"\n";
117		print STDERR "accept peer: ",$as->peerhost()," ",
118		    $as->peerport(),"\n";
119	}
120	if ($self->{listenproto} eq "tls") {
121		print STDERR "ssl version: ",$as->get_sslversion(),"\n";
122		print STDERR "ssl cipher: ",$as->get_cipher(),"\n";
123		print STDERR "ssl subject: ", $as->peer_certificate("subject")
124		    ,"\n" if $self->{sslca};
125	}
126
127	*STDIN = *STDOUT = $self->{as} = $as;
128}
129
1301;
131