hotspot.m4 revision 2065:559c65fe6b56
1#
2# Copyright (c) 2011, 2016, Oracle and/or its affiliates. All rights reserved.
3# DO NOT ALTER OR REMOVE COPYRIGHT NOTICES OR THIS FILE HEADER.
4#
5# This code is free software; you can redistribute it and/or modify it
6# under the terms of the GNU General Public License version 2 only, as
7# published by the Free Software Foundation.  Oracle designates this
8# particular file as subject to the "Classpath" exception as provided
9# by Oracle in the LICENSE file that accompanied this code.
10#
11# This code is distributed in the hope that it will be useful, but WITHOUT
12# ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
13# FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License
14# version 2 for more details (a copy is included in the LICENSE file that
15# accompanied this code).
16#
17# You should have received a copy of the GNU General Public License version
18# 2 along with this work; if not, write to the Free Software Foundation,
19# Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301 USA.
20#
21# Please contact Oracle, 500 Oracle Parkway, Redwood Shores, CA 94065 USA
22# or visit www.oracle.com if you need additional information or have any
23# questions.
24#
25
26# All valid JVM features, regardless of platform
27VALID_JVM_FEATURES="compiler1 compiler2 zero shark minimal dtrace jvmti jvmci \
28    fprof vm-structs jni-check services management all-gcs nmt cds static-build"
29
30# All valid JVM variants
31VALID_JVM_VARIANTS="server client minimal core zero zeroshark custom"
32
33###############################################################################
34# Check if the specified JVM variant should be built. To be used in shell if
35# constructs, like this:
36# if HOTSPOT_CHECK_JVM_VARIANT(server); then
37#
38# Only valid to use after HOTSPOT_SETUP_JVM_VARIANTS has setup variants.
39
40# Definition kept in one line to allow inlining in if statements.
41# Additional [] needed to keep m4 from mangling shell constructs.
42AC_DEFUN([HOTSPOT_CHECK_JVM_VARIANT],
43[ [ [[ " $JVM_VARIANTS " =~ " $1 " ]] ] ])
44
45###############################################################################
46# Check if the specified JVM features are explicitly enabled. To be used in
47# shell if constructs, like this:
48# if HOTSPOT_CHECK_JVM_FEATURE(jvmti); then
49#
50# Only valid to use after HOTSPOT_SETUP_JVM_FEATURES has setup features.
51
52# Definition kept in one line to allow inlining in if statements.
53# Additional [] needed to keep m4 from mangling shell constructs.
54AC_DEFUN([HOTSPOT_CHECK_JVM_FEATURE],
55[ [ [[ " $JVM_FEATURES " =~ " $1 " ]] ] ])
56
57###############################################################################
58# Check which variants of the JVM that we want to build. Available variants are:
59#   server: normal interpreter, and a tiered C1/C2 compiler
60#   client: normal interpreter, and C1 (no C2 compiler)
61#   minimal: reduced form of client with optional features stripped out
62#   core: normal interpreter only, no compiler
63#   zero: C++ based interpreter only, no compiler
64#   zeroshark: C++ based interpreter, and a llvm-based compiler
65#   custom: baseline JVM with no default features
66#
67AC_DEFUN_ONCE([HOTSPOT_SETUP_JVM_VARIANTS],
68[
69  AC_ARG_WITH([jvm-variants], [AS_HELP_STRING([--with-jvm-variants],
70      [JVM variants (separated by commas) to build (server,client,minimal,core,zero,zeroshark,custom) @<:@server@:>@])])
71
72  if test "x$with_jvm_variants" = x; then
73    with_jvm_variants="server"
74  fi
75  JVM_VARIANTS_OPT="$with_jvm_variants"
76
77  # Has the user listed more than one variant?
78  # Additional [] needed to keep m4 from mangling shell constructs.
79  if [ [[ "$JVM_VARIANTS_OPT" =~ "," ]] ]; then
80    BUILDING_MULTIPLE_JVM_VARIANTS=true
81  else
82    BUILDING_MULTIPLE_JVM_VARIANTS=false
83  fi
84  # Replace the commas with AND for use in the build directory name.
85  JVM_VARIANTS_WITH_AND=`$ECHO "$JVM_VARIANTS_OPT" | $SED -e 's/,/AND/g'`
86
87  AC_MSG_CHECKING([which variants of the JVM to build])
88  # JVM_VARIANTS is a space-separated list.
89  # Also use minimal, not minimal1 (which is kept for backwards compatibility).
90  JVM_VARIANTS=`$ECHO $JVM_VARIANTS_OPT | $SED -e 's/,/ /g' -e 's/minimal1/minimal/'`
91  AC_MSG_RESULT([$JVM_VARIANTS])
92
93  # Check that the selected variants are valid
94
95  # grep filter function inspired by a comment to http://stackoverflow.com/a/1617326
96  # Notice that the original variant failes on SLES 10 and 11
97  NEEDLE=${VALID_JVM_VARIANTS// /$'\n'}
98  STACK=${JVM_VARIANTS// /$'\n'}
99  INVALID_VARIANTS=`$GREP -Fvx "${NEEDLE}" <<< "${STACK}"`
100  if test "x$INVALID_VARIANTS" != x; then
101    AC_MSG_NOTICE([Unknown variant(s) specified: $INVALID_VARIANTS])
102    AC_MSG_ERROR([The available JVM variants are: $VALID_JVM_VARIANTS])
103  fi
104
105  # All "special" variants share the same output directory ("server")
106  VALID_MULTIPLE_JVM_VARIANTS="server client minimal"
107  NEEDLE=${VALID_MULTIPLE_JVM_VARIANTS// /$'\n'}
108  STACK=${JVM_VARIANTS// /$'\n'}
109  INVALID_MULTIPLE_VARIANTS=`$GREP -Fvx "${NEEDLE}" <<< "${STACK}"`
110  if  test "x$INVALID_MULTIPLE_VARIANTS" != x && test "x$BUILDING_MULTIPLE_JVM_VARIANTS" = xtrue; then
111    AC_MSG_ERROR([You cannot build multiple variants with anything else than $VALID_MULTIPLE_JVM_VARIANTS.])
112  fi
113
114  AC_SUBST(JVM_VARIANTS)
115  AC_SUBST(VALID_JVM_VARIANTS)
116
117  if HOTSPOT_CHECK_JVM_VARIANT(zero) || HOTSPOT_CHECK_JVM_VARIANT(zeroshark); then
118    # zero behaves as a platform and rewrites these values. This is really weird. :(
119    # We are guaranteed that we do not build any other variants when building zero.
120    HOTSPOT_TARGET_CPU=zero
121    HOTSPOT_TARGET_CPU_ARCH=zero
122  fi
123])
124
125###############################################################################
126# Check if dtrace should be enabled and has all prerequisites present.
127#
128AC_DEFUN_ONCE([HOTSPOT_SETUP_DTRACE],
129[
130  # Test for dtrace dependencies
131  AC_ARG_ENABLE([dtrace], [AS_HELP_STRING([--enable-dtrace@<:@=yes/no/auto@:>@],
132      [enable dtrace. Default is auto, where dtrace is enabled if all dependencies
133      are present.])])
134
135  DTRACE_DEP_MISSING=false
136
137  AC_MSG_CHECKING([for dtrace tool])
138  if test "x$DTRACE" != "x" && test -x "$DTRACE"; then
139    AC_MSG_RESULT([$DTRACE])
140  else
141    AC_MSG_RESULT([not found, cannot build dtrace])
142    DTRACE_DEP_MISSING=true
143  fi
144
145  AC_CHECK_HEADERS([sys/sdt.h], [DTRACE_HEADERS_OK=yes],[DTRACE_HEADERS_OK=no])
146  if test "x$DTRACE_HEADERS_OK" != "xyes"; then
147    DTRACE_DEP_MISSING=true
148  fi
149
150  AC_MSG_CHECKING([if dtrace should be built])
151  if test "x$enable_dtrace" = "xyes"; then
152    if test "x$DTRACE_DEP_MISSING" = "xtrue"; then
153      AC_MSG_RESULT([no, missing dependencies])
154      HELP_MSG_MISSING_DEPENDENCY([dtrace])
155      AC_MSG_ERROR([Cannot enable dtrace with missing dependencies. See above. $HELP_MSG])
156    else
157      INCLUDE_DTRACE=true
158      AC_MSG_RESULT([yes, forced])
159    fi
160  elif test "x$enable_dtrace" = "xno"; then
161    INCLUDE_DTRACE=false
162    AC_MSG_RESULT([no, forced])
163  elif test "x$enable_dtrace" = "xauto" || test "x$enable_dtrace" = "x"; then
164    if test "x$OPENJDK_TARGET_OS" = "xlinux" && test "x$OPENJDK" != "xtrue"; then
165      INCLUDE_DTRACE=false
166      AC_MSG_RESULT([no, non-open linux build])
167    elif test "x$DTRACE_DEP_MISSING" = "xtrue"; then
168      INCLUDE_DTRACE=false
169      AC_MSG_RESULT([no, missing dependencies])
170    else
171      INCLUDE_DTRACE=true
172      AC_MSG_RESULT([yes, dependencies present])
173    fi
174  else
175    AC_MSG_ERROR([Invalid value for --enable-dtrace: $enable_dtrace])
176  fi
177  AC_SUBST(INCLUDE_DTRACE)
178])
179
180###############################################################################
181# Set up all JVM features for each JVM variant.
182#
183AC_DEFUN_ONCE([HOTSPOT_SETUP_JVM_FEATURES],
184[
185  # The user can in some cases supply additional jvm features. For the custom
186  # variant, this defines the entire variant.
187  AC_ARG_WITH([jvm-features], [AS_HELP_STRING([--with-jvm-features],
188      [additional JVM features to enable (separated by comma),  use '--help' to show possible values @<:@none@:>@])])
189  if test "x$with_jvm_features" != x; then
190    AC_MSG_CHECKING([additional JVM features])
191    JVM_FEATURES=`$ECHO $with_jvm_features | $SED -e 's/,/ /g'`
192    AC_MSG_RESULT([$JVM_FEATURES])
193  fi
194
195  # Verify that dependencies are met for explicitly set features.
196  if HOTSPOT_CHECK_JVM_FEATURE(jvmti) && ! HOTSPOT_CHECK_JVM_FEATURE(services); then
197    AC_MSG_ERROR([Specified JVM feature 'jvmti' requires feature 'services'])
198  fi
199
200  if HOTSPOT_CHECK_JVM_FEATURE(management) && ! HOTSPOT_CHECK_JVM_FEATURE(nmt); then
201    AC_MSG_ERROR([Specified JVM feature 'management' requires feature 'nmt'])
202  fi
203
204  if HOTSPOT_CHECK_JVM_FEATURE(jvmci) && ! HOTSPOT_CHECK_JVM_FEATURE(compiler2); then
205    AC_MSG_ERROR([Specified JVM feature 'jvmci' requires feature 'compiler2'])
206  fi
207
208  if HOTSPOT_CHECK_JVM_FEATURE(compiler2) && ! HOTSPOT_CHECK_JVM_FEATURE(all-gcs); then
209    AC_MSG_ERROR([Specified JVM feature 'compiler2' requires feature 'all-gcs'])
210  fi
211
212  if HOTSPOT_CHECK_JVM_FEATURE(vm-structs) && ! HOTSPOT_CHECK_JVM_FEATURE(all-gcs); then
213    AC_MSG_ERROR([Specified JVM feature 'vm-structs' requires feature 'all-gcs'])
214  fi
215
216  # Turn on additional features based on other parts of configure
217  if test "x$INCLUDE_DTRACE" = "xtrue"; then
218    JVM_FEATURES="$JVM_FEATURES dtrace"
219  else
220    if HOTSPOT_CHECK_JVM_FEATURE(dtrace); then
221      AC_MSG_ERROR([To enable dtrace, you must use --enable-dtrace])
222    fi
223  fi
224
225  if test "x$STATIC_BUILD" = "xtrue"; then
226    JVM_FEATURES="$JVM_FEATURES static-build"
227  else
228    if HOTSPOT_CHECK_JVM_FEATURE(static-build); then
229      AC_MSG_ERROR([To enable static-build, you must use --enable-static-build])
230    fi
231  fi
232
233  if ! HOTSPOT_CHECK_JVM_VARIANT(zero) && ! HOTSPOT_CHECK_JVM_VARIANT(zeroshark); then
234    if HOTSPOT_CHECK_JVM_FEATURE(zero); then
235      AC_MSG_ERROR([To enable zero/zeroshark, you must use --with-jvm-variants=zero/zeroshark])
236    fi
237  fi
238
239  if ! HOTSPOT_CHECK_JVM_VARIANT(zeroshark); then
240    if HOTSPOT_CHECK_JVM_FEATURE(shark); then
241      AC_MSG_ERROR([To enable shark, you must use --with-jvm-variants=zeroshark])
242    fi
243  fi
244
245  # Only enable jvmci on x86_64, sparcv9 and aarch64, and only on server.
246  if test "x$OPENJDK_TARGET_CPU" = "xx86_64" || \
247      test "x$OPENJDK_TARGET_CPU" = "xsparcv9" || \
248      test "x$OPENJDK_TARGET_CPU" = "xaarch64" ; then
249    JVM_FEATURES_jvmci="jvmci"
250  else
251    JVM_FEATURES_jvmci=""
252  fi
253
254  # All variants but minimal (and custom) get these features
255  NON_MINIMAL_FEATURES="$NON_MINIMAL_FEATURES jvmti fprof vm-structs jni-check services management all-gcs nmt cds"
256
257  # Enable features depending on variant.
258  JVM_FEATURES_server="compiler1 compiler2 $NON_MINIMAL_FEATURES $JVM_FEATURES $JVM_FEATURES_jvmci"
259  JVM_FEATURES_client="compiler1 $NON_MINIMAL_FEATURES $JVM_FEATURES"
260  JVM_FEATURES_core="$NON_MINIMAL_FEATURES $JVM_FEATURES"
261  JVM_FEATURES_minimal="compiler1 minimal $JVM_FEATURES"
262  JVM_FEATURES_zero="zero $NON_MINIMAL_FEATURES $JVM_FEATURES"
263  JVM_FEATURES_zeroshark="zero shark $NON_MINIMAL_FEATURES $JVM_FEATURES"
264  JVM_FEATURES_custom="$JVM_FEATURES"
265
266  AC_SUBST(JVM_FEATURES_server)
267  AC_SUBST(JVM_FEATURES_client)
268  AC_SUBST(JVM_FEATURES_core)
269  AC_SUBST(JVM_FEATURES_minimal)
270  AC_SUBST(JVM_FEATURES_zero)
271  AC_SUBST(JVM_FEATURES_zeroshark)
272  AC_SUBST(JVM_FEATURES_custom)
273
274  # Used for verification of Makefiles by check-jvm-feature
275  AC_SUBST(VALID_JVM_FEATURES)
276
277  # We don't support --with-jvm-interpreter anymore, use zero instead.
278  BASIC_DEPRECATED_ARG_WITH(jvm-interpreter)
279])
280
281###############################################################################
282# Validate JVM features once all setup is complete, including custom setup.
283#
284AC_DEFUN_ONCE([HOTSPOT_VALIDATE_JVM_FEATURES],
285[
286  # Keep feature lists sorted and free of duplicates
287  JVM_FEATURES_server="$($ECHO $($PRINTF '%s\n' $JVM_FEATURES_server | $SORT -u))"
288  JVM_FEATURES_client="$($ECHO $($PRINTF '%s\n' $JVM_FEATURES_client | $SORT -u))"
289  JVM_FEATURES_core="$($ECHO $($PRINTF '%s\n' $JVM_FEATURES_core | $SORT -u))"
290  JVM_FEATURES_minimal="$($ECHO $($PRINTF '%s\n' $JVM_FEATURES_minimal | $SORT -u))"
291  JVM_FEATURES_zero="$($ECHO $($PRINTF '%s\n' $JVM_FEATURES_zero | $SORT -u))"
292  JVM_FEATURES_zeroshark="$($ECHO $($PRINTF '%s\n' $JVM_FEATURES_zeroshark | $SORT -u))"
293  JVM_FEATURES_custom="$($ECHO $($PRINTF '%s\n' $JVM_FEATURES_custom | $SORT -u))"
294
295  # Validate features
296  for variant in $JVM_VARIANTS; do
297    AC_MSG_CHECKING([JVM features for JVM variant '$variant'])
298    features_var_name=JVM_FEATURES_$variant
299    JVM_FEATURES_TO_TEST=${!features_var_name}
300    AC_MSG_RESULT([$JVM_FEATURES_TO_TEST])
301    NEEDLE=${VALID_JVM_FEATURES// /$'\n'}
302    STACK=${JVM_FEATURES_TO_TEST// /$'\n'}
303    INVALID_FEATURES=`$GREP -Fvx "${NEEDLE}" <<< "${STACK}"`
304    if test "x$INVALID_FEATURES" != x; then
305      AC_MSG_ERROR([Invalid JVM feature(s): $INVALID_FEATURES])
306    fi
307  done
308])
309
310###############################################################################
311# Support for old hotspot build. Remove once new hotspot build has proven
312# to work satisfactory.
313#
314AC_DEFUN_ONCE([HOTSPOT_SETUP_LEGACY_BUILD],
315[
316  AC_ARG_ENABLE(new-hotspot-build, [AS_HELP_STRING([--disable-new-hotspot-build],
317      [disable the new hotspot build system (use the old) @<:@enabled@:>@])])
318
319   if test "x$enable_new_hotspot_build" = "x" || test "x$enable_new_hotspot_build" = "xyes"; then
320     USE_NEW_HOTSPOT_BUILD=true
321   else
322     USE_NEW_HOTSPOT_BUILD=false
323   fi
324  AC_SUBST(USE_NEW_HOTSPOT_BUILD)
325
326  case $HOTSPOT_DEBUG_LEVEL in
327    product )
328      VARIANT="OPT"
329      FASTDEBUG="false"
330      DEBUG_CLASSFILES="false"
331      ;;
332    fastdebug )
333      VARIANT="DBG"
334      FASTDEBUG="true"
335      DEBUG_CLASSFILES="true"
336      ;;
337    debug )
338      VARIANT="DBG"
339      FASTDEBUG="false"
340      DEBUG_CLASSFILES="true"
341      ;;
342    optimized )
343      VARIANT="OPT"
344      FASTDEBUG="false"
345      DEBUG_CLASSFILES="false"
346      ;;
347  esac
348  AC_SUBST(VARIANT)
349  AC_SUBST(FASTDEBUG)
350  AC_SUBST(DEBUG_CLASSFILES)
351
352  if test "x$OPENJDK_TARGET_OS" = "xmacosx"; then
353    MACOSX_UNIVERSAL="true"
354  fi
355
356  AC_SUBST(MACOSX_UNIVERSAL)
357
358  # Make sure JVM_VARIANTS_COMMA use minimal1 for backwards compatibility
359  JVM_VARIANTS_COMMA=`$ECHO ,$JVM_VARIANTS_OPT, | $SED -e 's/,minimal,/,minimal1,/'`
360
361  JVM_VARIANT_SERVER=`$ECHO "$JVM_VARIANTS_COMMA" | $SED -e '/,server,/!s/.*/false/g' -e '/,server,/s/.*/true/g'`
362  JVM_VARIANT_CLIENT=`$ECHO "$JVM_VARIANTS_COMMA" | $SED -e '/,client,/!s/.*/false/g' -e '/,client,/s/.*/true/g'`
363  JVM_VARIANT_MINIMAL1=`$ECHO "$JVM_VARIANTS_COMMA" | $SED -e '/,minimal1\?,/!s/.*/false/g' -e '/,minimal1\?,/s/.*/true/g'`
364  JVM_VARIANT_CORE=`$ECHO "$JVM_VARIANTS_COMMA" | $SED -e '/,core,/!s/.*/false/g' -e '/,core,/s/.*/true/g'`
365  JVM_VARIANT_ZERO=`$ECHO "$JVM_VARIANTS_COMMA" | $SED -e '/,zero,/!s/.*/false/g' -e '/,zero,/s/.*/true/g'`
366  JVM_VARIANT_ZEROSHARK=`$ECHO "$JVM_VARIANTS_COMMA" | $SED -e '/,zeroshark,/!s/.*/false/g' -e '/,zeroshark,/s/.*/true/g'`
367  JVM_VARIANT_CUSTOM=`$ECHO "$JVM_VARIANTS_COMMA" | $SED -e '/,custom,/!s/.*/false/g' -e '/,custom,/s/.*/true/g'`
368
369  #####
370  # Generate the legacy makefile targets for hotspot.
371  HOTSPOT_TARGET=""
372
373  if test "x$JVM_VARIANT_SERVER" = xtrue; then
374    HOTSPOT_TARGET="$HOTSPOT_TARGET${HOTSPOT_DEBUG_LEVEL} "
375  fi
376
377  if test "x$JVM_VARIANT_CLIENT" = xtrue; then
378    HOTSPOT_TARGET="$HOTSPOT_TARGET${HOTSPOT_DEBUG_LEVEL}1 "
379  fi
380
381  if test "x$JVM_VARIANT_MINIMAL1" = xtrue; then
382    HOTSPOT_TARGET="$HOTSPOT_TARGET${HOTSPOT_DEBUG_LEVEL}minimal1 "
383  fi
384
385  if test "x$JVM_VARIANT_ZERO" = xtrue; then
386    HOTSPOT_TARGET="$HOTSPOT_TARGET${HOTSPOT_DEBUG_LEVEL}zero "
387  fi
388
389  if test "x$JVM_VARIANT_ZEROSHARK" = xtrue; then
390    HOTSPOT_TARGET="$HOTSPOT_TARGET${HOTSPOT_DEBUG_LEVEL}shark "
391  fi
392
393  if test "x$JVM_VARIANT_CORE" = xtrue; then
394    HOTSPOT_TARGET="$HOTSPOT_TARGET${HOTSPOT_DEBUG_LEVEL}core "
395  fi
396
397  HOTSPOT_TARGET="$HOTSPOT_TARGET docs export_$HOTSPOT_DEBUG_LEVEL"
398
399  # On Macosx universal binaries are produced, but they only contain
400  # 64 bit intel. This invalidates control of which jvms are built
401  # from configure, but only server is valid anyway. Fix this
402  # when hotspot makefiles are rewritten.
403  if test "x$MACOSX_UNIVERSAL" = xtrue; then
404    HOTSPOT_TARGET=universal_${HOTSPOT_DEBUG_LEVEL}
405  fi
406
407  HOTSPOT_MAKE_ARGS="$HOTSPOT_TARGET"
408  AC_SUBST(HOTSPOT_MAKE_ARGS)
409
410  # Control wether Hotspot runs Queens test after build.
411  AC_ARG_ENABLE([hotspot-test-in-build], [AS_HELP_STRING([--enable-hotspot-test-in-build],
412      [run the Queens test after Hotspot build @<:@disabled@:>@])],,
413      [enable_hotspot_test_in_build=no])
414  if test "x$enable_hotspot_test_in_build" = "xyes"; then
415    TEST_IN_BUILD=true
416  else
417    TEST_IN_BUILD=false
418  fi
419  AC_SUBST(TEST_IN_BUILD)
420
421  if test "x$USE_NEW_HOTSPOT_BUILD" = xfalse; then
422    if test "x$JVM_VARIANT_CLIENT" = xtrue; then
423      if test "x$OPENJDK_TARGET_CPU_BITS" = x64; then
424        AC_MSG_ERROR([You cannot build a client JVM for a 64-bit machine.])
425      fi
426    fi
427    if test "x$JVM_VARIANT_MINIMAL1" = xtrue; then
428      if test "x$OPENJDK_TARGET_CPU_BITS" = x64; then
429        AC_MSG_ERROR([You cannot build a minimal JVM for a 64-bit machine.])
430      fi
431    fi
432    if test "x$JVM_VARIANT_CUSTOM" = xtrue; then
433        AC_MSG_ERROR([You cannot build a custom JVM using the old hotspot build system.])
434    fi
435  fi
436
437  AC_SUBST(JVM_VARIANTS_COMMA)
438  AC_SUBST(JVM_VARIANT_SERVER)
439  AC_SUBST(JVM_VARIANT_CLIENT)
440  AC_SUBST(JVM_VARIANT_MINIMAL1)
441  AC_SUBST(JVM_VARIANT_HOTSPOT)
442  AC_SUBST(JVM_VARIANT_ZERO)
443  AC_SUBST(JVM_VARIANT_ZEROSHARK)
444  AC_SUBST(JVM_VARIANT_CORE)
445])
446