_setjmp.S revision 1.10 
1/* $OpenBSD: _setjmp.S,v 1.10 2013/01/05 11:20:55 miod Exp $ */
2/*-
3 * Copyright (c) 2002 Steve Murphree, Jr.
4 * All rights reserved.
5 *
6 * Redistribution and use in source and binary forms, with or without
7 * modification, are permitted provided that the following conditions
8 * are met:
9 * 1. Redistributions of source code must retain the above copyright
10 *    notice, this list of conditions and the following disclaimer.
11 * 2. Redistributions in binary form must reproduce the above copyright
12 *    notice, this list of conditions and the following disclaimer in the
13 *    documentation and/or other materials provided with the distribution.
14 * 3. All advertising materials mentioning features or use of this software
15 *    must display the following acknowledgement:
16 *      This product includes software developed by Steve Murphree, Jr.
17 * 4. The name of the author may not be used to endorse or promote products
18 *    derived from this software without specific prior written permission.
19 *
20 * THIS SOFTWARE IS PROVIDED BY THE AUTHOR ``AS IS'' AND ANY EXPRESS OR
21 * IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED WARRANTIES
22 * OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE DISCLAIMED.
23 * IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR ANY DIRECT, INDIRECT,
24 * INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT
25 * NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
26 * DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
27 * THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
28 * (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF
29 * THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
30 */
31
32#include "SYS.h"
33
34/*
35 * C library -- _setjmp, _longjmp
36 *
37 *	_longjmp(a,v)
38 * will generate a "return(v)" from the last call to
39 *	_setjmp(a)
40 * by restoring registers from the stack.  The previous signal state is
41 * neither saved nor restored.
42 *
43 * For m88k, we define our jmp_buf length to be the size of 21 (_JBLEN) longs.
44 * The buffer layout is as follows:
45 *
46 * jmp_buf[0]		return address
47 * jmp_buf[1]		unused
48 * jmp_buf[2 to 19]	r14 to r31
49 * jmp_buf[20]		setjmp type
50 */
51
52#define	U_SETJMP_SIG	0x1764
53
54/*
55int _setjmp(jmp_buf env);
56 */
57ENTRY(_setjmp)
58	st	%r1, %r2,0	/* save registers to the environment buffer */
59	st	%r14,%r2,8
60	st	%r15,%r2,12
61	st	%r16,%r2,16
62	st	%r17,%r2,20
63	st	%r18,%r2,24
64	st	%r19,%r2,28
65	st	%r20,%r2,32
66	st	%r21,%r2,36
67	st	%r22,%r2,40
68	st	%r23,%r2,44
69	st	%r24,%r2,48
70	st	%r25,%r2,52
71	st	%r26,%r2,56
72	st	%r27,%r2,60
73	st	%r28,%r2,64
74	st	%r29,%r2,68
75	st	%r30,%r2,72
76	st	%r31,%r2,76
77	or	%r4,%r0,U_SETJMP_SIG	/* setjmp type to _setjmp */
78	st	%r4,%r2,80
79	jmp.n	%r1
80	 or	%r2,%r0,0		/* return 0 */
81
82/*
83void _longjmp(jmp_buf env, int val);
84 */
85ENTRY(_longjmp)
86	bcnd	eq0,%r2,2f	/* check for bad environment buffer address. */
87	ld	%r4,%r2,80	/* check setjmp type. */
88	cmp	%r4,%r4,U_SETJMP_SIG	/* should be U_SETJMP_SIG */
89	bb1	ne,%r4,2f	/* if != U_SETJMP_SIG, abort. */
90
91	ld	%r14,%r2,8	/* restore registers from the environment buffer */
92	ld	%r15,%r2,12
93	ld	%r16,%r2,16
94	ld	%r17,%r2,20
95	ld	%r18,%r2,24
96	ld	%r19,%r2,28
97	ld	%r20,%r2,32
98	ld	%r21,%r2,36
99	ld	%r22,%r2,40
100	ld	%r23,%r2,44
101	ld	%r24,%r2,48
102	ld	%r25,%r2,52
103	ld	%r26,%r2,56
104	ld	%r27,%r2,60
105	ld	%r28,%r2,64
106	ld	%r29,%r2,68
107	ld	%r30,%r2,72
108	ld	%r31,%r2,76
109	ld	%r1,%r2,0		/* restore r1 */
110	bcnd.n	ne0,%r3,1f
111	 or	%r2,%r3,%r0
112	or	%r2,%r0,1		/* never return zero! */
1131:	jmp	%r1
114
1152:	subu	%r31,%r31,16	/* get a temporary stack */
116	st	%r1,%r31,0	/* save r1 on stack (return address) */
117	bsr	_C_LABEL(longjmperror)
118	bsr	_C_LABEL(abort)	/* NO RETURN */
119	ld	%r1,%r31,0	/* restore r1 from stack */
120	jmp.n	%r1	/* this should not happen but we are prepared */
121	 addu	%r31,%r31,16	/* restore the stack */
122
123