build-performance.m4 revision 738:c0fa87863427 
1#
2# Copyright (c) 2011, 2012, Oracle and/or its affiliates. All rights reserved.
3# DO NOT ALTER OR REMOVE COPYRIGHT NOTICES OR THIS FILE HEADER.
4#
5# This code is free software; you can redistribute it and/or modify it
6# under the terms of the GNU General Public License version 2 only, as
7# published by the Free Software Foundation.  Oracle designates this
8# particular file as subject to the "Classpath" exception as provided
9# by Oracle in the LICENSE file that accompanied this code.
10#
11# This code is distributed in the hope that it will be useful, but WITHOUT
12# ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
13# FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License
14# version 2 for more details (a copy is included in the LICENSE file that
15# accompanied this code).
16#
17# You should have received a copy of the GNU General Public License version
18# 2 along with this work; if not, write to the Free Software Foundation,
19# Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301 USA.
20#
21# Please contact Oracle, 500 Oracle Parkway, Redwood Shores, CA 94065 USA
22# or visit www.oracle.com if you need additional information or have any
23# questions.
24#
25
26AC_DEFUN([BPERF_CHECK_CORES],
27[
28    AC_MSG_CHECKING([for number of cores])
29    NUM_CORES=1
30    FOUND_CORES=no
31    
32    if test -f /proc/cpuinfo; then
33        # Looks like a Linux (or cygwin) system
34        NUM_CORES=`cat /proc/cpuinfo  | grep -c processor`
35        FOUND_CORES=yes
36    elif test -x /usr/sbin/psrinfo; then
37        # Looks like a Solaris system
38        NUM_CORES=`LC_MESSAGES=C /usr/sbin/psrinfo -v | grep -c on-line`
39        FOUND_CORES=yes
40    elif test -x /usr/sbin/system_profiler; then
41        # Looks like a MacOSX system
42        NUM_CORES=`/usr/sbin/system_profiler -detailLevel full SPHardwareDataType | grep 'Cores' | awk  '{print [$]5}'`
43        FOUND_CORES=yes
44    elif test -n "$NUMBER_OF_PROCESSORS"; then
45        # On windows, look in the env
46        NUM_CORES=$NUMBER_OF_PROCESSORS
47        FOUND_CORES=yes
48    fi
49
50    if test "x$FOUND_CORES" = xyes; then
51        AC_MSG_RESULT([$NUM_CORES])
52    else
53        AC_MSG_RESULT([could not detect number of cores, defaulting to 1])
54        AC_MSG_WARN([This will disable all parallelism from build!])
55    fi 
56
57])
58
59AC_DEFUN([BPERF_CHECK_MEMORY_SIZE],
60[
61    AC_MSG_CHECKING([for memory size])
62    # Default to 1024 MB
63    MEMORY_SIZE=1024
64    FOUND_MEM=no
65    
66    if test -f /proc/meminfo; then
67        # Looks like a Linux (or cygwin) system
68        MEMORY_SIZE=`cat /proc/meminfo | grep MemTotal | awk '{print [$]2}'`
69        MEMORY_SIZE=`expr $MEMORY_SIZE / 1024`
70        FOUND_MEM=yes
71    elif test -x /usr/sbin/prtconf; then
72        # Looks like a Solaris system
73        MEMORY_SIZE=`/usr/sbin/prtconf | grep "Memory size" | awk '{ print [$]3 }'`
74        FOUND_MEM=yes
75    elif test -x /usr/sbin/system_profiler; then
76        # Looks like a MacOSX system
77        MEMORY_SIZE=`/usr/sbin/system_profiler -detailLevel full SPHardwareDataType | grep 'Memory' | awk  '{print [$]2}'`
78        MEMORY_SIZE=`expr $MEMORY_SIZE \* 1024`
79        FOUND_MEM=yes
80    elif test "x$OPENJDK_BUILD_OS" = xwindows; then
81        # Windows, but without cygwin
82        MEMORY_SIZE=`wmic computersystem get totalphysicalmemory -value | grep = | cut -d "=" -f 2-`
83        MEMORY_SIZE=`expr $MEMORY_SIZE / 1024 / 1024`
84        FOUND_MEM=yes    
85    fi
86
87    if test "x$FOUND_MEM" = xyes; then
88        AC_MSG_RESULT([$MEMORY_SIZE MB])
89    else
90        AC_MSG_RESULT([could not detect memory size, defaulting to 1024 MB])
91        AC_MSG_WARN([This might seriously impact build performance!])
92    fi 
93])
94
95AC_DEFUN_ONCE([BPERF_SETUP_BUILD_CORES],
96[
97  # How many cores do we have on this build system?
98  AC_ARG_WITH(num-cores, [AS_HELP_STRING([--with-num-cores],
99    [number of cores in the build system, e.g. --with-num-cores=8 @<:@probed@:>@])])
100  if test "x$with_num_cores" = x; then
101    # The number of cores were not specified, try to probe them.
102    BPERF_CHECK_CORES
103  else
104    NUM_CORES=$with_num_cores
105  fi
106  AC_SUBST(NUM_CORES)
107])
108
109AC_DEFUN_ONCE([BPERF_SETUP_BUILD_MEMORY],
110[
111  # How much memory do we have on this build system?
112  AC_ARG_WITH(memory-size, [AS_HELP_STRING([--with-memory-size],
113    [memory (in MB) available in the build system, e.g. --with-memory-size=1024 @<:@probed@:>@])])
114  if test "x$with_memory_size" = x; then
115    # The memory size was not specified, try to probe it.
116    BPERF_CHECK_MEMORY_SIZE
117  else
118    MEMORY_SIZE=$with_memory_size
119  fi
120  AC_SUBST(MEMORY_SIZE)
121])
122
123AC_DEFUN_ONCE([BPERF_SETUP_BUILD_JOBS],
124[
125  # Provide a decent default number of parallel jobs for make depending on 
126  # number of cores, amount of memory and machine architecture.
127  AC_ARG_WITH(jobs, [AS_HELP_STRING([--with-jobs],
128    [number of parallel jobs to let make run @<:@calculated based on cores and memory@:>@])])
129  if test "x$with_jobs" = x; then
130    # Number of jobs was not specified, calculate.
131    AC_MSG_CHECKING([for appropriate number of jobs to run in parallel])
132    # Approximate memory in GB, rounding up a bit.
133    memory_gb=`expr $MEMORY_SIZE / 1100`
134    # Pick the lowest of memory in gb and number of cores.
135    if test "$memory_gb" -lt "$NUM_CORES"; then
136      JOBS="$memory_gb"
137    else
138      JOBS="$NUM_CORES"
139      # On bigger machines, leave some room for other processes to run
140      if test "$JOBS" -gt "4"; then
141        JOBS=`expr $JOBS '*' 90 / 100`
142      fi
143    fi
144    # Cap number of jobs to 16
145    if test "$JOBS" -gt "16"; then
146      JOBS=16
147    fi
148    if test "$JOBS" -eq "0"; then
149      JOBS=1
150    fi
151    AC_MSG_RESULT([$JOBS])
152  else
153    JOBS=$with_jobs
154  fi
155  AC_SUBST(JOBS)
156])
157
158AC_DEFUN([BPERF_SETUP_CCACHE],
159[
160    AC_ARG_ENABLE([ccache],
161	      [AS_HELP_STRING([--disable-ccache],
162	      		      [disable using ccache to speed up recompilations @<:@enabled@:>@])],
163              [ENABLE_CCACHE=${enable_ccache}], [ENABLE_CCACHE=yes])
164    if test "x$ENABLE_CCACHE" = xyes; then
165        OLD_PATH="$PATH"
166        if test "x$TOOLS_DIR" != x; then
167          PATH=$TOOLS_DIR:$PATH
168        fi
169        AC_PATH_PROG(CCACHE, ccache)
170        PATH="$OLD_PATH"
171    else
172        AC_MSG_CHECKING([for ccache])
173        AC_MSG_RESULT([explicitly disabled])    
174        CCACHE=
175    fi    
176    AC_SUBST(CCACHE)
177
178    AC_ARG_WITH([ccache-dir],
179	      [AS_HELP_STRING([--with-ccache-dir],
180	      		      [where to store ccache files @<:@~/.ccache@:>@])])
181
182    if test "x$with_ccache_dir" != x; then
183        # When using a non home ccache directory, assume the use is to share ccache files
184        # with other users. Thus change the umask.
185        SET_CCACHE_DIR="CCACHE_DIR=$with_ccache_dir CCACHE_UMASK=002"
186    fi
187    CCACHE_FOUND=""
188    if test "x$CCACHE" != x; then
189        BPERF_SETUP_CCACHE_USAGE
190    fi    
191])
192
193AC_DEFUN([BPERF_SETUP_CCACHE_USAGE],
194[
195    if test "x$CCACHE" != x; then
196        CCACHE_FOUND="true"
197        # Only use ccache if it is 3.1.4 or later, which supports
198        # precompiled headers.
199        AC_MSG_CHECKING([if ccache supports precompiled headers])
200        HAS_GOOD_CCACHE=`($CCACHE --version | head -n 1 | grep -E 3.1.@<:@456789@:>@) 2> /dev/null`
201        if test "x$HAS_GOOD_CCACHE" = x; then
202            AC_MSG_RESULT([no, disabling ccache])
203            CCACHE=
204        else
205            AC_MSG_RESULT([yes])
206            AC_MSG_CHECKING([if C-compiler supports ccache precompiled headers])
207            PUSHED_FLAGS="$CXXFLAGS"
208            CXXFLAGS="-fpch-preprocess $CXXFLAGS"
209            AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [])], [CC_KNOWS_CCACHE_TRICK=yes], [CC_KNOWS_CCACHE_TRICK=no])
210            CXXFLAGS="$PUSHED_FLAGS"
211            if test "x$CC_KNOWS_CCACHE_TRICK" = xyes; then
212                AC_MSG_RESULT([yes])
213            else
214                AC_MSG_RESULT([no, disabling ccaching of precompiled headers])
215                CCACHE=
216            fi
217        fi
218    fi
219
220    if test "x$CCACHE" != x; then
221        CCACHE_SLOPPINESS=time_macros
222        CCACHE="CCACHE_COMPRESS=1 $SET_CCACHE_DIR CCACHE_SLOPPINESS=$CCACHE_SLOPPINESS $CCACHE"
223        CCACHE_FLAGS=-fpch-preprocess
224
225        if test "x$SET_CCACHE_DIR" != x; then
226            mkdir -p $CCACHE_DIR > /dev/null 2>&1
227	    chmod a+rwxs $CCACHE_DIR > /dev/null 2>&1
228        fi
229    fi
230])
231
232AC_DEFUN_ONCE([BPERF_SETUP_PRECOMPILED_HEADERS],
233[
234       
235###############################################################################
236#
237# Can the C/C++ compiler use precompiled headers?
238#
239AC_ARG_ENABLE([precompiled-headers], [AS_HELP_STRING([--disable-precompiled-headers],
240	[disable using precompiled headers when compiling C++ @<:@enabled@:>@])],
241    [ENABLE_PRECOMPH=${enable_precompiled_headers}], [ENABLE_PRECOMPH=yes])
242
243USE_PRECOMPILED_HEADER=1
244if test "x$ENABLE_PRECOMPH" = xno; then
245    USE_PRECOMPILED_HEADER=0
246fi
247
248if test "x$ENABLE_PRECOMPH" = xyes; then
249    # Check that the compiler actually supports precomp headers.
250    if test "x$GCC" = xyes; then
251         AC_MSG_CHECKING([that precompiled headers work])
252         echo "int alfa();" > conftest.h
253         $CXX -x c++-header conftest.h -o conftest.hpp.gch 2>&AS_MESSAGE_LOG_FD >&AS_MESSAGE_LOG_FD
254         if test ! -f conftest.hpp.gch; then
255             USE_PRECOMPILED_HEADER=0
256             AC_MSG_RESULT([no])        
257         else
258             AC_MSG_RESULT([yes])
259         fi
260         rm -f conftest.h conftest.hpp.gch
261    fi
262fi
263
264AC_SUBST(USE_PRECOMPILED_HEADER)
265])
266
267
268AC_DEFUN_ONCE([BPERF_SETUP_SMART_JAVAC],
269[
270AC_ARG_WITH(sjavac-server-java, [AS_HELP_STRING([--with-sjavac-server-java],
271	[use this java binary for running the sjavac background server @<:@Boot JDK java@:>@])])
272
273if test "x$with_sjavac_server_java" != x; then
274    SJAVAC_SERVER_JAVA="$with_sjavac_server_java"
275    FOUND_VERSION=`$SJAVAC_SERVER_JAVA -version 2>&1 | grep " version \""`
276    if test "x$FOUND_VERSION" = x; then
277        AC_MSG_ERROR([Could not execute server java: $SJAVAC_SERVER_JAVA])
278    fi
279else
280    SJAVAC_SERVER_JAVA=""
281    # Hotspot specific options.
282    ADD_JVM_ARG_IF_OK([-verbosegc],SJAVAC_SERVER_JAVA,[$JAVA])
283    # JRockit specific options.
284    ADD_JVM_ARG_IF_OK([-Xverbose:gc],SJAVAC_SERVER_JAVA,[$JAVA])
285    SJAVAC_SERVER_JAVA="$JAVA $SJAVAC_SERVER_JAVA"
286fi                    
287AC_SUBST(SJAVAC_SERVER_JAVA)
288
289if test "$MEMORY_SIZE" -gt "2500"; then
290    ADD_JVM_ARG_IF_OK([-d64],SJAVAC_SERVER_JAVA,[$SJAVAC_SERVER_JAVA])
291    if test "$JVM_ARG_OK" = true; then
292        JVM_64BIT=true
293	JVM_ARG_OK=false
294    fi
295    fi
296
297if test "$JVM_64BIT" = true; then
298    if test "$MEMORY_SIZE" -gt "17000"; then
299        ADD_JVM_ARG_IF_OK([-Xms10G -Xmx10G],SJAVAC_SERVER_JAVA,[$SJAVAC_SERVER_JAVA])
300    fi
301    if test "$MEMORY_SIZE" -gt "10000" && test "$JVM_ARG_OK" = false; then
302        ADD_JVM_ARG_IF_OK([-Xms6G -Xmx6G],SJAVAC_SERVER_JAVA,[$SJAVAC_SERVER_JAVA])
303    fi
304    if test "$MEMORY_SIZE" -gt "5000" && test "$JVM_ARG_OK" = false; then
305        ADD_JVM_ARG_IF_OK([-Xms1G -Xmx3G],SJAVAC_SERVER_JAVA,[$SJAVAC_SERVER_JAVA])
306    fi
307    if test "$MEMORY_SIZE" -gt "3800" && test "$JVM_ARG_OK" = false; then
308        ADD_JVM_ARG_IF_OK([-Xms1G -Xmx2500M],SJAVAC_SERVER_JAVA,[$SJAVAC_SERVER_JAVA])
309    fi
310fi
311if test "$MEMORY_SIZE" -gt "2500" && test "$JVM_ARG_OK" = false; then
312    ADD_JVM_ARG_IF_OK([-Xms1000M -Xmx1500M],SJAVAC_SERVER_JAVA,[$SJAVAC_SERVER_JAVA])
313fi
314if test "$MEMORY_SIZE" -gt "1000" && test "$JVM_ARG_OK" = false; then
315    ADD_JVM_ARG_IF_OK([-Xms400M -Xmx1100M],SJAVAC_SERVER_JAVA,[$SJAVAC_SERVER_JAVA])
316fi
317if test "$JVM_ARG_OK" = false; then
318    ADD_JVM_ARG_IF_OK([-Xms256M -Xmx512M],SJAVAC_SERVER_JAVA,[$SJAVAC_SERVER_JAVA])
319fi
320
321AC_MSG_CHECKING([whether to use sjavac])
322AC_ARG_ENABLE([sjavac], [AS_HELP_STRING([--enable-sjavac],
323	[use sjavac to do fast incremental compiles @<:@disabled@:>@])],
324	[ENABLE_SJAVAC="${enableval}"], [ENABLE_SJAVAC='no'])
325AC_MSG_RESULT([$ENABLE_SJAVAC])
326AC_SUBST(ENABLE_SJAVAC)
327
328if test "x$ENABLE_SJAVAC" = xyes; then
329    SJAVAC_SERVER_DIR="$OUTPUT_ROOT/javacservers"
330else
331    SJAVAC_SERVER_DIR=
332fi
333AC_SUBST(SJAVAC_SERVER_DIR)
334
335])
336