sbrk.S revision 1.18 
1/* $OpenBSD: sbrk.S,v 1.18 2023/12/10 16:45:51 deraadt Exp $ */
2
3/*
4 * Copyright (c) 1996 Dale Rahn
5 *
6 * Redistribution and use in source and binary forms, with or without
7 * modification, are permitted provided that the following conditions
8 * are met:
9 * 1. Redistributions of source code must retain the above copyright
10 *    notice, this list of conditions and the following disclaimer.
11 * 2. Redistributions in binary form must reproduce the above copyright
12 *    notice, this list of conditions and the following disclaimer in the
13 *    documentation and/or other materials provided with the distribution.
14 *
15 * THIS SOFTWARE IS PROVIDED BY THE AUTHOR ``AS IS'' AND ANY EXPRESS
16 * OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED
17 * WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
18 * ARE DISCLAIMED.  IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR ANY
19 * DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
20 * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
21 * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
22 * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
23 * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
24 * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
25 * SUCH DAMAGE.
26 */
27
28#include "SYS.h"
29
30	.data
31	.globl _end
32	.globl __curbrk
33	.hidden __curbrk
34__curbrk:
35	.long _end
36	END(__curbrk)
37	.type	__curbrk,@object
38
39	.text
40ENTRY_NB(sbrk)
41
42	/* call break(__curbrk + size) */
43#ifndef __PIC__
44	addis	6, 0, __curbrk@H
45	ori	6, 6, __curbrk@L	/* # 6 = &__curbrk */
46#else
47	mflr	10
48	bcl	20, 31, 1f
491:	mflr	9
50	addis	9, 9, _GLOBAL_OFFSET_TABLE_-1b@ha
51	addi	9, 9, _GLOBAL_OFFSET_TABLE_-1b@l
52	mtlr	10
53	lwz	6,__curbrk@got(9)
54#endif
55	lwz	5, 0(6)		/* # 5 = *6 (old_curbrk) */
56	add	3, 5, 3		/* # 3 = new_curbrk */
57	mr	7, 3
58
59	li	0, SYS_break
6099:	sc
61	PINSYSCALL(SYS_break, 99b)
62
63	/* check for error */
64	cmpwi	0, 0
65	beq+	.L_sbrk_ok
66	stw	0, R2_OFFSET_ERRNO(2)
67	li	3, -1
68	blr
69
70	/* update, __curbrk and return */
71.L_sbrk_ok:
72	stw	7, 0(6)		/* # remember, 6=&__curbrk, 7=new_curbrk */
73	mr	3, 5		/* # remember, 5=old_curbrk */
74	blr
75END(sbrk)
76	.weak	sbrk
77