1OUTPUT_FORMAT("elf64-sparc")
2OUTPUT_ARCH(sparc:v9)
3
4ENTRY(_start)
5
6PHDRS
7{
8	headers PT_PHDR PHDRS ;
9	text PT_LOAD FILEHDR PHDRS FLAGS(5) ;
10	data PT_LOAD ;
11	dynamic PT_DYNAMIC ;
12}
13
14SECTIONS
15{
16	. = 0xFFFFFFFF80000000 + SIZEOF_HEADERS;
17
18	.interp : { *(.interp) } : text
19	.hash : { *(.hash) }
20	.dynsym : { *(.dynsym) }
21	.dynstr : { *(.dynstr) }
22	.rela.text : { *(.rela.text .rela.text.* .rela.gnu.linkonce.t.*) }
23	.rela.data : { *(.rela.data .rela.data.* .rela.gnu.linkonce.d.*) }
24	.rela.rodata : { *(.rela.rodata .rela.rodata.* .rela.gnu.linkonce.r.*) }
25	.rela.got : { *(.rela.got) }
26	.rela.ctors : { *(.rela.ctors) }
27	.rela.dtors : { *(.rela.dtors) }
28	.rela.init : { *(.rela.init) }
29	.rela.fini : { *(.rela.fini) }
30	.rela.bss : { *(.rela.bss .rela.bss.* .rela.gnu.linkonce.b.*) }
31	.rela.plt : { *(.rela.plt) }
32	.init : { *(.init) } =0x90909090
33	.plt : { *(.plt) }
34
35	/* text/read-only data */
36	.text :	{ *(.text .text.* .gnu.linkonce.t.*) } :text =0x90909090
37
38	.rodata : { *(.rodata .rodata.* .gnu.linkonce.r.*) }
39
40	. = ALIGN(0x8);
41	altcodepatch_begin = .;
42	.altcodepatch : { *(.altcodepatch) }
43	altcodepatch_end = .;
44
45	/* writable data - in a separate page for memory protection purposes */
46	. = ALIGN (0x2000);
47	__data_start = .;
48	.data : { *(.data .data.* .gnu.linkonce.d.*) } :data
49
50	. = ALIGN(0x4);
51	__ctor_list = .;
52	.ctors : { *(.ctors) }
53	__ctor_end = .;
54	__dtor_list = .;
55	.dtors : { *(.dtors) }
56	__dtor_end = .;
57	.got : { *(.got.plt) *(.got) }
58	.dynamic : { *(.dynamic) } :dynamic :data
59	
60	/* uninitialized data (in same segment as writable data) */
61	. = ALIGN(0x8);
62	__bss_start = .;
63	.bss : { *(.bss .bss.* .gnu.linkonce.b.*) } :data
64
65	/* make sure to end on a page boundary */
66	. = ALIGN(0x2000);
67	_end = . ;
68
69	/* Strip unnecessary stuff */
70	/DISCARD/ : { *(.comment .note .eh_frame) }
71}
72