libraries.m4 revision 861:56db38956113 
1#
2# Copyright (c) 2011, 2012, Oracle and/or its affiliates. All rights reserved.
3# DO NOT ALTER OR REMOVE COPYRIGHT NOTICES OR THIS FILE HEADER.
4#
5# This code is free software; you can redistribute it and/or modify it
6# under the terms of the GNU General Public License version 2 only, as
7# published by the Free Software Foundation.  Oracle designates this
8# particular file as subject to the "Classpath" exception as provided
9# by Oracle in the LICENSE file that accompanied this code.
10#
11# This code is distributed in the hope that it will be useful, but WITHOUT
12# ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
13# FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License
14# version 2 for more details (a copy is included in the LICENSE file that
15# accompanied this code).
16#
17# You should have received a copy of the GNU General Public License version
18# 2 along with this work; if not, write to the Free Software Foundation,
19# Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301 USA.
20#
21# Please contact Oracle, 500 Oracle Parkway, Redwood Shores, CA 94065 USA
22# or visit www.oracle.com if you need additional information or have any
23# questions.
24#
25
26AC_DEFUN_ONCE([LIB_SETUP_INIT],
27[
28
29  ###############################################################################
30  #
31  # OS specific settings that we never will need to probe.
32  #
33  if test "x$OPENJDK_TARGET_OS" = xlinux; then
34    AC_MSG_CHECKING([what is not needed on Linux?])
35    PULSE_NOT_NEEDED=yes
36    AC_MSG_RESULT([pulse])
37  fi
38
39  if test "x$OPENJDK_TARGET_OS" = xsolaris; then
40    AC_MSG_CHECKING([what is not needed on Solaris?])
41    ALSA_NOT_NEEDED=yes
42    PULSE_NOT_NEEDED=yes
43    AC_MSG_RESULT([alsa pulse])
44  fi
45
46  if test "x$OPENJDK_TARGET_OS" = xwindows; then
47    AC_MSG_CHECKING([what is not needed on Windows?])
48    CUPS_NOT_NEEDED=yes
49    ALSA_NOT_NEEDED=yes
50    PULSE_NOT_NEEDED=yes
51    X11_NOT_NEEDED=yes
52    AC_MSG_RESULT([alsa cups pulse x11])
53  fi
54
55  if test "x$OPENJDK_TARGET_OS" = xmacosx; then
56    AC_MSG_CHECKING([what is not needed on MacOSX?])
57    ALSA_NOT_NEEDED=yes
58    PULSE_NOT_NEEDED=yes
59    X11_NOT_NEEDED=yes
60    FREETYPE2_NOT_NEEDED=yes
61    # If the java runtime framework is disabled, then we need X11.
62    # This will be adjusted below.
63    AC_MSG_RESULT([alsa pulse x11 freetype])
64  fi
65
66  if test "x$OPENJDK_TARGET_OS" = xbsd; then
67    AC_MSG_CHECKING([what is not needed on bsd?])
68    ALSA_NOT_NEEDED=yes
69    AC_MSG_RESULT([alsa])
70  fi
71
72  if test "x$OPENJDK" = "xfalse"; then
73    FREETYPE2_NOT_NEEDED=yes
74  fi
75
76  if test "x$SUPPORT_HEADFUL" = xno; then
77    X11_NOT_NEEDED=yes
78  fi
79
80  ###############################################################################
81  #
82  # Check for MacOSX support for OpenJDK.
83  #
84
85  BASIC_DEPRECATED_ARG_ENABLE(macosx-runtime-support, macosx_runtime_support)
86
87  AC_MSG_CHECKING([for Mac OS X Java Framework])
88  if test -f /System/Library/Frameworks/JavaVM.framework/Frameworks/JavaRuntimeSupport.framework/Headers/JavaRuntimeSupport.h; then
89    AC_MSG_RESULT([/System/Library/Frameworks/JavaVM.framework])
90  else
91    AC_MSG_RESULT([no])
92  fi
93])
94
95AC_DEFUN_ONCE([LIB_SETUP_X11],
96[
97
98  ###############################################################################
99  #
100  # Check for X Windows
101  #
102
103  # Check if the user has specified sysroot, but not --x-includes or --x-libraries.
104  # Make a simple check for the libraries at the sysroot, and setup --x-includes and
105  # --x-libraries for the sysroot, if that seems to be correct.
106  if test "x$SYS_ROOT" != "x/"; then
107    if test "x$x_includes" = xNONE; then
108      if test -f "$SYS_ROOT/usr/X11R6/include/X11/Xlib.h"; then
109        x_includes="$SYS_ROOT/usr/X11R6/include"
110      elif test -f "$SYS_ROOT/usr/include/X11/Xlib.h"; then
111        x_includes="$SYS_ROOT/usr/include"
112      fi
113    fi
114    if test "x$x_libraries" = xNONE; then
115      if test -f "$SYS_ROOT/usr/X11R6/lib/libX11.so"; then
116        x_libraries="$SYS_ROOT/usr/X11R6/lib"
117      elif test "$SYS_ROOT/usr/lib64/libX11.so" && test "x$OPENJDK_TARGET_CPU_BITS" = x64; then
118        x_libraries="$SYS_ROOT/usr/lib64"
119      elif test -f "$SYS_ROOT/usr/lib/libX11.so"; then
120        x_libraries="$SYS_ROOT/usr/lib"
121      fi
122    fi
123  fi
124
125  # Now let autoconf do it's magic
126  AC_PATH_X
127  AC_PATH_XTRA
128
129  # AC_PATH_XTRA creates X_LIBS and sometimes adds -R flags. When cross compiling
130  # this doesn't make sense so we remove it.
131  if test "x$COMPILE_TYPE" = xcross; then
132    X_LIBS=`$ECHO $X_LIBS | $SED 's/-R \{0,1\}[[^ ]]*//g'`
133  fi
134
135  if test "x$no_x" = xyes && test "x$X11_NOT_NEEDED" != xyes; then
136    HELP_MSG_MISSING_DEPENDENCY([x11])
137    AC_MSG_ERROR([Could not find X11 libraries. $HELP_MSG])
138  fi
139
140  # Some of the old makefiles require a setting of OPENWIN_HOME
141  # Since the X11R6 directory has disappeared on later Linuxes,
142  # we need to probe for it.
143  if test "x$OPENJDK_TARGET_OS" = xlinux; then
144    if test -d "$SYS_ROOT/usr/X11R6"; then
145      OPENWIN_HOME="$SYS_ROOT/usr/X11R6"
146    elif test -d "$SYS_ROOT/usr/include/X11"; then
147      OPENWIN_HOME="$SYS_ROOT/usr"
148    fi
149  fi
150  if test "x$OPENJDK_TARGET_OS" = xsolaris; then
151    OPENWIN_HOME="/usr/openwin"
152  fi
153  AC_SUBST(OPENWIN_HOME)
154
155
156  #
157  # Weird Sol10 something check...TODO change to try compile
158  #
159  if test "x${OPENJDK_TARGET_OS}" = xsolaris; then
160    if test "`uname -r`" = "5.10"; then
161      if test "`${EGREP} -c XLinearGradient ${OPENWIN_HOME}/share/include/X11/extensions/Xrender.h`" = "0"; then
162        X_CFLAGS="${X_CFLAGS} -DSOLARIS10_NO_XRENDER_STRUCTS"
163      fi
164    fi
165  fi
166
167  AC_LANG_PUSH(C)
168  OLD_CFLAGS="$CFLAGS"
169  CFLAGS="$CFLAGS $X_CFLAGS"
170
171  # Need to include Xlib.h and Xutil.h to avoid "present but cannot be compiled" warnings on Solaris 10
172  AC_CHECK_HEADERS([X11/extensions/shape.h X11/extensions/Xrender.h X11/extensions/XTest.h X11/Intrinsic.h],
173      [X11_A_OK=yes],
174      [X11_A_OK=no; break],
175      [
176        # include <X11/Xlib.h>
177        # include <X11/Xutil.h>
178      ]
179  )
180
181  CFLAGS="$OLD_CFLAGS"
182  AC_LANG_POP(C)
183
184  if test "x$X11_A_OK" = xno && test "x$X11_NOT_NEEDED" != xyes; then
185    HELP_MSG_MISSING_DEPENDENCY([x11])
186    AC_MSG_ERROR([Could not find all X11 headers (shape.h Xrender.h XTest.h Intrinsic.h). $HELP_MSG])
187  fi
188
189  AC_SUBST(X_CFLAGS)
190  AC_SUBST(X_LIBS)
191])
192
193AC_DEFUN_ONCE([LIB_SETUP_CUPS],
194[
195
196  ###############################################################################
197  #
198  # The common unix printing system cups is used to print from java.
199  #
200  AC_ARG_WITH(cups, [AS_HELP_STRING([--with-cups],
201      [specify prefix directory for the cups package
202      (expecting the headers under PATH/include)])])
203  AC_ARG_WITH(cups-include, [AS_HELP_STRING([--with-cups-include],
204      [specify directory for the cups include files])])
205
206  if test "x$CUPS_NOT_NEEDED" = xyes; then
207    if test "x${with_cups}" != x || test "x${with_cups_include}" != x; then
208      AC_MSG_WARN([cups not used, so --with-cups is ignored])
209    fi
210    CUPS_CFLAGS=
211  else
212    CUPS_FOUND=no
213
214    if test "x${with_cups}" = xno || test "x${with_cups_include}" = xno; then
215      AC_MSG_ERROR([It is not possible to disable the use of cups. Remove the --without-cups option.])
216    fi
217
218    if test "x${with_cups}" != x; then
219      CUPS_CFLAGS="-I${with_cups}/include"
220      CUPS_FOUND=yes
221    fi
222    if test "x${with_cups_include}" != x; then
223      CUPS_CFLAGS="-I${with_cups_include}"
224      CUPS_FOUND=yes
225    fi
226    if test "x$CUPS_FOUND" = xno; then
227      BDEPS_CHECK_MODULE(CUPS, cups, xxx, [CUPS_FOUND=yes])
228    fi
229    if test "x$CUPS_FOUND" = xno; then
230      # Are the cups headers installed in the default /usr/include location?
231      AC_CHECK_HEADERS([cups/cups.h cups/ppd.h],
232          [
233            CUPS_FOUND=yes
234            CUPS_CFLAGS=
235            DEFAULT_CUPS=yes
236          ]
237      )
238    fi
239    if test "x$CUPS_FOUND" = xno; then
240      # Getting nervous now? Lets poke around for standard Solaris third-party
241      # package installation locations.
242      AC_MSG_CHECKING([for cups headers])
243      if test -s /opt/sfw/cups/include/cups/cups.h; then
244        # An SFW package seems to be installed!
245        CUPS_FOUND=yes
246        CUPS_CFLAGS="-I/opt/sfw/cups/include"
247      elif test -s /opt/csw/include/cups/cups.h; then
248        # A CSW package seems to be installed!
249        CUPS_FOUND=yes
250        CUPS_CFLAGS="-I/opt/csw/include"
251      fi
252      AC_MSG_RESULT([$CUPS_FOUND])
253    fi
254    if test "x$CUPS_FOUND" = xno; then
255      HELP_MSG_MISSING_DEPENDENCY([cups])
256      AC_MSG_ERROR([Could not find cups! $HELP_MSG ])
257    fi
258  fi
259
260  AC_SUBST(CUPS_CFLAGS)
261
262])
263
264AC_DEFUN_ONCE([LIB_SETUP_FREETYPE],
265[
266
267  ###############################################################################
268  #
269  # The ubiquitous freetype2 library is used to render fonts.
270  #
271  AC_ARG_WITH(freetype, [AS_HELP_STRING([--with-freetype],
272      [specify prefix directory for the freetype2 package
273      (expecting the libraries under PATH/lib and the headers under PATH/include)])])
274
275  # If we are using the OS installed system lib for freetype, then we do not need to copy it to the build tree
276  USING_SYSTEM_FT_LIB=false
277
278  if test "x$FREETYPE2_NOT_NEEDED" = xyes; then
279    if test "x$with_freetype" != x || test "x$with_freetype_include" != x || test "x$with_freetype_lib" != x; then
280      AC_MSG_WARN([freetype not used, so --with-freetype is ignored])
281    fi
282    FREETYPE2_CFLAGS=
283    FREETYPE2_LIBS=
284    FREETYPE2_LIB_PATH=
285  else
286    FREETYPE2_FOUND=no
287
288    if test "x$with_freetype" != x; then
289      BASIC_FIXUP_PATH(with_freetype)
290      FREETYPE2_LIBS="-L$with_freetype/lib -lfreetype"
291      FREETYPE2_LIB_PATH="$with_freetype/lib"
292      if test "x$OPENJDK_TARGET_OS" = xsolaris && test "x$OPENJDK_TARGET_CPU" = xx86_64 && test -d "$with_freetype/lib/amd64"; then
293        FREETYPE2_LIBS="-L$with_freetype/lib/amd64 -lfreetype"
294        FREETYPE2_LIB_PATH="$with_freetype/lib/amd64"
295      fi
296      if test "x$OPENJDK_TARGET_OS" = xwindows; then
297        FREETYPE2_LIBS="$with_freetype/lib/freetype.lib"
298      fi
299      FREETYPE2_CFLAGS="-I$with_freetype/include"
300      if test -s $with_freetype/include/ft2build.h && test -d $with_freetype/include/freetype2/freetype; then
301        FREETYPE2_CFLAGS="-I$with_freetype/include/freetype2 -I$with_freetype/include"
302      fi
303      FREETYPE2_FOUND=yes
304      if test "x$FREETYPE2_FOUND" = xyes; then
305        # Verify that the directories exist
306        if ! test -d "$with_freetype/lib" || ! test -d "$with_freetype/include"; then
307          AC_MSG_ERROR([Could not find the expected directories $with_freetype/lib and $with_freetype/include])
308        fi
309        # List the contents of the lib.
310        FREETYPELIB=`ls $with_freetype/lib/libfreetype.so $with_freetype/lib/freetype.dll 2> /dev/null`
311        if test "x$FREETYPELIB" = x; then
312          AC_MSG_ERROR([Could not find libfreetype.so nor freetype.dll in $with_freetype/lib])
313        fi
314        # Check one h-file
315        if ! test -s "$with_freetype/include/ft2build.h"; then
316          AC_MSG_ERROR([Could not find $with_freetype/include/ft2build.h])
317        fi
318      fi
319    fi
320    if test "x$FREETYPE2_FOUND" = xno; then
321      BDEPS_CHECK_MODULE(FREETYPE2, freetype2, xxx, [FREETYPE2_FOUND=yes], [FREETYPE2_FOUND=no])
322      USING_SYSTEM_FT_LIB=true
323    fi
324    if test "x$FREETYPE2_FOUND" = xno && test "x$OPENJDK_TARGET_OS" = xwindows; then
325      FREETYPELOCATION="$PROGRAMFILES/GnuWin32"
326      BASIC_FIXUP_PATH(FREETYPELOCATION)
327      AC_MSG_CHECKING([for freetype in some standard windows locations])
328      if test -s "$FREETYPELOCATION/include/ft2build.h" && test -d "$FREETYPELOCATION/include/freetype2/freetype"; then
329        FREETYPE2_CFLAGS="-I$FREETYPELOCATION/include/freetype2 -I$FREETYPELOCATION/include"
330        FREETYPE2_LIBS="$FREETYPELOCATION/lib/freetype.lib"
331        FREETYPE2_LIB_PATH="$FREETYPELOCATION/lib"
332        if ! test -s "$FREETYPE2_LIBS"; then
333          AC_MSG_ERROR([Could not find $FREETYPE2_LIBS])
334        fi
335        if ! test -s "$FREETYPE2_LIB_PATH/freetype.dll"; then
336          AC_MSG_ERROR([Could not find $FREETYPE2_LIB_PATH/freetype.dll])
337        fi
338        USING_SYSTEM_FT_LIB=true
339        FREETYPE2_FOUND=yes
340      fi
341      AC_MSG_RESULT([$FREETYPE2_FOUND])
342    fi
343    if test "x$FREETYPE2_FOUND" = xno; then
344      PKG_CHECK_MODULES(FREETYPE2, freetype2, [FREETYPE2_FOUND=yes], [FREETYPE2_FOUND=no])
345      # On solaris, pkg_check adds -lz to freetype libs, which isn't necessary for us.
346      FREETYPE2_LIBS=`$ECHO $FREETYPE2_LIBS | $SED 's/-lz//g'`
347      USING_SYSTEM_FT_LIB=true
348      # 64-bit libs for Solaris x86 are installed in the amd64 subdirectory, change lib to lib/amd64
349      if test "x$FREETYPE2_FOUND" = xyes && test "x$OPENJDK_TARGET_OS" = xsolaris && test "x$OPENJDK_TARGET_CPU" = xx86_64; then
350        FREETYPE2_LIBS=`$ECHO $FREETYPE2_LIBS | $SED 's?/lib?/lib/amd64?g'`
351      fi
352    fi
353    if test "x$FREETYPE2_FOUND" = xno; then
354      AC_MSG_CHECKING([for freetype in some standard locations])
355
356      if test -s $SYS_ROOT/usr/X11/include/ft2build.h && test -d $SYS_ROOT/usr/X11/include/freetype2/freetype; then
357        DEFAULT_FREETYPE_CFLAGS="-I$SYS_ROOT/usr/X11/include/freetype2 -I$SYS_ROOT/usr/X11/include"
358        DEFAULT_FREETYPE_LIBS="-L$SYS_ROOT/usr/X11/lib -lfreetype"
359      fi
360      if test -s $SYS_ROOT/usr/include/ft2build.h && test -d $SYS_ROOT/usr/include/freetype2/freetype; then
361        DEFAULT_FREETYPE_CFLAGS="-I$SYS_ROOT/usr/include/freetype2"
362        DEFAULT_FREETYPE_LIBS="-lfreetype"
363      fi
364
365      PREV_CXXCFLAGS="$CXXFLAGS"
366      PREV_LDFLAGS="$LDFLAGS"
367      CXXFLAGS="$CXXFLAGS $DEFAULT_FREETYPE_CFLAGS"
368      LDFLAGS="$LDFLAGS $DEFAULT_FREETYPE_LIBS"
369      AC_LINK_IFELSE([AC_LANG_SOURCE([[
370            #include<ft2build.h>
371            #include FT_FREETYPE_H
372            int main() { return 0; }
373          ]])],
374          [
375            # Yes, the default cflags and libs did the trick.
376            FREETYPE2_FOUND=yes
377            FREETYPE2_CFLAGS="$DEFAULT_FREETYPE_CFLAGS"
378            FREETYPE2_LIBS="$DEFAULT_FREETYPE_LIBS"
379          ],
380          [
381            FREETYPE2_FOUND=no
382          ]
383      )
384      CXXCFLAGS="$PREV_CXXFLAGS"
385      LDFLAGS="$PREV_LDFLAGS"
386      AC_MSG_RESULT([$FREETYPE2_FOUND])
387      USING_SYSTEM_FT_LIB=true
388    fi
389    if test "x$FREETYPE2_FOUND" = xno; then
390      HELP_MSG_MISSING_DEPENDENCY([freetype2])
391      AC_MSG_ERROR([Could not find freetype2! $HELP_MSG ])
392    fi
393
394    if test "x$OPENJDK_TARGET_OS" != xwindows; then
395      # AC_CHECK_LIB does not support use of cl.exe
396      PREV_LDFLAGS="$LDFLAGS"
397      LDFLAGS="$FREETYPE2_LIBS"
398      AC_CHECK_LIB(freetype, FT_Init_FreeType,
399          FREETYPE2_FOUND=true,
400          AC_MSG_ERROR([Could not find freetype2! $HELP_MSG ]))
401      LDFLAGS="$PREV_LDFLAGS"
402    fi
403  fi
404
405  AC_SUBST(USING_SYSTEM_FT_LIB)
406  AC_SUBST(FREETYPE2_LIB_PATH)
407  AC_SUBST(FREETYPE2_CFLAGS)
408  AC_SUBST(FREETYPE2_LIBS)
409])
410
411AC_DEFUN_ONCE([LIB_SETUP_ALSA],
412[
413
414  ###############################################################################
415  #
416  # Check for alsa headers and libraries. Used on Linux/GNU systems.
417  #
418  AC_ARG_WITH(alsa, [AS_HELP_STRING([--with-alsa],
419      [specify prefix directory for the alsa package
420      (expecting the libraries under PATH/lib and the headers under PATH/include)])])
421  AC_ARG_WITH(alsa-include, [AS_HELP_STRING([--with-alsa-include],
422      [specify directory for the alsa include files])])
423  AC_ARG_WITH(alsa-lib, [AS_HELP_STRING([--with-alsa-lib],
424      [specify directory for the alsa library])])
425
426  if test "x$ALSA_NOT_NEEDED" = xyes; then
427    if test "x${with_alsa}" != x || test "x${with_alsa_include}" != x || test "x${with_alsa_lib}" != x; then
428      AC_MSG_WARN([alsa not used, so --with-alsa is ignored])
429    fi
430    ALSA_CFLAGS=
431    ALSA_LIBS=
432  else
433    ALSA_FOUND=no
434
435    if test "x${with_alsa}" = xno || test "x${with_alsa_include}" = xno || test "x${with_alsa_lib}" = xno; then
436      AC_MSG_ERROR([It is not possible to disable the use of alsa. Remove the --without-alsa option.])
437    fi
438
439    if test "x${with_alsa}" != x; then
440      ALSA_LIBS="-L${with_alsa}/lib -lalsa"
441      ALSA_CFLAGS="-I${with_alsa}/include"
442      ALSA_FOUND=yes
443    fi
444    if test "x${with_alsa_include}" != x; then
445      ALSA_CFLAGS="-I${with_alsa_include}"
446      ALSA_FOUND=yes
447    fi
448    if test "x${with_alsa_lib}" != x; then
449      ALSA_LIBS="-L${with_alsa_lib} -lalsa"
450      ALSA_FOUND=yes
451    fi
452    if test "x$ALSA_FOUND" = xno; then
453      BDEPS_CHECK_MODULE(ALSA, alsa, xxx, [ALSA_FOUND=yes], [ALSA_FOUND=no])
454    fi
455    if test "x$ALSA_FOUND" = xno; then
456      PKG_CHECK_MODULES(ALSA, alsa, [ALSA_FOUND=yes], [ALSA_FOUND=no])
457    fi
458    if test "x$ALSA_FOUND" = xno; then
459      AC_CHECK_HEADERS([alsa/asoundlib.h],
460          [
461            ALSA_FOUND=yes
462            ALSA_CFLAGS=-Iignoreme
463            ALSA_LIBS=-lasound
464            DEFAULT_ALSA=yes
465          ],
466          [ALSA_FOUND=no])
467    fi
468    if test "x$ALSA_FOUND" = xno; then
469      HELP_MSG_MISSING_DEPENDENCY([alsa])
470      AC_MSG_ERROR([Could not find alsa! $HELP_MSG ])
471    fi
472  fi
473
474  AC_SUBST(ALSA_CFLAGS)
475  AC_SUBST(ALSA_LIBS)
476])
477
478AC_DEFUN_ONCE([LIB_SETUP_MISC_LIBS],
479[
480
481  ###############################################################################
482  #
483  # Check for the jpeg library
484  #
485
486  USE_EXTERNAL_LIBJPEG=true
487  AC_CHECK_LIB(jpeg, main, [],
488      [ USE_EXTERNAL_LIBJPEG=false
489      AC_MSG_NOTICE([Will use jpeg decoder bundled with the OpenJDK source])
490  ])
491  AC_SUBST(USE_EXTERNAL_LIBJPEG)
492
493  ###############################################################################
494  #
495  # Check for the gif library
496  #
497
498  AC_ARG_WITH(giflib, [AS_HELP_STRING([--with-giflib],
499      [use giflib from build system or OpenJDK source (system, bundled) @<:@bundled@:>@])])
500
501
502  AC_MSG_CHECKING([for which giflib to use])
503
504  # default is bundled
505  DEFAULT_GIFLIB=bundled
506
507  #
508  # if user didn't specify, use DEFAULT_GIFLIB
509  #
510  if test "x${with_giflib}" = "x"; then
511    with_giflib=${DEFAULT_GIFLIB}
512  fi
513
514  AC_MSG_RESULT(${with_giflib})
515
516  if test "x${with_giflib}" = "xbundled"; then
517    USE_EXTERNAL_LIBGIF=false
518  elif test "x${with_giflib}" = "xsystem"; then
519    AC_CHECK_HEADER(gif_lib.h, [],
520        [ AC_MSG_ERROR([--with-giflib=system specified, but gif_lib.h not found!])])
521    AC_CHECK_LIB(gif, DGifGetCode, [],
522        [ AC_MSG_ERROR([--with-giflib=system specified, but no giflib found!])])
523
524    USE_EXTERNAL_LIBGIF=true
525  else
526    AC_MSG_ERROR([Invalid value of --with-giflib: ${with_giflib}, use 'system' or 'bundled'])
527  fi
528  AC_SUBST(USE_EXTERNAL_LIBGIF)
529
530  ###############################################################################
531  #
532  # Check for the zlib library
533  #
534
535  AC_ARG_WITH(zlib, [AS_HELP_STRING([--with-zlib],
536      [use zlib from build system or OpenJDK source (system, bundled) @<:@bundled@:>@])])
537
538  AC_CHECK_LIB(z, compress,
539      [ ZLIB_FOUND=yes ],
540      [ ZLIB_FOUND=no ])
541
542  AC_MSG_CHECKING([for which zlib to use])
543
544  DEFAULT_ZLIB=bundled
545  if test "x$OPENJDK_TARGET_OS" = xmacosx; then
546    #
547    # On macosx default is system...on others default is
548    #
549    DEFAULT_ZLIB=system
550  fi
551
552  if test "x${ZLIB_FOUND}" != "xyes"; then
553    #
554    # If we don't find any system...set default to bundled
555    #
556    DEFAULT_ZLIB=bundled
557  fi
558
559  #
560  # If user didn't specify, use DEFAULT_ZLIB
561  #
562  if test "x${with_zlib}" = "x"; then
563    with_zlib=${DEFAULT_ZLIB}
564  fi
565
566  if test "x${with_zlib}" = "xbundled"; then
567    USE_EXTERNAL_LIBZ=false
568    AC_MSG_RESULT([bundled])
569  elif test "x${with_zlib}" = "xsystem"; then
570    if test "x${ZLIB_FOUND}" = "xyes"; then
571      USE_EXTERNAL_LIBZ=true
572      AC_MSG_RESULT([system])
573    else
574      AC_MSG_RESULT([system not found])
575      AC_MSG_ERROR([--with-zlib=system specified, but no zlib found!])
576    fi
577  else
578    AC_MSG_ERROR([Invalid value for --with-zlib: ${with_zlib}, use 'system' or 'bundled'])
579  fi
580
581  AC_SUBST(USE_EXTERNAL_LIBZ)
582
583  ###############################################################################
584  LIBZIP_CAN_USE_MMAP=true
585
586  AC_SUBST(LIBZIP_CAN_USE_MMAP)
587
588  ###############################################################################
589  #
590  # Check if altzone exists in time.h
591  #
592
593  AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <time.h>], [return (int)altzone;])],
594      [has_altzone=yes],
595      [has_altzone=no])
596  if test "x$has_altzone" = xyes; then
597    AC_DEFINE([HAVE_ALTZONE], 1, [Define if you have the external 'altzone' variable in time.h])
598  fi
599
600  ###############################################################################
601  #
602  # Check the maths library
603  #
604
605  AC_CHECK_LIB(m, cos, [],
606      [
607        AC_MSG_NOTICE([Maths library was not found])
608      ]
609  )
610  AC_SUBST(LIBM)
611
612  ###############################################################################
613  #
614  # Check for libdl.so
615
616  save_LIBS="$LIBS"
617  LIBS=""
618  AC_CHECK_LIB(dl,dlopen)
619  LIBDL="$LIBS"
620  AC_SUBST(LIBDL)
621  LIBS="$save_LIBS"
622])
623
624AC_DEFUN_ONCE([LIB_SETUP_STATIC_LINK_LIBSTDCPP],
625[
626  ###############################################################################
627  #
628  # statically link libstdc++ before C++ ABI is stablized on Linux unless
629  # dynamic build is configured on command line.
630  #
631  AC_ARG_WITH([stdc++lib], [AS_HELP_STRING([--with-stdc++lib=<static>,<dynamic>,<default>],
632      [force linking of the C++ runtime on Linux to either static or dynamic, default is static with dynamic as fallback])],
633      [
634        if test "x$with_stdc__lib" != xdynamic && test "x$with_stdc__lib" != xstatic \
635                && test "x$with_stdc__lib" != xdefault; then
636          AC_MSG_ERROR([Bad parameter value --with-stdc++lib=$with_stdc__lib!])
637        fi
638      ],
639      [with_stdc__lib=default]
640  )
641
642  if test "x$OPENJDK_TARGET_OS" = xlinux; then
643    # Test if -lstdc++ works.
644    AC_MSG_CHECKING([if dynamic link of stdc++ is possible])
645    AC_LANG_PUSH(C++)
646    OLD_CXXFLAGS="$CXXFLAGS"
647    CXXFLAGS="$CXXFLAGS -lstdc++"
648    AC_LINK_IFELSE([AC_LANG_PROGRAM([], [return 0;])],
649        [has_dynamic_libstdcxx=yes],
650        [has_dynamic_libstdcxx=no])
651    CXXFLAGS="$OLD_CXXFLAGS"
652    AC_LANG_POP(C++)
653    AC_MSG_RESULT([$has_dynamic_libstdcxx])
654
655    # Test if stdc++ can be linked statically.
656    AC_MSG_CHECKING([if static link of stdc++ is possible])
657    STATIC_STDCXX_FLAGS="-Wl,-Bstatic -lstdc++ -lgcc -Wl,-Bdynamic"
658    AC_LANG_PUSH(C++)
659    OLD_LIBS="$LIBS"
660    OLD_CXX="$CXX"
661    LIBS="$STATIC_STDCXX_FLAGS"
662    CXX="$CC"
663    AC_LINK_IFELSE([AC_LANG_PROGRAM([], [return 0;])],
664        [has_static_libstdcxx=yes],
665        [has_static_libstdcxx=no])
666    LIBS="$OLD_LIBS"
667    CXX="$OLD_CXX"
668    AC_LANG_POP(C++)
669    AC_MSG_RESULT([$has_static_libstdcxx])
670
671    if test "x$has_static_libstdcxx" = xno && test "x$has_dynamic_libstdcxx" = xno; then
672      AC_MSG_ERROR([Cannot link to stdc++, neither dynamically nor statically!])
673    fi
674
675    if test "x$with_stdc__lib" = xstatic && test "x$has_static_libstdcxx" = xno; then
676      AC_MSG_ERROR([Static linking of libstdc++ was not possible!])
677    fi
678
679    if test "x$with_stdc__lib" = xdynamic && test "x$has_dynamic_libstdcxx" = xno; then
680      AC_MSG_ERROR([Dynamic linking of libstdc++ was not possible!])
681    fi
682
683    AC_MSG_CHECKING([how to link with libstdc++])
684    # If dynamic was requested, it's available since it would fail above otherwise.
685    # If dynamic wasn't requested, go with static unless it isn't available.
686    if test "x$with_stdc__lib" = xdynamic || test "x$has_static_libstdcxx" = xno || test "x$JVM_VARIANT_ZEROSHARK" = xtrue; then
687      LIBCXX="$LIBCXX -lstdc++"
688      LDCXX="$CXX"
689      STATIC_CXX_SETTING="STATIC_CXX=false"
690      AC_MSG_RESULT([dynamic])
691    else
692      LIBCXX="$LIBCXX $STATIC_STDCXX_FLAGS"
693      LDCXX="$CC"
694      STATIC_CXX_SETTING="STATIC_CXX=true"
695      AC_MSG_RESULT([static])
696    fi
697  fi
698  AC_SUBST(STATIC_CXX_SETTING)
699
700  if test "x$JVM_VARIANT_ZERO" = xtrue || test "x$JVM_VARIANT_ZEROSHARK" = xtrue; then
701    # Figure out LIBFFI_CFLAGS and LIBFFI_LIBS
702    PKG_CHECK_MODULES([LIBFFI], [libffi])
703
704  fi
705
706  if test "x$JVM_VARIANT_ZEROSHARK" = xtrue; then
707    AC_CHECK_PROG([LLVM_CONFIG], [llvm-config], [llvm-config])
708
709    if test "x$LLVM_CONFIG" != xllvm-config; then
710      AC_MSG_ERROR([llvm-config not found in $PATH.])
711    fi
712
713    llvm_components="jit mcjit engine nativecodegen native"
714    unset LLVM_CFLAGS
715    for flag in $("$LLVM_CONFIG" --cxxflags); do
716      if echo "${flag}" | grep -q '^-@<:@ID@:>@'; then
717        if test "${flag}" != "-D_DEBUG" ; then
718          if test "${LLVM_CFLAGS}" != "" ; then
719            LLVM_CFLAGS="${LLVM_CFLAGS} "
720          fi
721          LLVM_CFLAGS="${LLVM_CFLAGS}${flag}"
722        fi
723      fi
724    done
725    llvm_version=$("${LLVM_CONFIG}" --version | sed 's/\.//; s/svn.*//')
726    LLVM_CFLAGS="${LLVM_CFLAGS} -DSHARK_LLVM_VERSION=${llvm_version}"
727
728    unset LLVM_LDFLAGS
729    for flag in $("${LLVM_CONFIG}" --ldflags); do
730      if echo "${flag}" | grep -q '^-L'; then
731        if test "${LLVM_LDFLAGS}" != ""; then
732          LLVM_LDFLAGS="${LLVM_LDFLAGS} "
733        fi
734        LLVM_LDFLAGS="${LLVM_LDFLAGS}${flag}"
735      fi
736    done
737
738    unset LLVM_LIBS
739    for flag in $("${LLVM_CONFIG}" --libs ${llvm_components}); do
740      if echo "${flag}" | grep -q '^-l'; then
741        if test "${LLVM_LIBS}" != ""; then
742          LLVM_LIBS="${LLVM_LIBS} "
743        fi
744        LLVM_LIBS="${LLVM_LIBS}${flag}"
745      fi
746    done
747
748    AC_SUBST(LLVM_CFLAGS)
749    AC_SUBST(LLVM_LDFLAGS)
750    AC_SUBST(LLVM_LIBS)
751  fi
752
753  # libCrun is the c++ runtime-library with SunStudio (roughly the equivalent of gcc's libstdc++.so)
754  if test "x$OPENJDK_TARGET_OS" = xsolaris && test "x$LIBCXX" = x; then
755    LIBCXX="/usr/lib${OPENJDK_TARGET_CPU_ISADIR}/libCrun.so.1"
756  fi
757
758  # TODO better (platform agnostic) test
759  if test "x$OPENJDK_TARGET_OS" = xmacosx && test "x$LIBCXX" = x && test "x$GCC" = xyes; then
760    LIBCXX="-lstdc++"
761  fi
762
763  AC_SUBST(LIBCXX)
764])
765