jdk-options.m4 revision 1225:35c9a2c8bc2d 
1#
2# Copyright (c) 2011, 2014, Oracle and/or its affiliates. All rights reserved.
3# DO NOT ALTER OR REMOVE COPYRIGHT NOTICES OR THIS FILE HEADER.
4#
5# This code is free software; you can redistribute it and/or modify it
6# under the terms of the GNU General Public License version 2 only, as
7# published by the Free Software Foundation.  Oracle designates this
8# particular file as subject to the "Classpath" exception as provided
9# by Oracle in the LICENSE file that accompanied this code.
10#
11# This code is distributed in the hope that it will be useful, but WITHOUT
12# ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
13# FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License
14# version 2 for more details (a copy is included in the LICENSE file that
15# accompanied this code).
16#
17# You should have received a copy of the GNU General Public License version
18# 2 along with this work; if not, write to the Free Software Foundation,
19# Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301 USA.
20#
21# Please contact Oracle, 500 Oracle Parkway, Redwood Shores, CA 94065 USA
22# or visit www.oracle.com if you need additional information or have any
23# questions.
24#
25
26AC_DEFUN_ONCE([JDKOPT_SETUP_JDK_VARIANT],
27[
28  ###############################################################################
29  #
30  # Check which variant of the JDK that we want to build.
31  # Currently we have:
32  #    normal:   standard edition
33  # but the custom make system may add other variants
34  #
35  # Effectively the JDK variant gives a name to a specific set of
36  # modules to compile into the JDK. In the future, these modules
37  # might even be Jigsaw modules.
38  #
39  AC_MSG_CHECKING([which variant of the JDK to build])
40  AC_ARG_WITH([jdk-variant], [AS_HELP_STRING([--with-jdk-variant],
41      [JDK variant to build (normal) @<:@normal@:>@])])
42
43  if test "x$with_jdk_variant" = xnormal || test "x$with_jdk_variant" = x; then
44    JDK_VARIANT="normal"
45  else
46    AC_MSG_ERROR([The available JDK variants are: normal])
47  fi
48
49  AC_SUBST(JDK_VARIANT)
50
51  AC_MSG_RESULT([$JDK_VARIANT])
52])
53
54AC_DEFUN_ONCE([JDKOPT_SETUP_JVM_INTERPRETER],
55[
56###############################################################################
57#
58# Check which interpreter of the JVM we want to build.
59# Currently we have:
60#    template: Template interpreter (the default)
61#    cpp     : C++ interpreter
62AC_MSG_CHECKING([which interpreter of the JVM to build])
63AC_ARG_WITH([jvm-interpreter], [AS_HELP_STRING([--with-jvm-interpreter],
64	[JVM interpreter to build (template, cpp) @<:@template@:>@])])
65
66if test "x$with_jvm_interpreter" = x; then
67     with_jvm_interpreter="template"
68fi
69
70JVM_INTERPRETER="$with_jvm_interpreter"
71
72if test "x$JVM_INTERPRETER" != xtemplate && test "x$JVM_INTERPRETER" != xcpp; then
73   AC_MSG_ERROR([The available JVM interpreters are: template, cpp])
74fi
75
76AC_SUBST(JVM_INTERPRETER)
77
78AC_MSG_RESULT([$with_jvm_interpreter])
79])
80
81AC_DEFUN_ONCE([JDKOPT_SETUP_JVM_VARIANTS],
82[
83
84  ###############################################################################
85  #
86  # Check which variants of the JVM that we want to build.
87  # Currently we have:
88  #    server: normal interpreter and a tiered C1/C2 compiler
89  #    client: normal interpreter and C1 (no C2 compiler) (only 32-bit platforms)
90  #    minimal1: reduced form of client with optional VM services and features stripped out
91  #    kernel: kernel footprint JVM that passes the TCK without major performance problems,
92  #             ie normal interpreter and C1, only the serial GC, kernel jvmti etc
93  #    zero: no machine code interpreter, no compiler
94  #    zeroshark: zero interpreter and shark/llvm compiler backend
95#    core: interpreter only, no compiler (only works on some platforms)
96  AC_MSG_CHECKING([which variants of the JVM to build])
97  AC_ARG_WITH([jvm-variants], [AS_HELP_STRING([--with-jvm-variants],
98	[JVM variants (separated by commas) to build (server, client, minimal1, kernel, zero, zeroshark, core) @<:@server@:>@])])
99
100  if test "x$with_jvm_variants" = x; then
101    with_jvm_variants="server"
102  fi
103
104  JVM_VARIANTS=",$with_jvm_variants,"
105  TEST_VARIANTS=`$ECHO "$JVM_VARIANTS" | $SED -e 's/server,//' -e 's/client,//'  -e 's/minimal1,//' -e 's/kernel,//' -e 's/zero,//' -e 's/zeroshark,//' -e 's/core,//'`
106
107  if test "x$TEST_VARIANTS" != "x,"; then
108     AC_MSG_ERROR([The available JVM variants are: server, client, minimal1, kernel, zero, zeroshark, core])
109  fi
110  AC_MSG_RESULT([$with_jvm_variants])
111
112  JVM_VARIANT_SERVER=`$ECHO "$JVM_VARIANTS" | $SED -e '/,server,/!s/.*/false/g' -e '/,server,/s/.*/true/g'`
113  JVM_VARIANT_CLIENT=`$ECHO "$JVM_VARIANTS" | $SED -e '/,client,/!s/.*/false/g' -e '/,client,/s/.*/true/g'`
114  JVM_VARIANT_MINIMAL1=`$ECHO "$JVM_VARIANTS" | $SED -e '/,minimal1,/!s/.*/false/g' -e '/,minimal1,/s/.*/true/g'`
115  JVM_VARIANT_KERNEL=`$ECHO "$JVM_VARIANTS" | $SED -e '/,kernel,/!s/.*/false/g' -e '/,kernel,/s/.*/true/g'`
116  JVM_VARIANT_ZERO=`$ECHO "$JVM_VARIANTS" | $SED -e '/,zero,/!s/.*/false/g' -e '/,zero,/s/.*/true/g'`
117  JVM_VARIANT_ZEROSHARK=`$ECHO "$JVM_VARIANTS" | $SED -e '/,zeroshark,/!s/.*/false/g' -e '/,zeroshark,/s/.*/true/g'`
118  JVM_VARIANT_CORE=`$ECHO "$JVM_VARIANTS" | $SED -e '/,core,/!s/.*/false/g' -e '/,core,/s/.*/true/g'`
119
120  if test "x$JVM_VARIANT_CLIENT" = xtrue; then
121    if test "x$OPENJDK_TARGET_CPU_BITS" = x64; then
122      AC_MSG_ERROR([You cannot build a client JVM for a 64-bit machine.])
123    fi
124  fi
125  if test "x$JVM_VARIANT_KERNEL" = xtrue; then
126    if test "x$OPENJDK_TARGET_CPU_BITS" = x64; then
127      AC_MSG_ERROR([You cannot build a kernel JVM for a 64-bit machine.])
128    fi
129  fi
130  if test "x$JVM_VARIANT_MINIMAL1" = xtrue; then
131    if test "x$OPENJDK_TARGET_CPU_BITS" = x64; then
132      AC_MSG_ERROR([You cannot build a minimal JVM for a 64-bit machine.])
133    fi
134  fi
135
136  # Replace the commas with AND for use in the build directory name.
137  ANDED_JVM_VARIANTS=`$ECHO "$JVM_VARIANTS" | $SED -e 's/^,//' -e 's/,$//' -e 's/,/AND/g'`
138  COUNT_VARIANTS=`$ECHO "$JVM_VARIANTS" | $SED -e 's/server,/1/' -e 's/client,/1/' -e 's/minimal1,/1/' -e 's/kernel,/1/' -e 's/zero,/1/' -e 's/zeroshark,/1/' -e 's/core,/1/'`
139  if test "x$COUNT_VARIANTS" != "x,1"; then
140    BUILDING_MULTIPLE_JVM_VARIANTS=yes
141  else
142    BUILDING_MULTIPLE_JVM_VARIANTS=no
143  fi
144
145  AC_SUBST(JVM_VARIANTS)
146  AC_SUBST(JVM_VARIANT_SERVER)
147  AC_SUBST(JVM_VARIANT_CLIENT)
148  AC_SUBST(JVM_VARIANT_MINIMAL1)
149  AC_SUBST(JVM_VARIANT_KERNEL)
150  AC_SUBST(JVM_VARIANT_ZERO)
151  AC_SUBST(JVM_VARIANT_ZEROSHARK)
152  AC_SUBST(JVM_VARIANT_CORE)
153
154  INCLUDE_SA=true
155  if test "x$JVM_VARIANT_ZERO" = xtrue ; then
156    INCLUDE_SA=false
157  fi
158  if test "x$JVM_VARIANT_ZEROSHARK" = xtrue ; then
159    INCLUDE_SA=false
160  fi
161  if test "x$OPENJDK_TARGET_OS" = xaix ; then
162    INCLUDE_SA=false
163  fi
164  AC_SUBST(INCLUDE_SA)
165
166  if test "x$OPENJDK_TARGET_OS" = "xmacosx"; then
167    MACOSX_UNIVERSAL="true"
168  fi
169
170  AC_SUBST(MACOSX_UNIVERSAL)
171])
172
173AC_DEFUN_ONCE([JDKOPT_SETUP_DEBUG_LEVEL],
174[
175  ###############################################################################
176  #
177  # Set the debug level
178  #    release: no debug information, all optimizations, no asserts.
179  #    optimized: no debug information, all optimizations, no asserts, HotSpot target is 'optimized'.
180  #    fastdebug: debug information (-g), all optimizations, all asserts
181  #    slowdebug: debug information (-g), no optimizations, all asserts
182  #
183  DEBUG_LEVEL="release"
184  AC_MSG_CHECKING([which debug level to use])
185  AC_ARG_ENABLE([debug], [AS_HELP_STRING([--enable-debug],
186      [set the debug level to fastdebug (shorthand for --with-debug-level=fastdebug) @<:@disabled@:>@])],
187      [
188        ENABLE_DEBUG="${enableval}"
189        DEBUG_LEVEL="fastdebug"
190      ], [ENABLE_DEBUG="no"])
191
192  AC_ARG_WITH([debug-level], [AS_HELP_STRING([--with-debug-level],
193      [set the debug level (release, fastdebug, slowdebug, optimized (HotSpot build only)) @<:@release@:>@])],
194      [
195        DEBUG_LEVEL="${withval}"
196        if test "x$ENABLE_DEBUG" = xyes; then
197          AC_MSG_ERROR([You cannot use both --enable-debug and --with-debug-level at the same time.])
198        fi
199      ])
200  AC_MSG_RESULT([$DEBUG_LEVEL])
201
202  if test "x$DEBUG_LEVEL" != xrelease && \
203      test "x$DEBUG_LEVEL" != xoptimized && \
204      test "x$DEBUG_LEVEL" != xfastdebug && \
205      test "x$DEBUG_LEVEL" != xslowdebug; then
206    AC_MSG_ERROR([Allowed debug levels are: release, fastdebug and slowdebug])
207  fi
208
209
210  ###############################################################################
211  #
212  # Setup legacy vars/targets and new vars to deal with different debug levels.
213  #
214
215  case $DEBUG_LEVEL in
216    release )
217      VARIANT="OPT"
218      FASTDEBUG="false"
219      DEBUG_CLASSFILES="false"
220      BUILD_VARIANT_RELEASE=""
221      HOTSPOT_DEBUG_LEVEL="product"
222      HOTSPOT_EXPORT="product"
223      ;;
224    fastdebug )
225      VARIANT="DBG"
226      FASTDEBUG="true"
227      DEBUG_CLASSFILES="true"
228      BUILD_VARIANT_RELEASE="-fastdebug"
229      HOTSPOT_DEBUG_LEVEL="fastdebug"
230      HOTSPOT_EXPORT="fastdebug"
231      ;;
232    slowdebug )
233      VARIANT="DBG"
234      FASTDEBUG="false"
235      DEBUG_CLASSFILES="true"
236      BUILD_VARIANT_RELEASE="-debug"
237      HOTSPOT_DEBUG_LEVEL="debug"
238      HOTSPOT_EXPORT="debug"
239      ;;
240    optimized )
241      VARIANT="OPT"
242      FASTDEBUG="false"
243      DEBUG_CLASSFILES="false"
244      BUILD_VARIANT_RELEASE="-optimized"
245      HOTSPOT_DEBUG_LEVEL="optimized"
246      HOTSPOT_EXPORT="optimized"
247      ;;
248  esac
249
250  # The debug level 'optimized' is a little special because it is currently only
251  # applicable to the HotSpot build where it means to build a completely
252  # optimized version of the VM without any debugging code (like for the
253  # 'release' debug level which is called 'product' in the HotSpot build) but
254  # with the exception that it can contain additional code which is otherwise
255  # protected by '#ifndef PRODUCT' macros. These 'optimized' builds are used to
256  # test new and/or experimental features which are not intended for customer
257  # shipment. Because these new features need to be tested and benchmarked in
258  # real world scenarios, we want to build the containing JDK at the 'release'
259  # debug level.
260  if test "x$DEBUG_LEVEL" = xoptimized; then
261    DEBUG_LEVEL="release"
262  fi
263
264  #####
265  # Generate the legacy makefile targets for hotspot.
266  # The hotspot api for selecting the build artifacts, really, needs to be improved.
267  # JDK-7195896 will fix this on the hotspot side by using the JVM_VARIANT_* variables to
268  # determine what needs to be built. All we will need to set here is all_product, all_fastdebug etc
269  # But until then ...
270  HOTSPOT_TARGET=""
271
272  if test "x$JVM_VARIANT_SERVER" = xtrue; then
273    HOTSPOT_TARGET="$HOTSPOT_TARGET${HOTSPOT_DEBUG_LEVEL} "
274  fi
275
276  if test "x$JVM_VARIANT_CLIENT" = xtrue; then
277    HOTSPOT_TARGET="$HOTSPOT_TARGET${HOTSPOT_DEBUG_LEVEL}1 "
278  fi
279
280  if test "x$JVM_VARIANT_MINIMAL1" = xtrue; then
281    HOTSPOT_TARGET="$HOTSPOT_TARGET${HOTSPOT_DEBUG_LEVEL}minimal1 "
282  fi
283
284  if test "x$JVM_VARIANT_KERNEL" = xtrue; then
285    HOTSPOT_TARGET="$HOTSPOT_TARGET${HOTSPOT_DEBUG_LEVEL}kernel "
286  fi
287
288  if test "x$JVM_VARIANT_ZERO" = xtrue; then
289    HOTSPOT_TARGET="$HOTSPOT_TARGET${HOTSPOT_DEBUG_LEVEL}zero "
290  fi
291
292  if test "x$JVM_VARIANT_ZEROSHARK" = xtrue; then
293    HOTSPOT_TARGET="$HOTSPOT_TARGET${HOTSPOT_DEBUG_LEVEL}shark "
294  fi
295
296  if test "x$JVM_VARIANT_CORE" = xtrue; then
297    HOTSPOT_TARGET="$HOTSPOT_TARGET${HOTSPOT_DEBUG_LEVEL}core "
298  fi
299
300  HOTSPOT_TARGET="$HOTSPOT_TARGET docs export_$HOTSPOT_EXPORT"
301
302  # On Macosx universal binaries are produced, but they only contain
303  # 64 bit intel. This invalidates control of which jvms are built
304  # from configure, but only server is valid anyway. Fix this
305  # when hotspot makefiles are rewritten.
306  if test "x$MACOSX_UNIVERSAL" = xtrue; then
307    HOTSPOT_TARGET=universal_${HOTSPOT_EXPORT}
308  fi
309
310  #####
311
312  AC_SUBST(DEBUG_LEVEL)
313  AC_SUBST(VARIANT)
314  AC_SUBST(FASTDEBUG)
315  AC_SUBST(DEBUG_CLASSFILES)
316  AC_SUBST(BUILD_VARIANT_RELEASE)
317])
318
319
320###############################################################################
321#
322# Should we build only OpenJDK even if closed sources are present?
323#
324AC_DEFUN_ONCE([JDKOPT_SETUP_OPEN_OR_CUSTOM],
325[
326  AC_ARG_ENABLE([openjdk-only], [AS_HELP_STRING([--enable-openjdk-only],
327      [suppress building custom source even if present @<:@disabled@:>@])],,[enable_openjdk_only="no"])
328
329  AC_MSG_CHECKING([for presence of closed sources])
330  if test -d "$SRC_ROOT/jdk/src/closed"; then
331    CLOSED_SOURCE_PRESENT=yes
332  else
333    CLOSED_SOURCE_PRESENT=no
334  fi
335  AC_MSG_RESULT([$CLOSED_SOURCE_PRESENT])
336
337  AC_MSG_CHECKING([if closed source is suppressed (openjdk-only)])
338  SUPPRESS_CLOSED_SOURCE="$enable_openjdk_only"
339  AC_MSG_RESULT([$SUPPRESS_CLOSED_SOURCE])
340
341  if test "x$CLOSED_SOURCE_PRESENT" = xno; then
342    OPENJDK=true
343    if test "x$SUPPRESS_CLOSED_SOURCE" = "xyes"; then
344      AC_MSG_WARN([No closed source present, --enable-openjdk-only makes no sense])
345    fi
346  else
347    if test "x$SUPPRESS_CLOSED_SOURCE" = "xyes"; then
348      OPENJDK=true
349    else
350      OPENJDK=false
351    fi
352  fi
353
354  if test "x$OPENJDK" = "xtrue"; then
355    SET_OPENJDK="OPENJDK=true"
356  fi
357
358  AC_SUBST(SET_OPENJDK)
359
360  # custom-make-dir is deprecated. Please use your custom-hook.m4 to override
361  # the IncludeCustomExtension macro.
362  BASIC_DEPRECATED_ARG_WITH(custom-make-dir)
363])
364
365AC_DEFUN_ONCE([JDKOPT_SETUP_JDK_OPTIONS],
366[
367
368  ###############################################################################
369  #
370  # Should we build a JDK/JVM with headful support (ie a graphical ui)?
371  # We always build headless support.
372  #
373  AC_MSG_CHECKING([headful support])
374  AC_ARG_ENABLE([headful], [AS_HELP_STRING([--disable-headful],
375      [disable building headful support (graphical UI support) @<:@enabled@:>@])],
376      [SUPPORT_HEADFUL=${enable_headful}], [SUPPORT_HEADFUL=yes])
377
378  SUPPORT_HEADLESS=yes
379  BUILD_HEADLESS="BUILD_HEADLESS:=true"
380
381  if test "x$SUPPORT_HEADFUL" = xyes; then
382    # We are building both headful and headless.
383    headful_msg="include support for both headful and headless"
384  fi
385
386  if test "x$SUPPORT_HEADFUL" = xno; then
387    # Thus we are building headless only.
388    BUILD_HEADLESS="BUILD_HEADLESS:=true"
389    headful_msg="headless only"
390  fi
391
392  AC_MSG_RESULT([$headful_msg])
393
394  AC_SUBST(SUPPORT_HEADLESS)
395  AC_SUBST(SUPPORT_HEADFUL)
396  AC_SUBST(BUILD_HEADLESS)
397
398  # Control wether Hotspot runs Queens test after build.
399  AC_ARG_ENABLE([hotspot-test-in-build], [AS_HELP_STRING([--enable-hotspot-test-in-build],
400      [run the Queens test after Hotspot build @<:@disabled@:>@])],,
401      [enable_hotspot_test_in_build=no])
402  if test "x$enable_hotspot_test_in_build" = "xyes"; then
403    TEST_IN_BUILD=true
404  else
405    TEST_IN_BUILD=false
406  fi
407  AC_SUBST(TEST_IN_BUILD)
408
409  ###############################################################################
410  #
411  # Choose cacerts source file
412  #
413  AC_ARG_WITH(cacerts-file, [AS_HELP_STRING([--with-cacerts-file],
414      [specify alternative cacerts file])])
415  if test "x$with_cacerts_file" != x; then
416    CACERTS_FILE=$with_cacerts_file
417  fi
418  AC_SUBST(CACERTS_FILE)
419
420  ###############################################################################
421  #
422  # Enable or disable unlimited crypto
423  #
424  AC_ARG_ENABLE(unlimited-crypto, [AS_HELP_STRING([--enable-unlimited-crypto],
425      [Enable unlimited crypto policy @<:@disabled@:>@])],,
426      [enable_unlimited_crypto=no])
427  if test "x$enable_unlimited_crypto" = "xyes"; then
428    UNLIMITED_CRYPTO=true
429  else
430    UNLIMITED_CRYPTO=false
431  fi
432  AC_SUBST(UNLIMITED_CRYPTO)
433
434  ###############################################################################
435  #
436  # Enable or disable the elliptic curve crypto implementation
437  #
438  AC_DEFUN_ONCE([JDKOPT_DETECT_INTREE_EC],
439  [
440    AC_MSG_CHECKING([if elliptic curve crypto implementation is present])
441
442    if test -d "${SRC_ROOT}/jdk/src/jdk.crypto.ec/share/native/libsunec/impl"; then
443      ENABLE_INTREE_EC=yes
444      AC_MSG_RESULT([yes])
445    else
446      ENABLE_INTREE_EC=no
447      AC_MSG_RESULT([no])
448    fi
449
450    AC_SUBST(ENABLE_INTREE_EC)
451  ])
452
453  ###############################################################################
454  #
455  # --enable-rmiconnector-iiop
456  #
457  AC_ARG_ENABLE(rmiconnector-iiop, [AS_HELP_STRING([--enable-rmiconnector-iiop],
458      [enable the JMX RMIConnector iiop transport  @<:@disabled@:>@])])
459  if test "x$enable_rmiconnector_iiop" = "xyes"; then
460    RMICONNECTOR_IIOP=true
461  else
462    RMICONNECTOR_IIOP=false
463  fi
464  AC_SUBST(RMICONNECTOR_IIOP)
465
466  ###############################################################################
467  #
468  # Compress jars
469  #
470  COMPRESS_JARS=false
471
472  AC_SUBST(COMPRESS_JARS)
473])
474
475###############################################################################
476#
477# Setup version numbers
478#
479AC_DEFUN_ONCE([JDKOPT_SETUP_JDK_VERSION_NUMBERS],
480[
481  # Source the version numbers
482  . $AUTOCONF_DIR/version-numbers
483
484  # Get the settings from parameters
485  AC_ARG_WITH(milestone, [AS_HELP_STRING([--with-milestone],
486      [Set milestone value for build @<:@internal@:>@])])
487  if test "x$with_milestone" = xyes; then
488    AC_MSG_ERROR([Milestone must have a value])
489  elif test "x$with_milestone" != x; then
490    MILESTONE="$with_milestone"
491  fi
492  if test "x$MILESTONE" = x; then
493    MILESTONE=internal
494  fi
495
496  AC_ARG_WITH(update-version, [AS_HELP_STRING([--with-update-version],
497      [Set update version value for build @<:@b00@:>@])])
498  if test "x$with_update_version" = xyes; then
499    AC_MSG_ERROR([Update version must have a value])
500  elif test "x$with_update_version" != x; then
501    JDK_UPDATE_VERSION="$with_update_version"
502    # On macosx 10.7, it's not possible to set --with-update-version=0X due
503    # to a bug in expr (which reduces it to just X). To work around this, we
504    # always add a 0 to one digit update versions.
505    if test "${#JDK_UPDATE_VERSION}" = "1"; then
506      JDK_UPDATE_VERSION="0${JDK_UPDATE_VERSION}"
507    fi
508  fi
509
510  AC_ARG_WITH(user-release-suffix, [AS_HELP_STRING([--with-user-release-suffix],
511      [Add a custom string to the version string if build number is not set.@<:@username_builddateb00@:>@])])
512  if test "x$with_user_release_suffix" = xyes; then
513    AC_MSG_ERROR([Release suffix must have a value])
514  elif test "x$with_user_release_suffix" != x; then
515    USER_RELEASE_SUFFIX="$with_user_release_suffix"
516  fi
517
518  AC_ARG_WITH(build-number, [AS_HELP_STRING([--with-build-number],
519      [Set build number value for build @<:@b00@:>@])])
520  if test "x$with_build_number" = xyes; then
521    AC_MSG_ERROR([Build number must have a value])
522  elif test "x$with_build_number" != x; then
523    JDK_BUILD_NUMBER="$with_build_number"
524  fi
525  # Define default USER_RELEASE_SUFFIX if BUILD_NUMBER and USER_RELEASE_SUFFIX are not set
526  if test "x$JDK_BUILD_NUMBER" = x; then
527    JDK_BUILD_NUMBER=b00
528    if test "x$USER_RELEASE_SUFFIX" = x; then
529      BUILD_DATE=`date '+%Y_%m_%d_%H_%M'`
530      # Avoid [:alnum:] since it depends on the locale.
531      CLEAN_USERNAME=`echo "$USER" | $TR -d -c 'abcdefghijklmnopqrstuvwxyzABCDEFGHIJKLMNOPQRSTUVWXYZ0123456789'`
532      USER_RELEASE_SUFFIX=`echo "${CLEAN_USERNAME}_${BUILD_DATE}" | $TR 'ABCDEFGHIJKLMNOPQRSTUVWXYZ' 'abcdefghijklmnopqrstuvwxyz'`
533    fi
534  fi
535
536  # Now set the JDK version, milestone, build number etc.
537  AC_SUBST(USER_RELEASE_SUFFIX)
538  AC_SUBST(JDK_MAJOR_VERSION)
539  AC_SUBST(JDK_MINOR_VERSION)
540  AC_SUBST(JDK_MICRO_VERSION)
541  AC_SUBST(JDK_UPDATE_VERSION)
542  AC_SUBST(JDK_BUILD_NUMBER)
543  AC_SUBST(MILESTONE)
544  AC_SUBST(LAUNCHER_NAME)
545  AC_SUBST(PRODUCT_NAME)
546  AC_SUBST(PRODUCT_SUFFIX)
547  AC_SUBST(JDK_RC_PLATFORM_NAME)
548  AC_SUBST(COMPANY_NAME)
549  AC_SUBST(MACOSX_BUNDLE_NAME_BASE)
550  AC_SUBST(MACOSX_BUNDLE_ID_BASE)
551
552  AC_ARG_WITH(copyright-year, [AS_HELP_STRING([--with-copyright-year],
553      [Set copyright year value for build @<:@current year@:>@])])
554  if test "x$with_copyright_year" = xyes; then
555    AC_MSG_ERROR([Copyright year must have a value])
556  elif test "x$with_copyright_year" != x; then
557    COPYRIGHT_YEAR="$with_copyright_year"
558  else
559    COPYRIGHT_YEAR=`date +'%Y'`
560  fi
561  AC_SUBST(COPYRIGHT_YEAR)
562
563  if test "x$JDK_UPDATE_VERSION" != x; then
564    JDK_VERSION="${JDK_MAJOR_VERSION}.${JDK_MINOR_VERSION}.${JDK_MICRO_VERSION}_${JDK_UPDATE_VERSION}"
565  else
566    JDK_VERSION="${JDK_MAJOR_VERSION}.${JDK_MINOR_VERSION}.${JDK_MICRO_VERSION}"
567  fi
568  AC_SUBST(JDK_VERSION)
569
570  COOKED_BUILD_NUMBER=`$ECHO $JDK_BUILD_NUMBER | $SED -e 's/^b//' -e 's/^0//'`
571  AC_SUBST(COOKED_BUILD_NUMBER)
572])
573
574AC_DEFUN_ONCE([JDKOPT_SETUP_BUILD_TWEAKS],
575[
576  HOTSPOT_MAKE_ARGS="$HOTSPOT_TARGET"
577  AC_SUBST(HOTSPOT_MAKE_ARGS)
578
579  # The name of the Service Agent jar.
580  SALIB_NAME="${LIBRARY_PREFIX}saproc${SHARED_LIBRARY_SUFFIX}"
581  if test "x$OPENJDK_TARGET_OS" = "xwindows"; then
582    SALIB_NAME="${LIBRARY_PREFIX}sawindbg${SHARED_LIBRARY_SUFFIX}"
583  fi
584  AC_SUBST(SALIB_NAME)
585])
586
587AC_DEFUN_ONCE([JDKOPT_SETUP_DEBUG_SYMBOLS],
588[
589  #
590  # ENABLE_DEBUG_SYMBOLS
591  # This must be done after the toolchain is setup, since we're looking at objcopy.
592  #
593  AC_ARG_ENABLE([debug-symbols],
594      [AS_HELP_STRING([--disable-debug-symbols],[disable generation of debug symbols @<:@enabled@:>@])])
595
596  AC_MSG_CHECKING([if we should generate debug symbols])
597
598  if test "x$enable_debug_symbols" = "xyes" && test "x$OBJCOPY" = x; then
599    # explicit enabling of enable-debug-symbols and can't find objcopy
600    #   this is an error
601    AC_MSG_ERROR([Unable to find objcopy, cannot enable debug-symbols])
602  fi
603
604  if test "x$enable_debug_symbols" = "xyes"; then
605    ENABLE_DEBUG_SYMBOLS=true
606  elif test "x$enable_debug_symbols" = "xno"; then
607    ENABLE_DEBUG_SYMBOLS=false
608  else
609    # Default is on if objcopy is found
610    if test "x$OBJCOPY" != x; then
611      ENABLE_DEBUG_SYMBOLS=true
612    # MacOS X and Windows don't use objcopy but default is on for those OSes
613    elif test "x$OPENJDK_TARGET_OS" = xmacosx || test "x$OPENJDK_TARGET_OS" = xwindows; then
614      ENABLE_DEBUG_SYMBOLS=true
615    else
616      ENABLE_DEBUG_SYMBOLS=false
617    fi
618  fi
619
620  AC_MSG_RESULT([$ENABLE_DEBUG_SYMBOLS])
621
622  #
623  # ZIP_DEBUGINFO_FILES
624  #
625  AC_MSG_CHECKING([if we should zip debug-info files])
626  AC_ARG_ENABLE([zip-debug-info],
627      [AS_HELP_STRING([--disable-zip-debug-info],[disable zipping of debug-info files @<:@enabled@:>@])],
628      [enable_zip_debug_info="${enableval}"], [enable_zip_debug_info="yes"])
629  AC_MSG_RESULT([${enable_zip_debug_info}])
630
631  if test "x${enable_zip_debug_info}" = "xno"; then
632    ZIP_DEBUGINFO_FILES=false
633  else
634    ZIP_DEBUGINFO_FILES=true
635  fi
636
637  AC_SUBST(ENABLE_DEBUG_SYMBOLS)
638  AC_SUBST(ZIP_DEBUGINFO_FILES)
639])
640