flags.m4 revision 1076:26ba036c46fc 
1#
2# Copyright (c) 2011, 2014, Oracle and/or its affiliates. All rights reserved.
3# DO NOT ALTER OR REMOVE COPYRIGHT NOTICES OR THIS FILE HEADER.
4#
5# This code is free software; you can redistribute it and/or modify it
6# under the terms of the GNU General Public License version 2 only, as
7# published by the Free Software Foundation.  Oracle designates this
8# particular file as subject to the "Classpath" exception as provided
9# by Oracle in the LICENSE file that accompanied this code.
10#
11# This code is distributed in the hope that it will be useful, but WITHOUT
12# ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
13# FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License
14# version 2 for more details (a copy is included in the LICENSE file that
15# accompanied this code).
16#
17# You should have received a copy of the GNU General Public License version
18# 2 along with this work; if not, write to the Free Software Foundation,
19# Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301 USA.
20#
21# Please contact Oracle, 500 Oracle Parkway, Redwood Shores, CA 94065 USA
22# or visit www.oracle.com if you need additional information or have any
23# questions.
24#
25
26AC_DEFUN_ONCE([FLAGS_SETUP_INIT_FLAGS],
27[
28  # Option used to tell the compiler whether to create 32- or 64-bit executables
29  if test "x$TOOLCHAIN_TYPE" = xxlc; then
30    COMPILER_TARGET_BITS_FLAG="-q"
31  else
32    COMPILER_TARGET_BITS_FLAG="-m"
33  fi
34  AC_SUBST(COMPILER_TARGET_BITS_FLAG)
35
36  # FIXME: figure out if we should select AR flags depending on OS or toolchain.
37  if test "x$OPENJDK_TARGET_OS" = xmacosx; then
38    ARFLAGS="-r"
39  elif test "x$OPENJDK_TARGET_OS" = xaix; then
40    ARFLAGS="-X64"
41  elif test "x$OPENJDK_TARGET_OS" = xwindows; then
42    # lib.exe is used as AR to create static libraries.
43    ARFLAGS="-nologo -NODEFAULTLIB:MSVCRT"
44  else
45    ARFLAGS=""
46  fi
47  AC_SUBST(ARFLAGS)
48
49  ## Setup strip.
50  # FIXME: should this really be per platform, or should it be per toolchain type?
51  # strip is not provided by clang or solstudio; so guessing platform makes most sense.
52  # FIXME: we should really only export STRIPFLAGS from here, not POST_STRIP_CMD.
53  if test "x$OPENJDK_TARGET_OS" = xlinux; then
54    STRIPFLAGS="-g"
55  elif test "x$OPENJDK_TARGET_OS" = xsolaris; then
56    STRIPFLAGS="-x"
57  elif test "x$OPENJDK_TARGET_OS" = xmacosx; then
58    STRIPFLAGS="-S"
59  elif test "x$OPENJDK_TARGET_OS" = xaix; then
60    STRIPFLAGS="-X32_64"
61  fi
62
63  if test "x$OPENJDK_TARGET_OS" != xwindows; then
64    POST_STRIP_CMD="$STRIP $STRIPFLAGS"
65  fi
66  AC_SUBST(POST_STRIP_CMD)
67
68  if test "x$OPENJDK_TARGET_OS" = xsolaris; then
69    # FIXME: break out into MCSFLAGS
70    POST_MCS_CMD="$MCS -d -a \"JDK $FULL_VERSION\""
71  fi
72  AC_SUBST(POST_MCS_CMD)
73
74  if test "x$TOOLCHAIN_TYPE" = xmicrosoft; then
75    CC_OUT_OPTION=-Fo
76    EXE_OUT_OPTION=-out:
77    LD_OUT_OPTION=-out:
78    AR_OUT_OPTION=-out:
79  else
80    # The option used to specify the target .o,.a or .so file.
81    # When compiling, how to specify the to be created object file.
82    CC_OUT_OPTION='-o$(SPACE)'
83    # When linking, how to specify the to be created executable.
84    EXE_OUT_OPTION='-o$(SPACE)'
85    # When linking, how to specify the to be created dynamically linkable library.
86    LD_OUT_OPTION='-o$(SPACE)'
87    # When archiving, how to specify the to be create static archive for object files.
88    AR_OUT_OPTION='rcs$(SPACE)'
89  fi
90  AC_SUBST(CC_OUT_OPTION)
91  AC_SUBST(EXE_OUT_OPTION)
92  AC_SUBST(LD_OUT_OPTION)
93  AC_SUBST(AR_OUT_OPTION)
94
95  # On Windows, we need to set RC flags.
96  if test "x$TOOLCHAIN_TYPE" = xmicrosoft; then
97    RC_FLAGS="-nologo -l 0x409 -r"
98    if test "x$VARIANT" = xOPT; then
99      RC_FLAGS="$RC_FLAGS -d NDEBUG"
100    fi
101
102    # The version variables used to create RC_FLAGS may be overridden
103    # in a custom configure script, or possibly the command line.
104    # Let those variables be expanded at make time in spec.gmk.
105    # The \$ are escaped to the shell, and the $(...) variables
106    # are evaluated by make.
107    RC_FLAGS="$RC_FLAGS \
108        -d \"JDK_BUILD_ID=\$(FULL_VERSION)\" \
109        -d \"JDK_COMPANY=\$(COMPANY_NAME)\" \
110        -d \"JDK_COMPONENT=\$(PRODUCT_NAME) \$(JDK_RC_PLATFORM_NAME) binary\" \
111        -d \"JDK_VER=\$(JDK_MINOR_VERSION).\$(JDK_MICRO_VERSION).\$(if \$(JDK_UPDATE_VERSION),\$(JDK_UPDATE_VERSION),0).\$(COOKED_BUILD_NUMBER)\" \
112        -d \"JDK_COPYRIGHT=Copyright \xA9 $COPYRIGHT_YEAR\" \
113        -d \"JDK_NAME=\$(PRODUCT_NAME) \$(JDK_RC_PLATFORM_NAME) \$(JDK_MINOR_VERSION) \$(JDK_UPDATE_META_TAG)\" \
114        -d \"JDK_FVER=\$(JDK_MINOR_VERSION),\$(JDK_MICRO_VERSION),\$(if \$(JDK_UPDATE_VERSION),\$(JDK_UPDATE_VERSION),0),\$(COOKED_BUILD_NUMBER)\""
115  fi
116  AC_SUBST(RC_FLAGS)
117
118  if test "x$TOOLCHAIN_TYPE" = xmicrosoft; then
119    # silence copyright notice and other headers.
120    COMMON_CCXXFLAGS="$COMMON_CCXXFLAGS -nologo"
121  fi
122
123  if test "x$SYSROOT" != "x"; then
124    if test "x$TOOLCHAIN_TYPE" = xsolstudio; then
125      if test "x$OPENJDK_TARGET_OS" = xsolaris; then
126        # Solaris Studio does not have a concept of sysroot. Instead we must
127        # make sure the default include and lib dirs are appended to each
128        # compile and link command line.
129        SYSROOT_CFLAGS="-I$SYSROOT/usr/include"
130        SYSROOT_LDFLAGS="-L$SYSROOT/usr/lib$OPENJDK_TARGET_CPU_ISADIR \
131            -L$SYSROOT/lib$OPENJDK_TARGET_CPU_ISADIR \
132            -L$SYSROOT/usr/ccs/lib$OPENJDK_TARGET_CPU_ISADIR"
133      fi
134    elif test "x$OPENJDK_TARGET_OS" = xmacosx; then
135      # Apple only wants -isysroot <path>, but we also need -iframework<path>/System/Library/Frameworks
136      SYSROOT_CFLAGS="-isysroot \"$SYSROOT\" -iframework\"$SYSROOT/System/Library/Frameworks\""
137      SYSROOT_LDFLAGS=$SYSROOT_CFLAGS
138    elif test "x$TOOLCHAIN_TYPE" = xgcc; then
139      SYSROOT_CFLAGS="--sysroot=\"$SYSROOT\""
140      SYSROOT_LDFLAGS="--sysroot=\"$SYSROOT\""
141    elif test "x$TOOLCHAIN_TYPE" = xclang; then
142      SYSROOT_CFLAGS="-isysroot \"$SYSROOT\""
143      SYSROOT_LDFLAGS="-isysroot \"$SYSROOT\""
144    fi
145    # Propagate the sysroot args to hotspot
146    LEGACY_EXTRA_CFLAGS="$LEGACY_EXTRA_CFLAGS $SYSROOT_CFLAGS"
147    LEGACY_EXTRA_CXXFLAGS="$LEGACY_EXTRA_CXXFLAGS $SYSROOT_CFLAGS"
148    LEGACY_EXTRA_LDFLAGS="$LEGACY_EXTRA_LDFLAGS $SYSROOT_LDFLAGS"
149  fi
150
151  # These always need to be set, or we can't find the frameworks embedded in JavaVM.framework
152  # set this here so it doesn't have to be peppered throughout the forest
153  if test "x$OPENJDK_TARGET_OS" = xmacosx; then
154    SYSROOT_CFLAGS="$SYSROOT_CFLAGS -F\"$SYSROOT/System/Library/Frameworks/JavaVM.framework/Frameworks\""
155    SYSROOT_LDFLAGS="$SYSROOT_LDFLAGS -F\"$SYSROOT/System/Library/Frameworks/JavaVM.framework/Frameworks\""
156  fi
157
158  AC_SUBST(SYSROOT_CFLAGS)
159  AC_SUBST(SYSROOT_LDFLAGS)
160])
161
162AC_DEFUN_ONCE([FLAGS_SETUP_COMPILER_FLAGS_FOR_LIBS],
163[
164  ###############################################################################
165  #
166  # How to compile shared libraries.
167  #
168
169  if test "x$TOOLCHAIN_TYPE" = xgcc; then
170    PICFLAG="-fPIC"
171    C_FLAG_REORDER=''
172    CXX_FLAG_REORDER=''
173
174    if test "x$OPENJDK_TARGET_OS" = xmacosx; then
175      # Linking is different on MacOSX
176      SHARED_LIBRARY_FLAGS="-dynamiclib -compatibility_version 1.0.0 -current_version 1.0.0 $PICFLAG"
177      SET_EXECUTABLE_ORIGIN='-Xlinker -rpath -Xlinker @loader_path/.'
178      SET_SHARED_LIBRARY_ORIGIN="$SET_EXECUTABLE_ORIGIN"
179      SET_SHARED_LIBRARY_NAME='-Xlinker -install_name -Xlinker @rpath/[$]1'
180      SET_SHARED_LIBRARY_MAPFILE=''
181    else
182      # Default works for linux, might work on other platforms as well.
183      SHARED_LIBRARY_FLAGS='-shared'
184      SET_EXECUTABLE_ORIGIN='-Xlinker -rpath -Xlinker \$$$$ORIGIN[$]1'
185      SET_SHARED_LIBRARY_ORIGIN="-Xlinker -z -Xlinker origin $SET_EXECUTABLE_ORIGIN"
186      SET_SHARED_LIBRARY_NAME='-Xlinker -soname=[$]1'
187      SET_SHARED_LIBRARY_MAPFILE='-Xlinker -version-script=[$]1'
188    fi
189  elif test "x$TOOLCHAIN_TYPE" = xclang; then
190    PICFLAG=''
191    C_FLAG_REORDER=''
192    CXX_FLAG_REORDER=''
193
194    if test "x$OPENJDK_TARGET_OS" = xmacosx; then
195      # Linking is different on MacOSX
196      SHARED_LIBRARY_FLAGS="-dynamiclib -compatibility_version 1.0.0 -current_version 1.0.0 $PICFLAG"
197      SET_EXECUTABLE_ORIGIN='-Xlinker -rpath -Xlinker @loader_path/.'
198      SET_SHARED_LIBRARY_ORIGIN="$SET_EXECUTABLE_ORIGIN"
199      SET_SHARED_LIBRARY_NAME='-Xlinker -install_name -Xlinker @rpath/[$]1'
200      SET_SHARED_LIBRARY_MAPFILE=''
201    else
202      # Default works for linux, might work on other platforms as well.
203      SHARED_LIBRARY_FLAGS='-shared'
204      SET_EXECUTABLE_ORIGIN='-Xlinker -rpath -Xlinker \$$$$ORIGIN[$]1'
205      SET_SHARED_LIBRARY_ORIGIN="-Xlinker -z -Xlinker origin $SET_EXECUTABLE_ORIGIN"
206      SET_SHARED_LIBRARY_NAME='-Xlinker -soname=[$]1'
207      SET_SHARED_LIBRARY_MAPFILE='-Xlinker -version-script=[$]1'
208    fi
209  elif test "x$TOOLCHAIN_TYPE" = xsolstudio; then
210    PICFLAG="-KPIC"
211    C_FLAG_REORDER='-xF'
212    CXX_FLAG_REORDER='-xF'
213    SHARED_LIBRARY_FLAGS="-G"
214    SET_EXECUTABLE_ORIGIN='-R\$$$$ORIGIN[$]1'
215    SET_SHARED_LIBRARY_ORIGIN="$SET_EXECUTABLE_ORIGIN"
216    SET_SHARED_LIBRARY_NAME=''
217    SET_SHARED_LIBRARY_MAPFILE='-M[$]1'
218  elif test "x$TOOLCHAIN_TYPE" = xxlc; then
219    PICFLAG="-qpic=large"
220    C_FLAG_REORDER=''
221    CXX_FLAG_REORDER=''
222    SHARED_LIBRARY_FLAGS="-qmkshrobj"
223    SET_EXECUTABLE_ORIGIN=""
224    SET_SHARED_LIBRARY_ORIGIN=''
225    SET_SHARED_LIBRARY_NAME=''
226    SET_SHARED_LIBRARY_MAPFILE=''
227  elif test "x$TOOLCHAIN_TYPE" = xmicrosoft; then
228    PICFLAG=""
229    C_FLAG_REORDER=''
230    CXX_FLAG_REORDER=''
231    SHARED_LIBRARY_FLAGS="-LD"
232    SET_EXECUTABLE_ORIGIN=''
233    SET_SHARED_LIBRARY_ORIGIN=''
234    SET_SHARED_LIBRARY_NAME=''
235    SET_SHARED_LIBRARY_MAPFILE=''
236  fi
237
238  AC_SUBST(C_FLAG_REORDER)
239  AC_SUBST(CXX_FLAG_REORDER)
240  AC_SUBST(SHARED_LIBRARY_FLAGS)
241  AC_SUBST(SET_EXECUTABLE_ORIGIN)
242  AC_SUBST(SET_SHARED_LIBRARY_ORIGIN)
243  AC_SUBST(SET_SHARED_LIBRARY_NAME)
244  AC_SUBST(SET_SHARED_LIBRARY_MAPFILE)
245
246  if test "x$OPENJDK_TARGET_OS" = xsolaris; then
247    CFLAGS_JDK="${CFLAGS_JDK} -D__solaris__"
248    CXXFLAGS_JDK="${CXXFLAGS_JDK} -D__solaris__"
249    CFLAGS_JDKLIB_EXTRA='-xstrconst'
250  fi
251  # The (cross) compiler is now configured, we can now test capabilities
252  # of the target platform.
253])
254
255# Documentation on common flags used for solstudio in HIGHEST.
256#
257# WARNING: Use of OPTIMIZATION_LEVEL=HIGHEST in your Makefile needs to be
258#          done with care, there are some assumptions below that need to
259#          be understood about the use of pointers, and IEEE behavior.
260#
261# -fns: Use non-standard floating point mode (not IEEE 754)
262# -fsimple: Do some simplification of floating point arithmetic (not IEEE 754)
263# -fsingle: Use single precision floating point with 'float'
264# -xalias_level=basic: Assume memory references via basic pointer types do not alias
265#   (Source with excessing pointer casting and data access with mixed
266#    pointer types are not recommended)
267# -xbuiltin=%all: Use intrinsic or inline versions for math/std functions
268#   (If you expect perfect errno behavior, do not use this)
269# -xdepend: Loop data dependency optimizations (need -xO3 or higher)
270# -xrestrict: Pointer parameters to functions do not overlap
271#   (Similar to -xalias_level=basic usage, but less obvious sometimes.
272#    If you pass in multiple pointers to the same data, do not use this)
273# -xlibmil: Inline some library routines
274#   (If you expect perfect errno behavior, do not use this)
275# -xlibmopt: Use optimized math routines (CURRENTLY DISABLED)
276#   (If you expect perfect errno behavior, do not use this)
277#  Can cause undefined external on Solaris 8 X86 on __sincos, removing for now
278
279    # FIXME: this will never happen since sparc != sparcv9, ie 32 bit, which we don't build anymore.
280    # Bug?
281    #if test "x$OPENJDK_TARGET_CPU" = xsparc; then
282    #  CFLAGS_JDK="${CFLAGS_JDK} -xmemalign=4s"
283    #  CXXFLAGS_JDK="${CXXFLAGS_JDK} -xmemalign=4s"
284    #fi
285
286AC_DEFUN_ONCE([FLAGS_SETUP_COMPILER_FLAGS_FOR_OPTIMIZATION],
287[
288
289  ###############################################################################
290  #
291  # Setup the opt flags for different compilers
292  # and different operating systems.
293  #
294
295  # FIXME: this was indirectly the old default, but just inherited.
296  # if test "x$TOOLCHAIN_TYPE" = xmicrosoft; then
297  #   C_FLAG_DEPS="-MMD -MF"
298  # fi
299
300  # Generate make dependency files
301  if test "x$TOOLCHAIN_TYPE" = xgcc; then
302    C_FLAG_DEPS="-MMD -MF"
303  elif test "x$TOOLCHAIN_TYPE" = xclang; then
304    C_FLAG_DEPS="-MMD -MF"
305  elif test "x$TOOLCHAIN_TYPE" = xsolstudio; then
306    C_FLAG_DEPS="-xMMD -xMF"
307  elif test "x$TOOLCHAIN_TYPE" = xxlc; then
308    C_FLAG_DEPS="-qmakedep=gcc -MF"
309  fi
310  CXX_FLAG_DEPS="$C_FLAG_DEPS"
311  AC_SUBST(C_FLAG_DEPS)
312  AC_SUBST(CXX_FLAG_DEPS)
313
314  # Debug symbols
315  if test "x$TOOLCHAIN_TYPE" = xgcc; then
316    if test "x$OPENJDK_TARGET_CPU_BITS" = "x64" && test "x$DEBUG_LEVEL" = "xfastdebug"; then
317      # reduce from default "-g2" option to save space
318      CFLAGS_DEBUG_SYMBOLS="-g1"
319      CXXFLAGS_DEBUG_SYMBOLS="-g1"
320    else
321      CFLAGS_DEBUG_SYMBOLS="-g"
322      CXXFLAGS_DEBUG_SYMBOLS="-g"
323    fi
324  elif test "x$TOOLCHAIN_TYPE" = xclang; then
325    CFLAGS_DEBUG_SYMBOLS="-g"
326    CXXFLAGS_DEBUG_SYMBOLS="-g"
327  elif test "x$TOOLCHAIN_TYPE" = xsolstudio; then
328    CFLAGS_DEBUG_SYMBOLS="-g -xs"
329    # FIXME: likely a bug, this disables debug symbols rather than enables them
330    CXXFLAGS_DEBUG_SYMBOLS="-g0 -xs"
331  elif test "x$TOOLCHAIN_TYPE" = xxlc; then
332    CFLAGS_DEBUG_SYMBOLS="-g"
333    CXXFLAGS_DEBUG_SYMBOLS="-g"
334  fi
335  AC_SUBST(CFLAGS_DEBUG_SYMBOLS)
336  AC_SUBST(CXXFLAGS_DEBUG_SYMBOLS)
337
338  # bounds, memory and behavior checking options
339  if test "x$TOOLCHAIN_TYPE" = xgcc; then
340    case $DEBUG_LEVEL in
341    release )
342      # no adjustment
343      ;;
344    fastdebug )
345      # Add compile time bounds checks.
346      CFLAGS_DEBUG_OPTIONS="-U_FORTIFY_SOURCE -D_FORTIFY_SOURCE=1"
347      CXXFLAGS_DEBUG_OPTIONS="-U_FORTIFY_SOURCE -D_FORTIFY_SOURCE=1"
348      ;;
349    slowdebug )
350      # Add runtime bounds checks and symbol info.
351      CFLAGS_DEBUG_OPTIONS="-U_FORTIFY_SOURCE -D_FORTIFY_SOURCE=2 -fstack-protector-all --param ssp-buffer-size=1"
352      CXXFLAGS_DEBUG_OPTIONS="-U_FORTIFY_SOURCE -D_FORTIFY_SOURCE=2 -fstack-protector-all --param ssp-buffer-size=1"
353      if test "x$HAS_CFLAG_DETECT_UNDEFINED_BEHAVIOR" = "xtrue"; then
354        CFLAGS_DEBUG_OPTIONS="$CFLAGS_DEBUG_OPTIONS  $CFLAG_DETECT_UNDEFINED_BEHAVIOR_FLAG"
355        CXXFLAGS_DEBUG_OPTIONS="$CXXFLAGS_DEBUG_OPTIONS $CFLAG_DETECT_UNDEFINED_BEHAVIOR_FLAG"
356      fi
357      ;;
358    esac
359  fi
360  AC_SUBST(CFLAGS_DEBUG_OPTIONS)
361  AC_SUBST(CXXFLAGS_DEBUG_OPTIONS)
362
363  # Optimization levels
364  if test "x$TOOLCHAIN_TYPE" = xsolstudio; then
365    CC_HIGHEST="$CC_HIGHEST -fns -fsimple -fsingle -xbuiltin=%all -xdepend -xrestrict -xlibmil"
366
367    if test "x$OPENJDK_TARGET_CPU_ARCH" = "xx86"; then
368      # FIXME: seems we always set -xregs=no%frameptr; put it elsewhere more global?
369      C_O_FLAG_HIGHEST="-xO4 -Wu,-O4~yz $CC_HIGHEST -xalias_level=basic -xregs=no%frameptr"
370      C_O_FLAG_HI="-xO4 -Wu,-O4~yz -xregs=no%frameptr"
371      C_O_FLAG_NORM="-xO2 -Wu,-O2~yz -xregs=no%frameptr"
372      C_O_FLAG_DEBUG="-xregs=no%frameptr"
373      C_O_FLAG_NONE="-xregs=no%frameptr"
374      CXX_O_FLAG_HIGHEST="-xO4 -Qoption ube -O4~yz $CC_HIGHEST -xregs=no%frameptr"
375      CXX_O_FLAG_HI="-xO4 -Qoption ube -O4~yz -xregs=no%frameptr"
376      CXX_O_FLAG_NORM="-xO2 -Qoption ube -O2~yz -xregs=no%frameptr"
377      CXX_O_FLAG_DEBUG="-xregs=no%frameptr"
378      CXX_O_FLAG_NONE="-xregs=no%frameptr"
379      if test "x$OPENJDK_TARGET_CPU_BITS" = "x32"; then
380        C_O_FLAG_HIGHEST="$C_O_FLAG_HIGHEST -xchip=pentium"
381        CXX_O_FLAG_HIGHEST="$CXX_O_FLAG_HIGHEST -xchip=pentium"
382      fi
383    elif test "x$OPENJDK_TARGET_CPU_ARCH" = "xsparc"; then
384      C_O_FLAG_HIGHEST="-xO4 -Wc,-Qrm-s -Wc,-Qiselect-T0 $CC_HIGHEST -xalias_level=basic -xprefetch=auto,explicit -xchip=ultra"
385      C_O_FLAG_HI="-xO4 -Wc,-Qrm-s -Wc,-Qiselect-T0"
386      C_O_FLAG_NORM="-xO2 -Wc,-Qrm-s -Wc,-Qiselect-T0"
387      C_O_FLAG_DEBUG=""
388      C_O_FLAG_NONE=""
389      CXX_O_FLAG_HIGHEST="-xO4 -Qoption cg -Qrm-s -Qoption cg -Qiselect-T0 $CC_HIGHEST -xprefetch=auto,explicit -xchip=ultra"
390      CXX_O_FLAG_HI="-xO4 -Qoption cg -Qrm-s -Qoption cg -Qiselect-T0"
391      CXX_O_FLAG_NORM="-xO2 -Qoption cg -Qrm-s -Qoption cg -Qiselect-T0"
392      C_O_FLAG_DEBUG=""
393      CXX_O_FLAG_NONE=""
394    fi
395  else
396    # The remaining toolchains share opt flags between CC and CXX;
397    # setup for C and duplicate afterwards.
398    if test "x$TOOLCHAIN_TYPE" = xgcc; then
399      if test "x$OPENJDK_TARGET_OS" = xmacosx; then
400        # On MacOSX we optimize for size, something
401        # we should do for all platforms?
402        C_O_FLAG_HIGHEST="-Os"
403        C_O_FLAG_HI="-Os"
404        C_O_FLAG_NORM="-Os"
405      else
406        C_O_FLAG_HIGHEST="-O3"
407        C_O_FLAG_HI="-O3"
408        C_O_FLAG_NORM="-O2"
409      fi
410      if test "x$HAS_CFLAG_OPTIMIZE_DEBUG" = "xtrue"; then
411        C_O_FLAG_DEBUG="$CFLAG_OPTIMIZE_DEBUG_FLAG"
412      else
413        C_O_FLAG_DEBUG="-O0"
414      fi
415      C_O_FLAG_NONE="-O0"
416    elif test "x$TOOLCHAIN_TYPE" = xclang; then
417      if test "x$OPENJDK_TARGET_OS" = xmacosx; then
418        # On MacOSX we optimize for size, something
419        # we should do for all platforms?
420        C_O_FLAG_HIGHEST="-Os"
421        C_O_FLAG_HI="-Os"
422        C_O_FLAG_NORM="-Os"
423      else
424        C_O_FLAG_HIGHEST="-O3"
425        C_O_FLAG_HI="-O3"
426        C_O_FLAG_NORM="-O2"
427      fi
428      C_O_FLAG_DEBUG="-O0"
429      C_O_FLAG_NONE="-O0"
430    elif test "x$TOOLCHAIN_TYPE" = xxlc; then
431      C_O_FLAG_HIGHEST="-O3"
432      C_O_FLAG_HI="-O3 -qstrict"
433      C_O_FLAG_NORM="-O2"
434      C_O_FLAG_DEBUG="-qnoopt"
435      C_O_FLAG_NONE="-qnoop"
436    elif test "x$TOOLCHAIN_TYPE" = xmicrosoft; then
437      C_O_FLAG_HIGHEST="-O2"
438      C_O_FLAG_HI="-O1"
439      C_O_FLAG_NORM="-O1"
440      C_O_FLAG_DEBUG="-Od"
441      C_O_FLAG_NONE="-Od"
442    fi
443    CXX_O_FLAG_HIGHEST="$C_O_FLAG_HIGHEST"
444    CXX_O_FLAG_HI="$C_O_FLAG_HI"
445    CXX_O_FLAG_NORM="$C_O_FLAG_NORM"
446    CXX_O_FLAG_DEBUG="$C_O_FLAG_DEBUG"
447    CXX_O_FLAG_NONE="$C_O_FLAG_NONE"
448  fi
449
450  # Adjust optimization flags according to debug level.
451  case $DEBUG_LEVEL in
452    release )
453      # no adjustment
454      ;;
455    fastdebug )
456      # Not quite so much optimization
457      C_O_FLAG_HI="$C_O_FLAG_NORM"
458      CXX_O_FLAG_HI="$CXX_O_FLAG_NORM"
459      ;;
460    slowdebug )
461      # Disable optimization
462      C_O_FLAG_HIGHEST="$C_O_FLAG_DEBUG"
463      C_O_FLAG_HI="$C_O_FLAG_DEBUG"
464      C_O_FLAG_NORM="$C_O_FLAG_DEBUG"
465      CXX_O_FLAG_HIGHEST="$CXX_O_FLAG_DEBUG"
466      CXX_O_FLAG_HI="$CXX_O_FLAG_DEBUG"
467      CXX_O_FLAG_NORM="$CXX_O_FLAG_DEBUG"
468      ;;
469  esac
470
471  AC_SUBST(C_O_FLAG_HIGHEST)
472  AC_SUBST(C_O_FLAG_HI)
473  AC_SUBST(C_O_FLAG_NORM)
474  AC_SUBST(C_O_FLAG_DEBUG)
475  AC_SUBST(C_O_FLAG_NONE)
476  AC_SUBST(CXX_O_FLAG_HIGHEST)
477  AC_SUBST(CXX_O_FLAG_HI)
478  AC_SUBST(CXX_O_FLAG_NORM)
479  AC_SUBST(CXX_O_FLAG_DEBUG)
480  AC_SUBST(CXX_O_FLAG_NONE)
481])
482
483AC_DEFUN_ONCE([FLAGS_SETUP_COMPILER_FLAGS_FOR_JDK],
484[
485  # Special extras...
486  if test "x$TOOLCHAIN_TYPE" = xsolstudio; then
487    if test "x$OPENJDK_TARGET_CPU_ARCH" = "xsparc"; then
488      CFLAGS_JDKLIB_EXTRA="${CFLAGS_JDKLIB_EXTRA} -xregs=no%appl"
489      CXXFLAGS_JDKLIB_EXTRA="${CXXFLAGS_JDKLIB_EXTRA} -xregs=no%appl"
490    fi
491  elif test "x$TOOLCHAIN_TYPE" = xxlc; then
492    LDFLAGS_JDK="${LDFLAGS_JDK} -q64 -brtl -bnolibpath -liconv -bexpall"
493    CFLAGS_JDK="${CFLAGS_JDK} -qchars=signed -q64 -qfullpath -qsaveopt"
494    CXXFLAGS_JDK="${CXXFLAGS_JDK} -qchars=signed -q64 -qfullpath -qsaveopt"
495  fi
496
497  if test "x$CFLAGS" != "x${ADDED_CFLAGS}"; then
498    AC_MSG_WARN([Ignoring CFLAGS($CFLAGS) found in environment. Use --with-extra-cflags])
499  fi
500
501  if test "x$CXXFLAGS" != "x${ADDED_CXXFLAGS}"; then
502    AC_MSG_WARN([Ignoring CXXFLAGS($CXXFLAGS) found in environment. Use --with-extra-cxxflags])
503  fi
504
505  if test "x$LDFLAGS" != "x${ADDED_LDFLAGS}"; then
506    AC_MSG_WARN([Ignoring LDFLAGS($LDFLAGS) found in environment. Use --with-extra-ldflags])
507  fi
508
509  AC_ARG_WITH(extra-cflags, [AS_HELP_STRING([--with-extra-cflags],
510      [extra flags to be used when compiling jdk c-files])])
511
512  AC_ARG_WITH(extra-cxxflags, [AS_HELP_STRING([--with-extra-cxxflags],
513      [extra flags to be used when compiling jdk c++-files])])
514
515  AC_ARG_WITH(extra-ldflags, [AS_HELP_STRING([--with-extra-ldflags],
516      [extra flags to be used when linking jdk])])
517
518  CFLAGS_JDK="${CFLAGS_JDK} $with_extra_cflags"
519  CXXFLAGS_JDK="${CXXFLAGS_JDK} $with_extra_cxxflags"
520  LDFLAGS_JDK="${LDFLAGS_JDK} $with_extra_ldflags"
521
522  # Hotspot needs these set in their legacy form
523  LEGACY_EXTRA_CFLAGS="$LEGACY_EXTRA_CFLAGS $with_extra_cflags"
524  LEGACY_EXTRA_CXXFLAGS="$LEGACY_EXTRA_CXXFLAGS $with_extra_cxxflags"
525  LEGACY_EXTRA_LDFLAGS="$LEGACY_EXTRA_LDFLAGS $with_extra_ldflags"
526
527  AC_SUBST(LEGACY_EXTRA_CFLAGS)
528  AC_SUBST(LEGACY_EXTRA_CXXFLAGS)
529  AC_SUBST(LEGACY_EXTRA_LDFLAGS)
530
531  ###############################################################################
532  #
533  # Now setup the CFLAGS and LDFLAGS for the JDK build.
534  # Later we will also have CFLAGS and LDFLAGS for the hotspot subrepo build.
535  #
536
537  # Setup compiler/platform specific flags into
538  #    CFLAGS_JDK    - C Compiler flags
539  #    CXXFLAGS_JDK  - C++ Compiler flags
540  #    COMMON_CCXXFLAGS_JDK - common to C and C++
541  if test "x$TOOLCHAIN_TYPE" = xgcc; then
542    COMMON_CCXXFLAGS_JDK="$COMMON_CCXXFLAGS $COMMON_CCXXFLAGS_JDK -Wall -Wno-parentheses -Wextra -Wno-unused -Wno-unused-parameter -Wformat=2 \
543        -pipe -D_GNU_SOURCE -D_REENTRANT -D_LARGEFILE64_SOURCE"
544    case $OPENJDK_TARGET_CPU_ARCH in
545      arm )
546        # on arm we don't prevent gcc to omit frame pointer but do prevent strict aliasing
547        CFLAGS_JDK="${CFLAGS_JDK} -fno-strict-aliasing"
548        ;;
549      ppc )
550        # on ppc we don't prevent gcc to omit frame pointer but do prevent strict aliasing
551        CFLAGS_JDK="${CFLAGS_JDK} -fno-strict-aliasing"
552        ;;
553      * )
554        COMMON_CCXXFLAGS_JDK="$COMMON_CCXXFLAGS_JDK -fno-omit-frame-pointer"
555        CFLAGS_JDK="${CFLAGS_JDK} -fno-strict-aliasing"
556        ;;
557    esac
558  elif test "x$TOOLCHAIN_TYPE" = xsolstudio; then
559    COMMON_CCXXFLAGS_JDK="$COMMON_CCXXFLAGS $COMMON_CCXXFLAGS_JDK -DTRACING -DMACRO_MEMSYS_OPS -DBREAKPTS"
560    if test "x$OPENJDK_TARGET_CPU_ARCH" = xx86; then
561      COMMON_CCXXFLAGS_JDK="$COMMON_CCXXFLAGS_JDK -DcpuIntel -Di586 -D$OPENJDK_TARGET_CPU_LEGACY_LIB"
562      CFLAGS_JDK="$CFLAGS_JDK -erroff=E_BAD_PRAGMA_PACK_VALUE"
563    fi
564
565    CFLAGS_JDK="$CFLAGS_JDK -xc99=%none -xCC -errshort=tags -Xa -v -mt -W0,-noglobal"
566    CXXFLAGS_JDK="$CXXFLAGS_JDK -errtags=yes +w -mt -features=no%except -DCC_NOEX -norunpath -xnolib"
567  elif test "x$TOOLCHAIN_TYPE" = xxlc; then
568    CFLAGS_JDK="$CFLAGS_JDK -D_GNU_SOURCE -D_REENTRANT -D_LARGEFILE64_SOURCE -DSTDC"
569    CXXFLAGS_JDK="$CXXFLAGS_JDK -D_GNU_SOURCE -D_REENTRANT -D_LARGEFILE64_SOURCE -DSTDC"
570  elif test "x$TOOLCHAIN_TYPE" = xmicrosoft; then
571    COMMON_CCXXFLAGS_JDK="$COMMON_CCXXFLAGS $COMMON_CCXXFLAGS_JDK -Zi -MD -Zc:wchar_t- -W3 -wd4800 \
572    -D_STATIC_CPPLIB -D_DISABLE_DEPRECATE_STATIC_CPPLIB -DWIN32_LEAN_AND_MEAN \
573    -D_CRT_SECURE_NO_DEPRECATE -D_CRT_NONSTDC_NO_DEPRECATE \
574    -DWIN32 -DIAL"
575    if test "x$OPENJDK_TARGET_CPU" = xx86_64; then
576      COMMON_CCXXFLAGS_JDK="$COMMON_CCXXFLAGS_JDK -D_AMD64_ -Damd64"
577    else
578      COMMON_CCXXFLAGS_JDK="$COMMON_CCXXFLAGS_JDK -D_X86_ -Dx86"
579    fi
580  fi
581
582  ###############################################################################
583
584  # Adjust flags according to debug level.
585  case $DEBUG_LEVEL in
586    fastdebug | slowdebug )
587      CFLAGS_JDK="$CFLAGS_JDK $CFLAGS_DEBUG_SYMBOLS $CFLAGS_DEBUG_OPTIONS"
588      CXXFLAGS_JDK="$CXXFLAGS_JDK $CXXFLAGS_DEBUG_SYMBOLS $CXXFLAGS_DEBUG_OPTIONS"
589      JAVAC_FLAGS="$JAVAC_FLAGS -g"
590      ;;
591    release )
592      ;;
593    * )
594      AC_MSG_ERROR([Unrecognized \$DEBUG_LEVEL: $DEBUG_LEVEL])
595      ;;
596  esac
597
598  # Setup LP64
599  COMMON_CCXXFLAGS_JDK="$COMMON_CCXXFLAGS_JDK $ADD_LP64"
600
601  # Set some common defines. These works for all compilers, but assume
602  # -D is universally accepted.
603
604  # Setup endianness
605  if test "x$OPENJDK_TARGET_CPU_ENDIAN" = xlittle; then
606    # The macro _LITTLE_ENDIAN needs to be defined the same to avoid the
607    #   Sun C compiler warning message: warning: macro redefined: _LITTLE_ENDIAN
608    #   (The Solaris X86 system defines this in file /usr/include/sys/isa_defs.h).
609    #   Note: -Dmacro         is the same as    #define macro 1
610    #         -Dmacro=        is the same as    #define macro
611    if test "x$OPENJDK_TARGET_OS" = xsolaris; then
612      COMMON_CCXXFLAGS_JDK="$COMMON_CCXXFLAGS_JDK -D_LITTLE_ENDIAN="
613    else
614      COMMON_CCXXFLAGS_JDK="$COMMON_CCXXFLAGS_JDK -D_LITTLE_ENDIAN"
615    fi
616  else
617    # Same goes for _BIG_ENDIAN. Do we really need to set *ENDIAN on Solaris if they
618    # are defined in the system?
619    if test "x$OPENJDK_TARGET_OS" = xsolaris; then
620      COMMON_CCXXFLAGS_JDK="$COMMON_CCXXFLAGS_JDK -D_BIG_ENDIAN="
621    else
622      COMMON_CCXXFLAGS_JDK="$COMMON_CCXXFLAGS_JDK -D_BIG_ENDIAN"
623    fi
624  fi
625
626  # Setup target OS define. Use OS target name but in upper case.
627  OPENJDK_TARGET_OS_UPPERCASE=`$ECHO $OPENJDK_TARGET_OS | $TR 'abcdefghijklmnopqrstuvwxyz' 'ABCDEFGHIJKLMNOPQRSTUVWXYZ'`
628  COMMON_CCXXFLAGS_JDK="$COMMON_CCXXFLAGS_JDK -D$OPENJDK_TARGET_OS_UPPERCASE"
629
630  # Setup target CPU
631  COMMON_CCXXFLAGS_JDK="$COMMON_CCXXFLAGS_JDK -DARCH='\"$OPENJDK_TARGET_CPU_LEGACY\"' -D$OPENJDK_TARGET_CPU_LEGACY"
632
633  # Setup debug/release defines
634  if test "x$DEBUG_LEVEL" = xrelease; then
635    COMMON_CCXXFLAGS_JDK="$COMMON_CCXXFLAGS_JDK -DNDEBUG"
636    if test "x$OPENJDK_TARGET_OS" = xsolaris; then
637      COMMON_CCXXFLAGS_JDK="$COMMON_CCXXFLAGS_JDK -DTRIMMED"
638    fi
639  else
640    COMMON_CCXXFLAGS_JDK="$COMMON_CCXXFLAGS_JDK -DDEBUG"
641  fi
642
643  # Setup release name
644  COMMON_CCXXFLAGS_JDK="$COMMON_CCXXFLAGS_JDK -DRELEASE='\"\$(RELEASE)\"'"
645
646
647  # Set some additional per-OS defines.
648  if test "x$OPENJDK_TARGET_OS" = xmacosx; then
649    COMMON_CCXXFLAGS_JDK="$COMMON_CCXXFLAGS_JDK -D_ALLBSD_SOURCE -D_DARWIN_UNLIMITED_SELECT"
650  elif test "x$OPENJDK_TARGET_OS" = xaix; then
651    # FIXME: PPC64 should not be here.
652    COMMON_CCXXFLAGS_JDK="$COMMON_CCXXFLAGS_JDK -DPPC64"
653  elif test "x$OPENJDK_TARGET_OS" = xbsd; then
654    COMMON_CCXXFLAGS_JDK="$COMMON_CCXXFLAGS_JDK -D_ALLBSD_SOURCE"
655  fi
656
657  # Additional macosx handling
658  if test "x$OPENJDK_TARGET_OS" = xmacosx; then
659    # Setting these parameters makes it an error to link to macosx APIs that are
660    # newer than the given OS version and makes the linked binaries compatible
661    # even if built on a newer version of the OS.
662    # The expected format is X.Y.Z
663    MACOSX_VERSION_MIN=10.7.0
664    AC_SUBST(MACOSX_VERSION_MIN)
665
666    # The macro takes the version with no dots, ex: 1070
667    # Let the flags variables get resolved in make for easier override on make
668    # command line.
669    COMMON_CCXXFLAGS_JDK="$COMMON_CCXXFLAGS_JDK -DMAC_OS_X_VERSION_MAX_ALLOWED=\$(subst .,,\$(MACOSX_VERSION_MIN)) -mmacosx-version-min=\$(MACOSX_VERSION_MIN)"
670    LDFLAGS_JDK="$LDFLAGS_JDK -mmacosx-version-min=\$(MACOSX_VERSION_MIN)"
671  fi
672
673  # Setup some hard coded includes
674  COMMON_CCXXFLAGS_JDK="$COMMON_CCXXFLAGS_JDK \
675      -I${JDK_OUTPUTDIR}/include \
676      -I${JDK_OUTPUTDIR}/include/$OPENJDK_TARGET_OS \
677      -I${JDK_TOPDIR}/src/share/javavm/export \
678      -I${JDK_TOPDIR}/src/$OPENJDK_TARGET_OS_EXPORT_DIR/javavm/export \
679      -I${JDK_TOPDIR}/src/share/native/common \
680      -I${JDK_TOPDIR}/src/$OPENJDK_TARGET_OS_API_DIR/native/common"
681
682  # The shared libraries are compiled using the picflag.
683  CFLAGS_JDKLIB="$COMMON_CCXXFLAGS_JDK $CFLAGS_JDK $PICFLAG $CFLAGS_JDKLIB_EXTRA"
684  CXXFLAGS_JDKLIB="$COMMON_CCXXFLAGS_JDK $CXXFLAGS_JDK $PICFLAG $CXXFLAGS_JDKLIB_EXTRA "
685
686  # Executable flags
687  CFLAGS_JDKEXE="$COMMON_CCXXFLAGS_JDK $CFLAGS_JDK"
688  CXXFLAGS_JDKEXE="$COMMON_CCXXFLAGS_JDK $CXXFLAGS_JDK"
689
690  AC_SUBST(CFLAGS_JDKLIB)
691  AC_SUBST(CFLAGS_JDKEXE)
692  AC_SUBST(CXXFLAGS_JDKLIB)
693  AC_SUBST(CXXFLAGS_JDKEXE)
694
695  # Setup LDFLAGS et al.
696  #
697
698  # Now this is odd. The JDK native libraries have to link against libjvm.so
699  # On 32-bit machines there is normally two distinct libjvm.so:s, client and server.
700  # Which should we link to? Are we lucky enough that the binary api to the libjvm.so library
701  # is identical for client and server? Yes. Which is picked at runtime (client or server)?
702  # Neither, since the chosen libjvm.so has already been loaded by the launcher, all the following
703  # libraries will link to whatever is in memory. Yuck.
704  #
705  # Thus we offer the compiler to find libjvm.so first in server then in client. It works. Ugh.
706  if test "x$TOOLCHAIN_TYPE" = xmicrosoft; then
707    LDFLAGS_JDK="$LDFLAGS_JDK -nologo -opt:ref -incremental:no"
708    if test "x$OPENJDK_TARGET_CPU_BITS" = "x32"; then
709      LDFLAGS_JDK="$LDFLAGS_JDK -safeseh"
710    fi
711    # TODO: make -debug optional "--disable-full-debug-symbols"
712    LDFLAGS_JDK="$LDFLAGS_JDK -debug"
713  elif test "x$TOOLCHAIN_TYPE" = xgcc; then
714    # If this is a --hash-style=gnu system, use --hash-style=both, why?
715    # We have previously set HAS_GNU_HASH if this is the case
716    if test -n "$HAS_GNU_HASH"; then
717      LDFLAGS_JDK="${LDFLAGS_JDK} -Xlinker --hash-style=both"
718    fi
719    if test "x$OPENJDK_TARGET_OS" = xlinux; then
720      # And since we now know that the linker is gnu, then add -z defs, to forbid
721      # undefined symbols in object files.
722      LDFLAGS_JDK="${LDFLAGS_JDK} -Xlinker -z -Xlinker defs"
723      case $DEBUG_LEVEL in
724        release )
725          # tell linker to optimize libraries.
726          # Should this be supplied to the OSS linker as well?
727          LDFLAGS_JDK="${LDFLAGS_JDK} -Xlinker -O1"
728          ;;
729        slowdebug )
730          if test "x$HAS_LINKER_NOW" = "xtrue"; then
731            # do relocations at load
732            LDFLAGS_JDK="$LDFLAGS_JDK $LINKER_NOW_FLAG"
733            LDFLAGS_CXX_JDK="$LDFLAGS_CXX_JDK $LINKER_NOW_FLAG"
734          fi
735          if test "x$HAS_LINKER_RELRO" = "xtrue"; then
736            # mark relocations read only
737            LDFLAGS_JDK="$LDFLAGS_JDK $LINKER_RELRO_FLAG"
738            LDFLAGS_CXX_JDK="$LDFLAGS_CXX_JDK $LINKER_RELRO_FLAG"
739          fi
740          ;;
741        fastdebug )
742          if test "x$HAS_LINKER_RELRO" = "xtrue"; then
743            # mark relocations read only
744            LDFLAGS_JDK="$LDFLAGS_JDK $LINKER_RELRO_FLAG"
745            LDFLAGS_CXX_JDK="$LDFLAGS_CXX_JDK $LINKER_RELRO_FLAG"
746          fi
747          ;;
748        * )
749          AC_MSG_ERROR([Unrecognized \$DEBUG_LEVEL: $DEBUG_LEVEL])
750          ;;
751        esac
752    fi
753  elif test "x$TOOLCHAIN_TYPE" = xsolstudio; then
754    LDFLAGS_JDK="$LDFLAGS_JDK -z defs -xildoff -ztext"
755    LDFLAGS_CXX_JDK="$LDFLAGS_CXX_JDK -norunpath -xnolib"
756  fi
757
758  if test "x$TOOLCHAIN_TYPE" = xgcc || test "x$TOOLCHAIN_TYPE" = xclang; then
759    # If undefined behaviour detection is enabled then we need to tell linker.
760    case $DEBUG_LEVEL in
761      release | fastdebug )
762        ;;
763      slowdebug )
764        AC_MSG_WARN([$HAS_CFLAG_DETECT_UNDEFINED_BEHAVIOR])
765        if test "x$HAS_CFLAG_DETECT_UNDEFINED_BEHAVIOR" = "xtrue"; then
766          # enable undefined behaviour checking
767          LDFLAGS_JDK="$LDFLAGS_JDK `$ECHO -n $CFLAG_DETECT_UNDEFINED_BEHAVIOR_FLAG | sed -e "s/[ ]*\([^ ]\+\)/ -Xlinker \1/g"`"
768          LDFLAGS_CXX_JDK="$LDFLAGS_CXX_JDK `$ECHO -n $CFLAG_DETECT_UNDEFINED_BEHAVIOR_FLAG | sed -e "s/[ ]*\([^ ]\+\)/ -Xlinker \1/g"`"
769        fi
770        ;;
771      * )
772        AC_MSG_ERROR([Unrecognized \$DEBUG_LEVEL: $DEBUG_LEVEL])
773        ;;
774    esac
775  fi
776
777  # Customize LDFLAGS for executables
778
779  LDFLAGS_JDKEXE="${LDFLAGS_JDK}"
780
781  if test "x$TOOLCHAIN_TYPE" = xmicrosoft; then
782    if test "x$OPENJDK_TARGET_CPU_BITS" = "x64"; then
783      LDFLAGS_STACK_SIZE=1048576
784    else
785      LDFLAGS_STACK_SIZE=327680
786    fi
787    LDFLAGS_JDKEXE="${LDFLAGS_JDKEXE} /STACK:$LDFLAGS_STACK_SIZE"
788  elif test "x$OPENJDK_TARGET_OS" = xlinux; then
789    LDFLAGS_JDKEXE="$LDFLAGS_JDKEXE -Xlinker --allow-shlib-undefined"
790  fi
791
792  # Customize LDFLAGS for libs
793  LDFLAGS_JDKLIB="${LDFLAGS_JDK}"
794
795  if test "x$TOOLCHAIN_TYPE" = xmicrosoft; then
796    LDFLAGS_JDKLIB="${LDFLAGS_JDKLIB} -dll -libpath:${JDK_OUTPUTDIR}/lib"
797    LDFLAGS_JDKLIB_SUFFIX=""
798  else
799    LDFLAGS_JDKLIB="${LDFLAGS_JDKLIB}  ${SHARED_LIBRARY_FLAGS} \
800        -L${JDK_OUTPUTDIR}/lib${OPENJDK_TARGET_CPU_LIBDIR}"
801
802    # On some platforms (mac) the linker warns about non existing -L dirs.
803    # Add server first if available. Linking aginst client does not always produce the same results.
804    # Only add client dir if client is being built. Add minimal (note not minimal1) if only building minimal1.
805    # Default to server for other variants.
806    if test "x$JVM_VARIANT_SERVER" = xtrue; then
807      LDFLAGS_JDKLIB="${LDFLAGS_JDKLIB} -L${JDK_OUTPUTDIR}/lib${OPENJDK_TARGET_CPU_LIBDIR}/server"
808    elif test "x$JVM_VARIANT_CLIENT" = xtrue; then
809      LDFLAGS_JDKLIB="${LDFLAGS_JDKLIB} -L${JDK_OUTPUTDIR}/lib${OPENJDK_TARGET_CPU_LIBDIR}/client"
810    elif test "x$JVM_VARIANT_MINIMAL1" = xtrue; then
811      LDFLAGS_JDKLIB="${LDFLAGS_JDKLIB} -L${JDK_OUTPUTDIR}/lib${OPENJDK_TARGET_CPU_LIBDIR}/minimal"
812    else
813      LDFLAGS_JDKLIB="${LDFLAGS_JDKLIB} -L${JDK_OUTPUTDIR}/lib${OPENJDK_TARGET_CPU_LIBDIR}/server"
814    fi
815
816    LDFLAGS_JDKLIB_SUFFIX="-ljava -ljvm"
817    if test "x$TOOLCHAIN_TYPE" = xsolstudio; then
818      LDFLAGS_JDKLIB_SUFFIX="$LDFLAGS_JDKLIB_SUFFIX -lc"
819    fi
820  fi
821
822  AC_SUBST(LDFLAGS_JDKLIB)
823  AC_SUBST(LDFLAGS_JDKEXE)
824  AC_SUBST(LDFLAGS_JDKLIB_SUFFIX)
825  AC_SUBST(LDFLAGS_JDKEXE_SUFFIX)
826  AC_SUBST(LDFLAGS_CXX_JDK)
827])
828
829# FLAGS_COMPILER_CHECK_ARGUMENTS([ARGUMENT], [RUN-IF-TRUE],
830#                                   [RUN-IF-FALSE])
831# ------------------------------------------------------------
832# Check that the c and c++ compilers support an argument
833AC_DEFUN([FLAGS_COMPILER_CHECK_ARGUMENTS],
834[
835  AC_MSG_CHECKING([if compiler supports "$1"])
836  supports=yes
837
838  saved_cflags="$CFLAGS"
839  CFLAGS="$CFLAGS $1"
840  AC_LANG_PUSH([C])
841  AC_COMPILE_IFELSE([AC_LANG_SOURCE([[int i;]])], [],
842      [supports=no])
843  AC_LANG_POP([C])
844  CFLAGS="$saved_cflags"
845
846  saved_cxxflags="$CXXFLAGS"
847  CXXFLAGS="$CXXFLAG $1"
848  AC_LANG_PUSH([C++])
849  AC_COMPILE_IFELSE([AC_LANG_SOURCE([[int i;]])], [],
850      [supports=no])
851  AC_LANG_POP([C++])
852  CXXFLAGS="$saved_cxxflags"
853
854  AC_MSG_RESULT([$supports])
855  if test "x$supports" = "xyes" ; then
856    m4_ifval([$2], [$2], [:])
857  else
858    m4_ifval([$3], [$3], [:])
859  fi
860])
861
862# FLAGS_LINKER_CHECK_ARGUMENTS([ARGUMENT], [RUN-IF-TRUE],
863#                                    [RUN-IF-FALSE])
864# ------------------------------------------------------------
865# Check that the linker support an argument
866AC_DEFUN([FLAGS_LINKER_CHECK_ARGUMENTS],
867[
868  AC_MSG_CHECKING([if linker supports "$1"])
869  supports=yes
870
871  saved_ldflags="$LDFLAGS"
872  LDFLAGS="$LDFLAGS $1"
873  AC_LANG_PUSH([C])
874  AC_LINK_IFELSE([AC_LANG_PROGRAM([[]],[[]])],
875      [], [supports=no])
876  AC_LANG_POP([C])
877  LDFLAGS="$saved_ldflags"
878
879  AC_MSG_RESULT([$supports])
880  if test "x$supports" = "xyes" ; then
881    m4_ifval([$2], [$2], [:])
882  else
883    m4_ifval([$3], [$3], [:])
884  fi
885])
886
887AC_DEFUN_ONCE([FLAGS_SETUP_COMPILER_FLAGS_MISC],
888[
889  # Some Zero and Shark settings.
890  # ZERO_ARCHFLAG tells the compiler which mode to build for
891  case "${OPENJDK_TARGET_CPU}" in
892    s390)
893      ZERO_ARCHFLAG="${COMPILER_TARGET_BITS_FLAG}31"
894      ;;
895    *)
896      ZERO_ARCHFLAG="${COMPILER_TARGET_BITS_FLAG}${OPENJDK_TARGET_CPU_BITS}"
897  esac
898  FLAGS_COMPILER_CHECK_ARGUMENTS([$ZERO_ARCHFLAG], [], [ZERO_ARCHFLAG=""])
899  AC_SUBST(ZERO_ARCHFLAG)
900
901  # Check that the compiler supports -mX (or -qX on AIX) flags
902  # Set COMPILER_SUPPORTS_TARGET_BITS_FLAG to 'true' if it does
903  FLAGS_COMPILER_CHECK_ARGUMENTS([${COMPILER_TARGET_BITS_FLAG}${OPENJDK_TARGET_CPU_BITS}],
904      [COMPILER_SUPPORTS_TARGET_BITS_FLAG=true],
905      [COMPILER_SUPPORTS_TARGET_BITS_FLAG=false])
906  AC_SUBST(COMPILER_SUPPORTS_TARGET_BITS_FLAG)
907
908  case "${TOOLCHAIN_TYPE}" in
909    microsoft)
910      CFLAGS_WARNINGS_ARE_ERRORS="/WX"
911      ;;
912    solstudio)
913      CFLAGS_WARNINGS_ARE_ERRORS="-errtags -errwarn=%all"
914      ;;
915    gcc)
916      CFLAGS_WARNINGS_ARE_ERRORS="-Werror"
917      ;;
918    clang)
919      CFLAGS_WARNINGS_ARE_ERRORS="-Werror"
920      ;;
921  esac
922  AC_SUBST(CFLAGS_WARNINGS_ARE_ERRORS)
923])
924