1# SPDX-License-Identifier: FSFAP
2#
3# ===========================================================================
4#   https://www.gnu.org/software/autoconf-archive/ax_prog_cc_for_build.html
5# ===========================================================================
6#
7# SYNOPSIS
8#
9#   AX_PROG_CC_FOR_BUILD
10#
11# DESCRIPTION
12#
13#   This macro searches for a C compiler that generates native executables,
14#   that is a C compiler that surely is not a cross-compiler. This can be
15#   useful if you have to generate source code at compile-time like for
16#   example GCC does.
17#
18#   The macro sets the CC_FOR_BUILD and CPP_FOR_BUILD macros to anything
19#   needed to compile or link (CC_FOR_BUILD) and preprocess (CPP_FOR_BUILD).
20#   The value of these variables can be overridden by the user by specifying
21#   a compiler with an environment variable (like you do for standard CC).
22#
23#   It also sets BUILD_EXEEXT and BUILD_OBJEXT to the executable and object
24#   file extensions for the build platform, and GCC_FOR_BUILD to `yes' if
25#   the compiler we found is GCC. All these variables but GCC_FOR_BUILD are
26#   substituted in the Makefile.
27#
28# LICENSE
29#
30#   Copyright (c) 2008 Paolo Bonzini <bonzini@gnu.org>
31#
32#   Copying and distribution of this file, with or without modification, are
33#   permitted in any medium without royalty provided the copyright notice
34#   and this notice are preserved. This file is offered as-is, without any
35#   warranty.
36
37#serial 20
38
39AU_ALIAS([AC_PROG_CC_FOR_BUILD], [AX_PROG_CC_FOR_BUILD])
40AC_DEFUN([AX_PROG_CC_FOR_BUILD], [dnl
41AC_REQUIRE([AC_PROG_CC])dnl
42AC_REQUIRE([AC_PROG_CPP])dnl
43AC_REQUIRE([AC_CANONICAL_BUILD])dnl
44
45dnl Use the standard macros, but make them use other variable names
46dnl
47pushdef([ac_cv_prog_CPP], ac_cv_build_prog_CPP)dnl
48pushdef([ac_cv_prog_cc_c89], ac_cv_build_prog_cc_c89)dnl
49pushdef([ac_cv_prog_cc_c99], ac_cv_build_prog_cc_c99)dnl
50pushdef([ac_cv_prog_cc_c11], ac_cv_build_prog_cc_c11)dnl
51pushdef([ac_cv_prog_gcc], ac_cv_build_prog_gcc)dnl
52pushdef([ac_cv_prog_cc_works], ac_cv_build_prog_cc_works)dnl
53pushdef([ac_cv_prog_cc_cross], ac_cv_build_prog_cc_cross)dnl
54pushdef([ac_cv_prog_cc_g], ac_cv_build_prog_cc_g)dnl
55pushdef([ac_cv_c_compiler_gnu], ac_cv_build_c_compiler_gnu)dnl
56pushdef([ac_cv_exeext], ac_cv_build_exeext)dnl
57pushdef([ac_cv_objext], ac_cv_build_objext)dnl
58pushdef([ac_exeext], ac_build_exeext)dnl
59pushdef([ac_objext], ac_build_objext)dnl
60pushdef([CC], CC_FOR_BUILD)dnl
61pushdef([CPP], CPP_FOR_BUILD)dnl
62pushdef([GCC], GCC_FOR_BUILD)dnl
63pushdef([CFLAGS], CFLAGS_FOR_BUILD)dnl
64pushdef([CPPFLAGS], CPPFLAGS_FOR_BUILD)dnl
65pushdef([EXEEXT], BUILD_EXEEXT)dnl
66pushdef([LDFLAGS], LDFLAGS_FOR_BUILD)dnl
67pushdef([OBJEXT], BUILD_OBJEXT)dnl
68pushdef([host], build)dnl
69pushdef([host_alias], build_alias)dnl
70pushdef([host_cpu], build_cpu)dnl
71pushdef([host_vendor], build_vendor)dnl
72pushdef([host_os], build_os)dnl
73pushdef([ac_cv_host], ac_cv_build)dnl
74pushdef([ac_cv_host_alias], ac_cv_build_alias)dnl
75pushdef([ac_cv_host_cpu], ac_cv_build_cpu)dnl
76pushdef([ac_cv_host_vendor], ac_cv_build_vendor)dnl
77pushdef([ac_cv_host_os], ac_cv_build_os)dnl
78pushdef([ac_tool_prefix], ac_build_tool_prefix)dnl
79pushdef([am_cv_CC_dependencies_compiler_type], am_cv_build_CC_dependencies_compiler_type)dnl
80pushdef([am_cv_prog_cc_c_o], am_cv_build_prog_cc_c_o)dnl
81pushdef([cross_compiling], cross_compiling_build)dnl
82
83cross_compiling_build=no
84
85ac_build_tool_prefix=
86AS_IF([test -n "$build"],      [ac_build_tool_prefix="$build-"],
87      [test -n "$build_alias"],[ac_build_tool_prefix="$build_alias-"])
88
89AC_LANG_PUSH([C])
90
91dnl The pushdef([ac_cv_c_compiler_gnu], ...) currently does not cover
92dnl the use of this variable in _AC_LANG_COMPILER_GNU called by
93dnl AC_PROG_CC. Unset this cache variable temporarily as a workaround.
94was_set_c_compiler_gnu=${[ac_cv_c_compiler_gnu]+y}
95AS_IF([test ${was_set_c_compiler_gnu}],
96    [saved_c_compiler_gnu=$[ac_cv_c_compiler_gnu]
97    AS_UNSET([[ac_cv_c_compiler_gnu]])])
98
99AC_PROG_CC
100
101dnl Restore ac_cv_c_compiler_gnu
102AS_IF([test ${was_set_c_compiler_gnu}],
103  [[ac_cv_c_compiler_gnu]=$[saved_c_compiler_gnu]])
104
105_AC_COMPILER_EXEEXT
106_AC_COMPILER_OBJEXT
107AC_PROG_CPP
108
109dnl Restore the old definitions
110dnl
111popdef([cross_compiling])dnl
112popdef([am_cv_prog_cc_c_o])dnl
113popdef([am_cv_CC_dependencies_compiler_type])dnl
114popdef([ac_tool_prefix])dnl
115popdef([ac_cv_host_os])dnl
116popdef([ac_cv_host_vendor])dnl
117popdef([ac_cv_host_cpu])dnl
118popdef([ac_cv_host_alias])dnl
119popdef([ac_cv_host])dnl
120popdef([host_os])dnl
121popdef([host_vendor])dnl
122popdef([host_cpu])dnl
123popdef([host_alias])dnl
124popdef([host])dnl
125popdef([OBJEXT])dnl
126popdef([LDFLAGS])dnl
127popdef([EXEEXT])dnl
128popdef([CPPFLAGS])dnl
129popdef([CFLAGS])dnl
130popdef([GCC])dnl
131popdef([CPP])dnl
132popdef([CC])dnl
133popdef([ac_objext])dnl
134popdef([ac_exeext])dnl
135popdef([ac_cv_objext])dnl
136popdef([ac_cv_exeext])dnl
137popdef([ac_cv_c_compiler_gnu])dnl
138popdef([ac_cv_prog_cc_g])dnl
139popdef([ac_cv_prog_cc_cross])dnl
140popdef([ac_cv_prog_cc_works])dnl
141popdef([ac_cv_prog_cc_c89])dnl
142popdef([ac_cv_prog_gcc])dnl
143popdef([ac_cv_prog_CPP])dnl
144
145dnl restore global variables ac_ext, ac_cpp, ac_compile,
146dnl ac_link, ac_compiler_gnu (dependant on the current
147dnl language after popping):
148AC_LANG_POP([C])
149
150dnl Finally, set Makefile variables
151dnl
152AC_SUBST(BUILD_EXEEXT)dnl
153AC_SUBST(BUILD_OBJEXT)dnl
154AC_SUBST([CFLAGS_FOR_BUILD])dnl
155AC_SUBST([CPPFLAGS_FOR_BUILD])dnl
156AC_SUBST([LDFLAGS_FOR_BUILD])dnl
157])
158