build-performance.m4 revision 1807:c68e1abd0df9 
1#
2# Copyright (c) 2011, 2012, Oracle and/or its affiliates. All rights reserved.
3# DO NOT ALTER OR REMOVE COPYRIGHT NOTICES OR THIS FILE HEADER.
4#
5# This code is free software; you can redistribute it and/or modify it
6# under the terms of the GNU General Public License version 2 only, as
7# published by the Free Software Foundation.  Oracle designates this
8# particular file as subject to the "Classpath" exception as provided
9# by Oracle in the LICENSE file that accompanied this code.
10#
11# This code is distributed in the hope that it will be useful, but WITHOUT
12# ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
13# FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License
14# version 2 for more details (a copy is included in the LICENSE file that
15# accompanied this code).
16#
17# You should have received a copy of the GNU General Public License version
18# 2 along with this work; if not, write to the Free Software Foundation,
19# Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301 USA.
20#
21# Please contact Oracle, 500 Oracle Parkway, Redwood Shores, CA 94065 USA
22# or visit www.oracle.com if you need additional information or have any
23# questions.
24#
25
26AC_DEFUN([BPERF_CHECK_CORES],
27[
28  AC_MSG_CHECKING([for number of cores])
29  NUM_CORES=1
30  FOUND_CORES=no
31
32  if test -f /proc/cpuinfo; then
33    # Looks like a Linux (or cygwin) system
34    NUM_CORES=`cat /proc/cpuinfo  | grep -c processor`
35    FOUND_CORES=yes
36  elif test -x /usr/sbin/psrinfo; then
37    # Looks like a Solaris system
38    NUM_CORES=`LC_MESSAGES=C /usr/sbin/psrinfo -v | grep -c on-line`
39    FOUND_CORES=yes
40  elif test -x /usr/sbin/system_profiler; then
41    # Looks like a MacOSX system
42    NUM_CORES=`/usr/sbin/system_profiler -detailLevel full SPHardwareDataType | grep 'Cores' | awk  '{print [$]5}'`
43    FOUND_CORES=yes
44  elif test "x$OPENJDK_BUILD_OS" = xaix ; then
45    NUM_CORES=`/usr/sbin/prtconf | grep "^Number Of Processors" | awk '{ print [$]4 }'`
46    FOUND_CORES=yes
47  elif test -n "$NUMBER_OF_PROCESSORS"; then
48    # On windows, look in the env
49    NUM_CORES=$NUMBER_OF_PROCESSORS
50    FOUND_CORES=yes
51  fi
52
53  if test "x$FOUND_CORES" = xyes; then
54    AC_MSG_RESULT([$NUM_CORES])
55  else
56    AC_MSG_RESULT([could not detect number of cores, defaulting to 1])
57    AC_MSG_WARN([This will disable all parallelism from build!])
58  fi
59])
60
61AC_DEFUN([BPERF_CHECK_MEMORY_SIZE],
62[
63  AC_MSG_CHECKING([for memory size])
64  # Default to 1024 MB
65  MEMORY_SIZE=1024
66  FOUND_MEM=no
67
68  if test -f /proc/meminfo; then
69    # Looks like a Linux (or cygwin) system
70    MEMORY_SIZE=`cat /proc/meminfo | grep MemTotal | awk '{print [$]2}'`
71    MEMORY_SIZE=`expr $MEMORY_SIZE / 1024`
72    FOUND_MEM=yes
73  elif test -x /usr/sbin/prtconf; then
74    # Looks like a Solaris or AIX system
75    MEMORY_SIZE=`/usr/sbin/prtconf | grep "^Memory [[Ss]]ize" | awk '{ print [$]3 }'`
76    FOUND_MEM=yes
77  elif test -x /usr/sbin/system_profiler; then
78    # Looks like a MacOSX system
79    MEMORY_SIZE=`/usr/sbin/system_profiler -detailLevel full SPHardwareDataType | grep 'Memory' | awk  '{print [$]2}'`
80    MEMORY_SIZE=`expr $MEMORY_SIZE \* 1024`
81    FOUND_MEM=yes
82  elif test "x$OPENJDK_BUILD_OS" = xwindows; then
83    # Windows, but without cygwin
84    MEMORY_SIZE=`wmic computersystem get totalphysicalmemory -value | grep = | cut -d "=" -f 2-`
85    MEMORY_SIZE=`expr $MEMORY_SIZE / 1024 / 1024`
86    FOUND_MEM=yes
87  fi
88
89  if test "x$FOUND_MEM" = xyes; then
90    AC_MSG_RESULT([$MEMORY_SIZE MB])
91  else
92    AC_MSG_RESULT([could not detect memory size, defaulting to $MEMORY_SIZE MB])
93    AC_MSG_WARN([This might seriously impact build performance!])
94  fi
95])
96
97AC_DEFUN_ONCE([BPERF_SETUP_BUILD_CORES],
98[
99  # How many cores do we have on this build system?
100  AC_ARG_WITH(num-cores, [AS_HELP_STRING([--with-num-cores],
101      [number of cores in the build system, e.g. --with-num-cores=8 @<:@probed@:>@])])
102  if test "x$with_num_cores" = x; then
103    # The number of cores were not specified, try to probe them.
104    BPERF_CHECK_CORES
105  else
106    NUM_CORES=$with_num_cores
107  fi
108  AC_SUBST(NUM_CORES)
109])
110
111AC_DEFUN_ONCE([BPERF_SETUP_BUILD_MEMORY],
112[
113  # How much memory do we have on this build system?
114  AC_ARG_WITH(memory-size, [AS_HELP_STRING([--with-memory-size],
115      [memory (in MB) available in the build system, e.g. --with-memory-size=1024 @<:@probed@:>@])])
116  if test "x$with_memory_size" = x; then
117    # The memory size was not specified, try to probe it.
118    BPERF_CHECK_MEMORY_SIZE
119  else
120    MEMORY_SIZE=$with_memory_size
121  fi
122  AC_SUBST(MEMORY_SIZE)
123])
124
125AC_DEFUN_ONCE([BPERF_SETUP_BUILD_JOBS],
126[
127  # Provide a decent default number of parallel jobs for make depending on
128  # number of cores, amount of memory and machine architecture.
129  AC_ARG_WITH(jobs, [AS_HELP_STRING([--with-jobs],
130      [number of parallel jobs to let make run @<:@calculated based on cores and memory@:>@])])
131  if test "x$with_jobs" = x; then
132    # Number of jobs was not specified, calculate.
133    AC_MSG_CHECKING([for appropriate number of jobs to run in parallel])
134    # Approximate memory in GB.
135    memory_gb=`expr $MEMORY_SIZE / 1024`
136    # Pick the lowest of memory in gb and number of cores.
137    if test "$memory_gb" -lt "$NUM_CORES"; then
138      JOBS="$memory_gb"
139    else
140      JOBS="$NUM_CORES"
141    fi
142    if test "$JOBS" -eq "0"; then
143      JOBS=1
144    fi
145    AC_MSG_RESULT([$JOBS])
146  else
147    JOBS=$with_jobs
148  fi
149  AC_SUBST(JOBS)
150])
151
152AC_DEFUN([BPERF_SETUP_CCACHE],
153[
154  AC_ARG_ENABLE([ccache],
155      [AS_HELP_STRING([--enable-ccache],
156      [enable using ccache to speed up recompilations @<:@disabled@:>@])])
157
158  CCACHE=
159  CCACHE_STATUS=
160  AC_MSG_CHECKING([is ccache enabled])
161  if test "x$enable_ccache" = xyes; then
162    if test "x$TOOLCHAIN_TYPE" = "xgcc" -o "x$TOOLCHAIN_TYPE" = "xclang"; then
163      AC_MSG_RESULT([yes])
164      OLD_PATH="$PATH"
165      if test "x$TOOLCHAIN_PATH" != x; then
166        PATH=$TOOLCHAIN_PATH:$PATH
167      fi
168      BASIC_REQUIRE_PROGS(CCACHE, ccache)
169      PATH="$OLD_PATH"
170      CCACHE_VERSION=[`$CCACHE --version | head -n1 | $SED 's/[A-Za-z ]*//'`]
171      CCACHE_STATUS="Active ($CCACHE_VERSION)"
172    else
173      AC_MSG_RESULT([no])
174      AC_MSG_WARN([ccache is not supported with toolchain type $TOOLCHAIN_TYPE])
175    fi
176  elif test "x$enable_ccache" = xno; then
177    AC_MSG_RESULT([no, explicitly disabled])
178    CCACHE_STATUS="Disabled"
179  elif test "x$enable_ccache" = x; then
180    AC_MSG_RESULT([no])
181  else
182    AC_MSG_RESULT([unknown])
183    AC_MSG_ERROR([--enable-ccache does not accept any parameters])
184  fi
185  AC_SUBST(CCACHE)
186
187  AC_ARG_WITH([ccache-dir],
188      [AS_HELP_STRING([--with-ccache-dir],
189      [where to store ccache files @<:@~/.ccache@:>@])])
190
191  if test "x$with_ccache_dir" != x; then
192    # When using a non home ccache directory, assume the use is to share ccache files
193    # with other users. Thus change the umask.
194    SET_CCACHE_DIR="CCACHE_DIR=$with_ccache_dir CCACHE_UMASK=002"
195    if test "x$CCACHE" = x; then
196      AC_MSG_WARN([--with-ccache-dir has no meaning when ccache is not enabled])
197    fi
198  fi
199
200  if test "x$CCACHE" != x; then
201    BPERF_SETUP_CCACHE_USAGE
202  fi
203])
204
205AC_DEFUN([BPERF_SETUP_CCACHE_USAGE],
206[
207  if test "x$CCACHE" != x; then
208    if test "x$USE_PRECOMPILED_HEADER" = "x1"; then
209      HAS_BAD_CCACHE=[`$ECHO $CCACHE_VERSION | \
210          $GREP -e '^1.*' -e '^2.*' -e '^3\.0.*' -e '^3\.1\.[0123]$'`]
211      if test "x$HAS_BAD_CCACHE" != "x"; then
212        AC_MSG_ERROR([Precompiled headers requires ccache 3.1.4 or later, found $CCACHE_VERSION])
213      fi
214      AC_MSG_CHECKING([if C-compiler supports ccache precompiled headers])
215      CCACHE_PRECOMP_FLAG="-fpch-preprocess"
216      PUSHED_FLAGS="$CXXFLAGS"
217      CXXFLAGS="$CCACHE_PRECOMP_FLAG $CXXFLAGS"
218      AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [])], [CC_KNOWS_CCACHE_TRICK=yes], [CC_KNOWS_CCACHE_TRICK=no])
219      CXXFLAGS="$PUSHED_FLAGS"
220      if test "x$CC_KNOWS_CCACHE_TRICK" = xyes; then
221        AC_MSG_RESULT([yes])
222        CFLAGS_CCACHE="$CCACHE_PRECOMP_FLAG"
223        AC_SUBST(CFLAGS_CCACHE)
224        CCACHE_SLOPPINESS=pch_defines,time_macros
225      else
226        AC_MSG_RESULT([no])
227        AC_MSG_ERROR([Cannot use ccache with precompiled headers without compiler support for $CCACHE_PRECOMP_FLAG])
228      fi
229    fi
230
231    CCACHE="CCACHE_COMPRESS=1 $SET_CCACHE_DIR \
232        CCACHE_SLOPPINESS=$CCACHE_SLOPPINESS CCACHE_BASEDIR=$TOPDIR $CCACHE"
233
234    if test "x$SET_CCACHE_DIR" != x; then
235      mkdir -p $CCACHE_DIR > /dev/null 2>&1
236      chmod a+rwxs $CCACHE_DIR > /dev/null 2>&1
237    fi
238  fi
239])
240
241################################################################################
242#
243# Optionally enable distributed compilation of native code using icecc/icecream
244#
245AC_DEFUN([BPERF_SETUP_ICECC],
246[
247  AC_ARG_ENABLE([icecc], [AS_HELP_STRING([--enable-icecc],
248      [enable distribted compilation of native code using icecc/icecream @<:@disabled@:>@])])
249
250  if test "x${enable_icecc}" = "xyes"; then
251    BASIC_REQUIRE_PROGS(ICECC_CMD, icecc)
252    old_path="$PATH"
253
254    # Look for icecc-create-env in some known places
255    PATH="$PATH:/usr/lib/icecc:/usr/lib64/icecc"
256    BASIC_REQUIRE_PROGS(ICECC_CREATE_ENV, icecc-create-env)
257    # Use icecc-create-env to create a minimal compilation environment that can
258    # be sent to the other hosts in the icecream cluster.
259    icecc_create_env_log="${CONFIGURESUPPORT_OUTPUTDIR}/icecc/icecc_create_env.log"
260    ${MKDIR} -p ${CONFIGURESUPPORT_OUTPUTDIR}/icecc
261    AC_MSG_CHECKING([for icecc build environment for target compiler])
262    if test "x${TOOLCHAIN_TYPE}" = "xgcc"; then
263      cd ${CONFIGURESUPPORT_OUTPUTDIR}/icecc \
264          && ${ICECC_CREATE_ENV} --gcc ${CC} ${CXX} > ${icecc_create_env_log}
265    elif test "x$TOOLCHAIN_TYPE" = "xclang"; then
266      # For clang, the icecc compilerwrapper is needed. It usually resides next
267      # to icecc-create-env.
268      BASIC_REQUIRE_PROGS(ICECC_WRAPPER, compilerwrapper)
269      cd ${CONFIGURESUPPORT_OUTPUTDIR}/icecc \
270          && ${ICECC_CREATE_ENV} --clang ${CC} ${ICECC_WRAPPER} > ${icecc_create_env_log}
271    else
272      AC_MSG_ERROR([Can only create icecc compiler packages for toolchain types gcc and clang])
273    fi
274    PATH="$old_path"
275    # The bundle with the compiler gets a name based on checksums. Parse log file
276    # to find it.
277    ICECC_ENV_BUNDLE_BASENAME="`${SED} -n '/^creating/s/creating //p' ${icecc_create_env_log}`"
278    ICECC_ENV_BUNDLE="${CONFIGURESUPPORT_OUTPUTDIR}/icecc/${ICECC_ENV_BUNDLE_BASENAME}"
279    AC_MSG_RESULT([${ICECC_ENV_BUNDLE}])
280    ICECC="ICECC_VERSION=${ICECC_ENV_BUNDLE} ICECC_CC=${CC} ICECC_CXX=${CXX} ${ICECC_CMD}"
281
282    if test "x${COMPILE_TYPE}" = "xcross"; then
283      # If cross compiling, create a separate env package for the build compiler
284      AC_MSG_CHECKING([for icecc build environment for build compiler])
285      # Assume "gcc" or "cc" is gcc and "clang" is clang. Otherwise bail.
286      if test "x${BUILD_CC##*/}" = "xgcc" ||  test "x${BUILD_CC##*/}" = "xcc"; then
287        cd ${CONFIGURESUPPORT_OUTPUTDIR}/icecc \
288            && ${ICECC_CREATE_ENV} --gcc ${BUILD_CC} ${BUILD_CXX} > ${icecc_create_env_log}
289      elif test "x${BUILD_CC##*/}" = "xclang"; then
290        cd ${CONFIGURESUPPORT_OUTPUTDIR}/icecc \
291            && ${ICECC_CREATE_ENV} --clang ${BUILD_CC} ${ICECC_WRAPPER} > ${icecc_create_env_log}
292      else
293        AC_MSG_ERROR([Cannot create icecc compiler package for ${BUILD_CC}])
294      fi
295      ICECC_ENV_BUNDLE_BASENAME="`${SED} -n '/^creating/s/creating //p' ${icecc_create_env_log}`"
296      ICECC_ENV_BUNDLE="${CONFIGURESUPPORT_OUTPUTDIR}/icecc/${ICECC_ENV_BUNDLE_BASENAME}"
297      AC_MSG_RESULT([${ICECC_ENV_BUNDLE}])
298      BUILD_ICECC="ICECC_VERSION=${ICECC_ENV_BUNDLE} ICECC_CC=${BUILD_CC} \
299          ICECC_CXX=${BUILD_CXX} ${ICECC_CMD}"
300    else
301      BUILD_ICECC="${ICECC}"
302    fi
303    AC_SUBST(ICECC)
304    AC_SUBST(BUILD_ICECC)
305  fi
306])
307
308AC_DEFUN_ONCE([BPERF_SETUP_PRECOMPILED_HEADERS],
309[
310
311  ###############################################################################
312  #
313  # Can the C/C++ compiler use precompiled headers?
314  #
315  AC_ARG_ENABLE([precompiled-headers], [AS_HELP_STRING([--disable-precompiled-headers],
316      [disable using precompiled headers when compiling C++ @<:@enabled@:>@])],
317      [ENABLE_PRECOMPH=${enable_precompiled_headers}], [ENABLE_PRECOMPH=yes])
318
319  USE_PRECOMPILED_HEADER=1
320  AC_MSG_CHECKING([If precompiled header is enabled])
321  if test "x$ENABLE_PRECOMPH" = xno; then
322    AC_MSG_RESULT([no, forced])
323    USE_PRECOMPILED_HEADER=0
324  elif test "x$ICECC" != "x"; then
325    AC_MSG_RESULT([no, does not work effectively with icecc])
326    USE_PRECOMPILED_HEADER=0
327  else
328    AC_MSG_RESULT([yes])
329  fi
330
331  if test "x$ENABLE_PRECOMPH" = xyes; then
332    # Check that the compiler actually supports precomp headers.
333    if test "x$TOOLCHAIN_TYPE" = xgcc; then
334      AC_MSG_CHECKING([that precompiled headers work])
335      echo "int alfa();" > conftest.h
336      $CXX -x c++-header conftest.h -o conftest.hpp.gch 2>&AS_MESSAGE_LOG_FD >&AS_MESSAGE_LOG_FD
337      if test ! -f conftest.hpp.gch; then
338        USE_PRECOMPILED_HEADER=0
339        AC_MSG_RESULT([no])
340      else
341        AC_MSG_RESULT([yes])
342      fi
343      rm -f conftest.h conftest.hpp.gch
344    fi
345  fi
346
347  AC_SUBST(USE_PRECOMPILED_HEADER)
348])
349
350
351AC_DEFUN_ONCE([BPERF_SETUP_SMART_JAVAC],
352[
353  AC_ARG_WITH(sjavac-server-java, [AS_HELP_STRING([--with-sjavac-server-java],
354      [use this java binary for running the sjavac background server @<:@Boot JDK java@:>@])])
355
356  if test "x$with_sjavac_server_java" != x; then
357    SJAVAC_SERVER_JAVA="$with_sjavac_server_java"
358    FOUND_VERSION=`$SJAVAC_SERVER_JAVA -version 2>&1 | grep " version \""`
359    if test "x$FOUND_VERSION" = x; then
360      AC_MSG_ERROR([Could not execute server java: $SJAVAC_SERVER_JAVA])
361    fi
362  else
363    SJAVAC_SERVER_JAVA="$JAVA"
364  fi
365  AC_SUBST(SJAVAC_SERVER_JAVA)
366
367  if test "$MEMORY_SIZE" -gt "3000"; then
368    ADD_JVM_ARG_IF_OK([-d64],SJAVAC_SERVER_JAVA_FLAGS,[$SJAVAC_SERVER_JAVA])
369    if test "$JVM_ARG_OK" = true; then
370      JVM_64BIT=true
371      JVM_ARG_OK=false
372    fi
373  fi
374
375  MX_VALUE=`expr $MEMORY_SIZE / 2`
376  if test "$JVM_64BIT" = true; then
377    # Set ms lower than mx since more than one instance of the server might
378    # get launched at the same time before they figure out which instance won.
379    MS_VALUE=512
380    if test "$MX_VALUE" -gt "2048"; then
381      MX_VALUE=2048
382    fi
383  else
384    MS_VALUE=256
385    if test "$MX_VALUE" -gt "1500"; then
386      MX_VALUE=1500
387    fi
388  fi
389  if test "$MX_VALUE" -lt "512"; then
390    MX_VALUE=512
391  fi
392  ADD_JVM_ARG_IF_OK([-Xms${MS_VALUE}M -Xmx${MX_VALUE}M],SJAVAC_SERVER_JAVA_FLAGS,[$SJAVAC_SERVER_JAVA])
393  AC_SUBST(SJAVAC_SERVER_JAVA_FLAGS)
394
395  AC_ARG_ENABLE([sjavac], [AS_HELP_STRING([--enable-sjavac],
396      [use sjavac to do fast incremental compiles @<:@disabled@:>@])],
397      [ENABLE_SJAVAC="${enableval}"], [ENABLE_SJAVAC="no"])
398  if test "x$JVM_ARG_OK" = "xfalse"; then
399    AC_MSG_WARN([Could not set -Xms${MS_VALUE}M -Xmx${MX_VALUE}M, disabling sjavac])
400    ENABLE_SJAVAC="no"
401  fi
402  AC_MSG_CHECKING([whether to use sjavac])
403  AC_MSG_RESULT([$ENABLE_SJAVAC])
404  AC_SUBST(ENABLE_SJAVAC)
405
406  AC_ARG_ENABLE([javac-server], [AS_HELP_STRING([--disable-javac-server],
407      [disable javac server @<:@enabled@:>@])],
408      [ENABLE_JAVAC_SERVER="${enableval}"], [ENABLE_JAVAC_SERVER="yes"])
409  if test "x$JVM_ARG_OK" = "xfalse"; then
410    AC_MSG_WARN([Could not set -Xms${MS_VALUE}M -Xmx${MX_VALUE}M, disabling javac server])
411    ENABLE_JAVAC_SERVER="no"
412  fi
413  AC_MSG_CHECKING([whether to use javac server])
414  AC_MSG_RESULT([$ENABLE_JAVAC_SERVER])
415  AC_SUBST(ENABLE_JAVAC_SERVER)
416
417  if test "x$ENABLE_JAVAC_SERVER" = "xyes" || "x$ENABLE_SJAVAC" = "xyes"; then
418    # When using a server javac, the small client instances do not need much
419    # resources.
420    JAVA_FLAGS_JAVAC="$JAVA_FLAGS_SMALL"
421  fi
422])
423