1#compdef fc-list fc-match
2
3local -a suf
4local font=${${PREFIX//-[0-9]##:/:}%:*}: ret=1
5local attr
6
7compset -S ':*' || suf=( -S: -r "-: \t\n\-" )
8if compset -P '*:'; then
9  attr="${PREFIX%\=*}"
10  if compset -P '*='; then
11    case $attr in
12      hintstyle)
13        _wanted value expl 'value' compadd "$suf[@]" \
14	    hint{none,slight,medium,full} && ret=0
15      ;;
16      *)
17        _wanted value expl 'value' compadd "$suf[@]" \
18            ${${(f)"$(_call_program font-attrs
19	    fc-list $font $attr 2>/dev/null)"//,/$'\n'}##*=} && ret=0
20      ;;
21    esac
22  else
23    _tags elements {weight,slant}-constants
24    while _tags; do
25      _requested elements expl element compadd -qS= hintstyle hinting autohint \
26          size ${${(u)${(M)${(f)"$(_call_program elements
27	  fc-list -v $font 2>/dev/null)"}:#	[a-z]*}%%:*}#?} && ret=0
28      _requested weight-constants expl 'weight constant' compadd "$suf[@]" \
29          thin bold regular medium semibold heavy roman && ret=0
30      _requested slant-constants expl 'slant constant' compadd "$suf[@]" \
31          roman italic oblique && ret=0
32
33      (( ret )) || break
34    done
35  fi
36elif compset -P '*[^\\]-'; then
37  _message -e size 'point size' && ret=0
38else
39  _wanted fonts expl font compadd "$suf[@]" \
40      ${(us:,:)$(_call_program fonts fc-list -f '%\{family\},' 2>/dev/null)} && ret=0
41fi
42
43return ret
44