sigsetjmp.S revision 1.4 
1/*-
2 * Copyright (c) 2002 Steve Murphree, Jr.
3 * All rights reserved.
4 *
5 * Redistribution and use in source and binary forms, with or without
6 * modification, are permitted provided that the following conditions
7 * are met:
8 * 1. Redistributions of source code must retain the above copyright
9 *    notice, this list of conditions and the following disclaimer.
10 * 2. Redistributions in binary form must reproduce the above copyright
11 *    notice, this list of conditions and the following disclaimer in the
12 *    documentation and/or other materials provided with the distribution.
13 * 3. All advertising materials mentioning features or use of this software
14 *    must display the following acknowledgement:
15 *      This product includes software developed by Steve Murphree, Jr.
16 * 4. The name of the author may not be used to endorse or promote products
17 *    derived from this software without specific prior written permission.
18 *
19 * THIS SOFTWARE IS PROVIDED BY THE AUTHOR ``AS IS'' AND ANY EXPRESS OR
20 * IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED WARRANTIES
21 * OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE DISCLAIMED.
22 * IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR ANY DIRECT, INDIRECT,
23 * INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT
24 * NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
25 * DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
26 * THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
27 * (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF
28 * THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
29 */
30
31#if defined(LIBC_SCCS)
32	.text
33	.string "$OpenBSD: sigsetjmp.S,v 1.4 2003/01/04 00:13:11 miod Exp $\0"
34#endif /* LIBC_SCCS */
35
36#include "SYS.h"
37
38/*
39 * C library -- sigsetjmp, siglongjmp
40 *
41 *	siglongjmp(a,v)
42 * will generate a "return(v)" from
43 * the last call to
44 *	sigsetjmp(a,m)
45 * by restoring registers from the stack,
46 * The previous signal state is restored if 'm' was non-zero.
47 *
48 * For m88k, we define our jmp_buf length
49 * to be the size of 22 longs.  <machine/setjmp.h>
50 * The buffer's usage is as follows:
51 *
52 * jmp_buf[0]		return address
53 * jmp_buf[1]		signal set (if used)
54 * jmp_buf[2 to 19]	r14 to r31
55 * jmp_buf[20]		'used' flag
56 * jmp_buf[21]		setjmp type
57 *
58 */
59
60#include <machine/setjmp.h>
61
62#define	SIGSETJMP_SIG	0x582e
63
64/*
65int sigsetjmp(jmp_buf env, int savemask);
66 */
67ENTRY(sigsetjmp)
68	st	r1, r2,0	/* save registers to the environment buffer */
69	st	r14,r2,8
70	st	r15,r2,12
71	st	r16,r2,16
72	st	r17,r2,20
73	st	r18,r2,24
74	st	r19,r2,28
75	st	r20,r2,32
76	st	r21,r2,36
77	st	r22,r2,40
78	st	r23,r2,44
79	st	r24,r2,48
80	st	r25,r2,52
81	st	r26,r2,56
82	st	r27,r2,60
83	st	r28,r2,64
84	st	r29,r2,68
85	st	r30,r2,72
86	st	r31,r2,76
87	st	r0,r2,80	/* mark environment as NOT returned (0x0) */
88	or	r4,r0,0		/* clear r4 */
89	or	r4,r0,SIGSETJMP_SIG	/* r4 now contains setjmp type */
90	st	r4,r2,84	/* setjmp type to _setjmp */
91
92	or	r15,r1,0	/* store return address in r15 */
93	or	r14,r2,0	/* store address of env in r14 */
94	or	r13,r3,0	/* store savemask in r13 */
95
96	cmp	r11,r13,r0	/* see if sigmask == 0 */
97	bb1.n	eq,r1,1f	/* skip sig stuff */
98	 st	r0,r14,4	/* but save 0 set in offset 4 of env first */
99
100	bsr.n	_C_LABEL(sigblock) /* r2 = sigblock(savemask) */
101	 or	r2,r0,r13
102	st	r2,r14,4	/* save signal set in offset 4 of env */
1031:	jmp.n	r15		/* return 0 */
104	 or	r2,r0,0
105
106/*
107void siglongjmp(sigjmp_buf env, int val);
108 */
109ENTRY(siglongjmp)
110	cmp	r4,r2,r0	/* check for bad environment buffer address. */
111	bb1	eq,r4,3f	/* if == 0, abort. */
112	ld	r4,r2,80	/* check if environment buffer has */
113	cmp	r4,r4,r0	/* already returned. */
114	bb1	ne,r4,3f	/* if != 0, abort. */
115	ld	r4,r2,84	/* check setjmp type. */
116	cmp	r4,r4,SIGSETJMP_SIG	/* should be SIGSETJMP_SIG */
117	bb1	ne,r4,3f	/* if != SIGSETJMP_SIG, abort. */
118
119	subu	r31,r31,32	/* get a temporary stack */
120	ld	r14,r2,8	/* restore registers from the environment buffer */
121	ld	r15,r2,12
122	ld	r16,r2,16
123	ld	r17,r2,20
124	ld	r18,r2,24
125	ld	r19,r2,28
126	ld	r20,r2,32
127	ld	r21,r2,36
128	ld	r22,r2,40
129	ld	r23,r2,44
130	ld	r24,r2,48
131	ld	r25,r2,52
132	ld	r26,r2,56
133	ld	r27,r2,60
134	ld	r28,r2,64
135	ld	r29,r2,68
136
137	ld	r4,r2,4		/* get the sinal set from env */
138	cmp	r4,r4,r0	/* if r2 == 0 then skip signal stuff */
139	bb1	eq,r4,1f
140
141	st	r2,r31,24	/* save r2 on stack (environment) */
142	st	r3,r31,28	/* save r3 on stack (return val) */
143	bsr.n	_C_LABEL(sigsetmask) /* restore the signal set */
144	 ld	r2,r2,4
145	ld	r2,r31,24	/* restore r2 from stack */
146	ld	r3,r31,28	/* restore r3 from stack */
1471:	ld	r30,r2,72	/* restore r30 */
148	ld	r31,r2,76	/* restore r31 (sp)*/
149	or	r4,r0,1
150	st	r4,r2,80	/* mark environment buffer as returned */
151	ld	r1,r2,0		/* restore r1 */
152	bcnd.n	ne0,r3,3f
153	 or	r2,r3,r0
154	or	r2,r0,1		/* never return zero! */
1553:	jmp	r1
156
1572:	subu	r31,r31,32	/* get a temporary stack */
158	st	r1,r31,20	/* save r1 on stack (return address) */
159	bsr	_C_LABEL(longjmperror)
160	bsr	_C_LABEL(abort)	/* NO RETURN */
161	ld	r1,r31,20	/* restore r1 from stack */
162	addu	r31,r31,32	/* restore the stack */
163	jmp	r1	/* this should not happen but we are prepared */
164
165