1NAME
2 Variable::Magic - Associate user-defined magic to variables from Perl.
3
4VERSION
5 Version 0.43
6
7SYNOPSIS
8 use Variable::Magic qw/wizard cast VMG_OP_INFO_NAME/;
9
10 { # A variable tracer
11 my $wiz = wizard set => sub { print "now set to ${$_[0]}!\n" },
12 free => sub { print "destroyed!\n" };
13
14 my $a = 1;
15 cast $a, $wiz;
16 $a = 2; # "now set to 2!"
17 } # "destroyed!"
18
19 { # A hash with a default value
20 my $wiz = wizard data => sub { $_[1] },
21 fetch => sub { $_[2] = $_[1] unless exists $_[0]->{$_[2]}; () },
22 store => sub { print "key $_[2] stored in $_[-1]\n" },
23 copy_key => 1,
24 op_info => VMG_OP_INFO_NAME;
25
26 my %h = (_default => 0, apple => 2);
27 cast %h, $wiz, '_default';
28 print $h{banana}, "\n"; # "0", because the 'banana' key doesn't exist in %h
29 $h{pear} = 1; # "key pear stored in helem"
30 }
31
32DESCRIPTION
33 Magic is Perl's way of enhancing variables. This mechanism lets the user
34 add extra data to any variable and hook syntactical operations (such as
35 access, assignment or destruction) that can be applied to it. With this
36 module, you can add your own magic to any variable without having to
37 write a single line of XS.
38
39 You'll realize that these magic variables look a lot like tied
40 variables. It's not surprising, as tied variables are implemented as a
41 special kind of magic, just like any 'irregular' Perl variable : scalars
42 like $!, $( or $^W, the %ENV and %SIG hashes, the @ISA array, "vec()"
43 and "substr()" lvalues, threads::shared variables... They all share the
44 same underlying C API, and this module gives you direct access to it.
45
46 Still, the magic made available by this module differs from tieing and
47 overloading in several ways :
48
49 * It isn't copied on assignment.
50
51 You attach it to variables, not values (as for blessed references).
52
53 * It doesn't replace the original semantics.
54
55 Magic callbacks usually get triggered before the original action
56 takes place, and can't prevent it from happening. This also makes
57 catching individual events easier than with "tie", where you have to
58 provide fallbacks methods for all actions by usually inheriting from
59 the correct "Tie::Std*" class and overriding individual methods in
60 your own class.
61
62 * It's type-agnostic.
63
64 The same magic can be applied on scalars, arrays, hashes, subs or
65 globs. But the same hook (see below for a list) may trigger
66 differently depending on the the type of the variable.
67
68 * It's mostly invisible at the Perl level.
69
70 Magical and non-magical variables cannot be distinguished with
71 "ref", "tied" or another trick.
72
73 * It's notably faster.
74
75 Mainly because perl's way of handling magic is lighter by nature,
76 and because there's no need for any method resolution. Also, since
77 you don't have to reimplement all the variable semantics, you only
78 pay for what you actually use.
79
80 The operations that can be overloaded are :
81
82 * "get"
83
84 This magic is invoked when the variable is evaluated. It is never
85 called for arrays and hashes.
86
87 * "set"
88
89 This one is triggered each time the value of the variable changes.
90 It is called for array subscripts and slices, but never for hashes.
91
92 * "len"
93
94 This magic is a little special : it is called when the 'size' or the
95 'length' of the variable has to be known by Perl. Typically, it's
96 the magic involved when an array is evaluated in scalar context, but
97 also on array assignment and loops ("for", "map" or "grep"). The
98 callback has then to return the length as an integer.
99
100 * "clear"
101
102 This magic is invoked when the variable is reset, such as when an
103 array is emptied. Please note that this is different from undefining
104 the variable, even though the magic is called when the clearing is a
105 result of the undefine (e.g. for an array, but actually a bug
106 prevent it to work before perl 5.9.5 - see the history).
107
108 * "free"
109
110 This one can be considered as an object destructor. It happens when
111 the variable goes out of scope, but not when it is undefined.
112
113 * "copy"
114
115 This magic only applies to tied arrays and hashes. It fires when you
116 try to access or change their elements. It is available on your perl
117 iff "MGf_COPY" is true.
118
119 * "dup"
120
121 Invoked when the variable is cloned across threads. Currently not
122 available.
123
124 * "local"
125
126 When this magic is set on a variable, all subsequent localizations
127 of the variable will trigger the callback. It is available on your
128 perl iff "MGf_LOCAL" is true.
129
130 The following actions only apply to hashes and are available iff
131 "VMG_UVAR" is true. They are referred to as "uvar" magics.
132
133 * "fetch"
134
135 This magic happens each time an element is fetched from the hash.
136
137 * "store"
138
139 This one is called when an element is stored into the hash.
140
141 * "exists"
142
143 This magic fires when a key is tested for existence in the hash.
144
145 * "delete"
146
147 This last one triggers when a key is deleted in the hash, regardless
148 of whether the key actually exists in it.
149
150 You can refer to the tests to have more insight of where the different
151 magics are invoked.
152
153 To prevent any clash between different magics defined with this module,
154 an unique numerical signature is attached to each kind of magic (i.e.
155 each set of callbacks for magic operations). At the C level, magic
156 tokens owned by magic created by this module have their "mg->mg_private"
157 field set to 0x3891 or 0x3892, so please don't use these magic (sic)
158 numbers in other extensions.
159
160FUNCTIONS
161 "wizard"
162 wizard data => sub { ... },
163 get => sub { my ($ref, $data [, $op]) = @_; ... },
164 set => sub { my ($ref, $data [, $op]) = @_; ... },
165 len => sub { my ($ref, $data, $len [, $op]) = @_; ... ; return $newlen; },
166 clear => sub { my ($ref, $data [, $op]) = @_; ... },
167 free => sub { my ($ref, $data [, $op]) = @_, ... },
168 copy => sub { my ($ref, $data, $key, $elt [, $op]) = @_; ... },
169 local => sub { my ($ref, $data [, $op]) = @_; ... },
170 fetch => sub { my ($ref, $data, $key [, $op]) = @_; ... },
171 store => sub { my ($ref, $data, $key [, $op]) = @_; ... },
172 exists => sub { my ($ref, $data, $key [, $op]) = @_; ... },
173 delete => sub { my ($ref, $data, $key [, $op]) = @_; ... },
174 copy_key => $bool,
175 op_info => [ 0 | VMG_OP_INFO_NAME | VMG_OP_INFO_OBJECT ]
176
177 This function creates a 'wizard', an opaque type that holds the magic
178 information. It takes a list of keys / values as argument, whose keys
179 can be :
180
181 * "data"
182
183 A code (or string) reference to a private data constructor. It is
184 called each time this magic is cast on a variable, and the scalar
185 returned is used as private data storage for it. $_[0] is a
186 reference to the magic object and @_[1 .. @_-1] are all extra
187 arguments that were passed to "cast".
188
189 * "get", "set", "len", "clear", "free", "copy", "local", "fetch",
190 "store", "exists" and "delete"
191
192 Code (or string) references to the corresponding magic callbacks.
193 You don't have to specify all of them : the magic associated with
194 undefined entries simply won't be hooked. In those callbacks, $_[0]
195 is always a reference to the magic object and $_[1] is always the
196 private data (or "undef" when no private data constructor was
197 supplied).
198
199 Moreover, when you pass "op_info => $num" to "wizard", the last
200 element of @_ will be the current op name if "$num ==
201 VMG_OP_INFO_NAME" and a "B::OP" object representing the current op
202 if "$num == VMG_OP_INFO_OBJECT". Both have a performance hit, but
203 just getting the name is lighter than getting the op object.
204
205 Other arguments are specific to the magic hooked :
206
207 * "len"
208
209 When the variable is an array or a scalar, $_[2] contains
210 the non-magical length. The callback can return the new
211 scalar or array length to use, or "undef" to default to the
212 normal length.
213
214 * "copy"
215
216 $_[2] is a either a copy or an alias of the current key,
217 which means that it is useless to try to change or cast
218 magic on it. $_[3] is an alias to the current element (i.e.
219 the value).
220
221 * "fetch", "store", "exists" and "delete"
222
223 $_[2] is an alias to the current key. Nothing prevents you
224 from changing it, but be aware that there lurk dangerous
225 side effects. For example, it may rightfully be readonly if
226 the key was a bareword. You can get a copy instead by
227 passing "copy_key => 1" to "wizard", which allows you to
228 safely assign to $_[2] in order to e.g. redirect the action
229 to another key. This however has a little performance
230 drawback because of the copy.
231
232 All the callbacks are expected to return an integer, which is passed
233 straight to the perl magic API. However, only the return value of
234 the "len" callback currently holds a meaning.
235
236 Each callback can be specified as a code or a string reference, in which
237 case the function denoted by the string will be used as the callback.
238
239 Note that "free" callbacks are *never* called during global destruction,
240 as there's no way to ensure that the wizard and the "free" callback
241 weren't destroyed before the variable.
242
243 Here's a simple usage example :
244
245 # A simple scalar tracer
246 my $wiz = wizard get => sub { print STDERR "got ${$_[0]}\n" },
247 set => sub { print STDERR "set to ${$_[0]}\n" },
248 free => sub { print STDERR "${$_[0]} was deleted\n" }
249
250 "cast"
251 cast [$@%&*]var, $wiz, ...
252
253 This function associates $wiz magic to the variable supplied, without
254 overwriting any other kind of magic. It returns true on success or when
255 $wiz magic is already present, and croaks on error. All extra arguments
256 specified after $wiz are passed to the private data constructor in @_[1
257 .. @_-1]. If the variable isn't a hash, any "uvar" callback of the
258 wizard is safely ignored.
259
260 # Casts $wiz onto $x, and pass '1' to the data constructor.
261 my $x;
262 cast $x, $wiz, 1;
263
264 The "var" argument can be an array or hash value. Magic for those
265 behaves like for any other scalar, except that it is dispelled when the
266 entry is deleted from the container. For example, if you want to call
267 "POSIX::tzset" each time the 'TZ' environment variable is changed in
268 %ENV, you can use :
269
270 use POSIX;
271 cast $ENV{TZ}, wizard set => sub { POSIX::tzset(); () };
272
273 If you want to overcome the possible deletion of the 'TZ' entry, you
274 have no choice but to rely on "store" uvar magic.
275
276 "getdata"
277 getdata [$@%&*]var, $wiz
278
279 This accessor fetches the private data associated with the magic $wiz in
280 the variable. It croaks when $wiz do not represent a valid magic object,
281 and returns an empty list if no such magic is attached to the variable
282 or when the wizard has no data constructor.
283
284 # Get the attached data, or undef if the wizard does not attach any.
285 my $data = getdata $x, $wiz;
286
287 "dispell"
288 dispell [$@%&*]variable, $wiz
289
290 The exact opposite of "cast" : it dissociates $wiz magic from the
291 variable. This function returns true on success, 0 when no magic
292 represented by $wiz could be found in the variable, and croaks if the
293 supplied wizard is invalid.
294
295 # Dispell now.
296 die 'no such magic in $x' unless dispell $x, $wiz;
297
298CONSTANTS
299 "MGf_COPY"
300 Evaluates to true iff the 'copy' magic is available.
301
302 "MGf_DUP"
303 Evaluates to true iff the 'dup' magic is available.
304
305 "MGf_LOCAL"
306 Evaluates to true iff the 'local' magic is available.
307
308 "VMG_UVAR"
309 When this constant is true, you can use the "fetch,store,exists,delete"
310 callbacks on hashes.
311
312 "VMG_COMPAT_ARRAY_PUSH_NOLEN"
313 True for perls that don't call 'len' magic when you push an element in a
314 magical array. Starting from perl 5.11.0, this only refers to pushes in
315 non-void context and hence is false.
316
317 "VMG_COMPAT_ARRAY_PUSH_NOLEN_VOID"
318 True for perls that don't call 'len' magic when you push in void context
319 an element in a magical array.
320
321 "VMG_COMPAT_ARRAY_UNSHIFT_NOLEN_VOID"
322 True for perls that don't call 'len' magic when you unshift in void
323 context an element in a magical array.
324
325 "VMG_COMPAT_ARRAY_UNDEF_CLEAR"
326 True for perls that call 'clear' magic when undefining magical arrays.
327
328 "VMG_COMPAT_SCALAR_LENGTH_NOLEN"
329 True for perls that don't call 'len' magic when taking the "length" of a
330 magical scalar.
331
332 "VMG_COMPAT_GLOB_GET"
333 True for perls that call 'get' magic for operations on globs.
334
335 "VMG_PERL_PATCHLEVEL"
336 The perl patchlevel this module was built with, or 0 for non-debugging
337 perls.
338
339 "VMG_THREADSAFE"
340 True iff this module could have been built with thread-safety features
341 enabled.
342
343 "VMG_FORKSAFE"
344 True iff this module could have been built with fork-safety features
345 enabled. This will always be true except on Windows where it's false for
346 perl 5.10.0 and below .
347
348 "VMG_OP_INFO_NAME"
349 Value to pass with "op_info" to get the current op name in the magic
350 callbacks.
351
352 "VMG_OP_INFO_OBJECT"
353 Value to pass with "op_info" to get a "B::OP" object representing the
354 current op in the magic callbacks.
355
356COOKBOOK
357 Associate an object to any perl variable
358 This technique can be useful for passing user data through limited APIs.
359 It is similar to using inside-out objects, but without the drawback of
360 having to implement a complex destructor.
361
362 {
363 package Magical::UserData;
364
365 use Variable::Magic qw/wizard cast getdata/;
366
367 my $wiz = wizard data => sub { \$_[1] };
368
369 sub ud (\[$@%*&]) : lvalue {
370 my ($var) = @_;
371 my $data = &getdata($var, $wiz);
372 unless (defined $data) {
373 $data = \(my $slot);
374 &cast($var, $wiz, $slot)
375 or die "Couldn't cast UserData magic onto the variable";
376 }
377 $$data;
378 }
379 }
380
381 {
382 BEGIN { *ud = \&Magical::UserData::ud }
383
384 my $cb;
385 $cb = sub { print 'Hello, ', ud(&$cb), "!\n" };
386
387 ud(&$cb) = 'world';
388 $cb->(); # Hello, world!
389 }
390
391 Recursively cast magic on datastructures
392 "cast" can be called from any magical callback, and in particular from
393 "data". This allows you to recursively cast magic on datastructures :
394
395 my $wiz;
396 $wiz = wizard data => sub {
397 my ($var, $depth) = @_;
398 $depth ||= 0;
399 my $r = ref $var;
400 if ($r eq 'ARRAY') {
401 &cast((ref() ? $_ : \$_), $wiz, $depth + 1) for @$var;
402 } elsif ($r eq 'HASH') {
403 &cast((ref() ? $_ : \$_), $wiz, $depth + 1) for values %$var;
404 }
405 return $depth;
406 },
407 free => sub {
408 my ($var, $depth) = @_;
409 my $r = ref $var;
410 print "free $r at depth $depth\n";
411 ();
412 };
413
414 {
415 my %h = (
416 a => [ 1, 2 ],
417 b => { c => 3 }
418 );
419 cast %h, $wiz;
420 }
421
422 When %h goes out of scope, this will print something among the lines of
423 :
424
425 free HASH at depth 0
426 free HASH at depth 1
427 free SCALAR at depth 2
428 free ARRAY at depth 1
429 free SCALAR at depth 3
430 free SCALAR at depth 3
431
432 Of course, this example does nothing with the values that are added
433 after the "cast".
434
435PERL MAGIC HISTORY
436 The places where magic is invoked have changed a bit through perl
437 history. Here's a little list of the most recent ones.
438
439 * 5.6.x
440
441 *p14416* : 'copy' and 'dup' magic.
442
443 * 5.8.9
444
445 *p28160* : Integration of *p25854* (see below).
446
447 *p32542* : Integration of *p31473* (see below).
448
449 * 5.9.3
450
451 *p25854* : 'len' magic is no longer called when pushing an element
452 into a magic array.
453
454 *p26569* : 'local' magic.
455
456 * 5.9.5
457
458 *p31064* : Meaningful 'uvar' magic.
459
460 *p31473* : 'clear' magic wasn't invoked when undefining an array.
461 The bug is fixed as of this version.
462
463 * 5.10.0
464
465 Since "PERL_MAGIC_uvar" is uppercased, "hv_magic_check()" triggers
466 'copy' magic on hash stores for (non-tied) hashes that also have
467 'uvar' magic.
468
469 * 5.11.x
470
471 *p32969* : 'len' magic is no longer invoked when calling "length"
472 with a magical scalar.
473
474 *p34908* : 'len' magic is no longer called when pushing / unshifting
475 an element into a magical array in void context. The "push" part was
476 already covered by *p25854*.
477
478 *g9cdcb38b* : 'len' magic is called again when pushing into a
479 magical array in non-void context.
480
481EXPORT
482 The functions "wizard", "cast", "getdata" and "dispell" are only
483 exported on request. All of them are exported by the tags ':funcs' and
484 ':all'.
485
486 All the constants are also only exported on request, either individually
487 or by the tags ':consts' and ':all'.
488
489CAVEATS
490 If you store a magic object in the private data slot, the magic won't be
491 accessible by "getdata" since it's not copied by assignment. The only
492 way to address this would be to return a reference.
493
494 If you define a wizard with a "free" callback and cast it on itself,
495 this destructor won't be called because the wizard will be destroyed
496 first.
497
498DEPENDENCIES
499 perl 5.8.
500
501 Carp (standard since perl 5), XSLoader (standard since perl 5.006).
502
503 Copy tests need Tie::Array (standard since perl 5.005) and Tie::Hash
504 (since 5.002).
505
506 Some uvar tests need Hash::Util::FieldHash (standard since perl
507 5.009004).
508
509 Glob tests need Symbol (standard since perl 5.002).
510
511 Threads tests need threads and threads::shared.
512
513SEE ALSO
514 perlguts and perlapi for internal information about magic.
515
516 perltie and overload for other ways of enhancing objects.
517
518AUTHOR
519 Vincent Pit, "<perl at profvince.com>", <http://www.profvince.com>.
520
521 You can contact me by mail or on "irc.perl.org" (vincent).
522
523BUGS
524 Please report any bugs or feature requests to "bug-variable-magic at
525 rt.cpan.org", or through the web interface at
526 <http://rt.cpan.org/NoAuth/ReportBug.html?Queue=Variable-Magic>. I will
527 be notified, and then you'll automatically be notified of progress on
528 your bug as I make changes.
529
530SUPPORT
531 You can find documentation for this module with the perldoc command.
532
533 perldoc Variable::Magic
534
535 Tests code coverage report is available at
536 <http://www.profvince.com/perl/cover/Variable-Magic>.
537
538COPYRIGHT & LICENSE
539 Copyright 2007,2008,2009,2010 Vincent Pit, all rights reserved.
540
541 This program is free software; you can redistribute it and/or modify it
542 under the same terms as Perl itself.
543
544