configure.ac revision 1.33 
1#	$NetBSD: configure.ac,v 1.33 2002/12/16 00:35:00 thorpej Exp $
2#
3# Autoconf definition file for libnbcompat.
4#
5
6AC_INIT([libnbcompat], [noversion], [lib-bug-people@netbsd.org])
7AC_CONFIG_HEADERS(config.h)
8AC_CONFIG_FILES(defs.mk)
9
10AC_PATH_PROG(BSHELL, sh, )
11if test x"$BSHELL" = x; then
12	AC_MSG_ERROR([sh must be somewhere on \$PATH])
13fi
14AC_DEFINE_UNQUOTED(PATH_BSHELL, "$BSHELL")
15
16AC_C_BIGENDIAN
17AC_HEADER_STDC
18
19# Confirm existence of zlib.  (This is available as a default install
20# option on many OS's; this could be added as a reachover build in the
21# future.)
22AC_CHECK_HEADER(zlib.h,,
23	AC_MSG_ERROR([zlib must be installed in a compiler-visible path]))
24AC_CHECK_LIB(z, gzdopen,,
25	AC_MSG_ERROR([zlib must be installed in a compiler-visible path]))
26
27# Make sure certain required headers are available.
28# These are not necessarily required by the code, but they are not
29# currently conditionalized.
30AC_CHECK_HEADERS(sys/ioctl.h sys/mman.h sys/mtio.h sys/param.h \
31	sys/stat.h sys/time.h sys/types.h sys/utsname.h sys/wait.h \
32	assert.h ctype.h errno.h fcntl.h grp.h limits.h locale.h \
33	netdb.h pwd.h signal.h stdarg.h stdio.h stdlib.h string.h \
34	termios.h unistd.h,,
35	AC_MSG_ERROR([standard system header file not found]))
36
37# Find headers that may not be available.
38AC_HEADER_DIRENT
39AC_CHECK_HEADERS(sys/sysmacros.h sys/syslimits.h \
40	features.h malloc.h poll.h stddef.h)
41AC_CHECK_HEADERS(machine/bswap.h sys/cdefs.h sys/endian.h sys/featuretest.h \
42	err.h inttypes.h libgen.h paths.h stdint.h util.h,,
43	[test -f include/$ac_header || touch include/$ac_header])
44AC_CHECK_HEADERS(rpc/types.h getopt.h netconfig.h,,
45	[echo '#include "config.h"' >include/$ac_header.new
46	echo '#include "'$srcdir/../../include/$ac_header'"' >>include/$ac_header.new
47	if cmp include/$ac_header.new include/$ac_header >/dev/null 2>&1; then
48		rm -f include/$ac_header.new
49	else
50		mv -f include/$ac_header.new include/$ac_header
51	fi])
52
53# Typedefs.
54AC_TYPE_SIZE_T
55AC_CHECK_TYPES([id_t, long long, u_quad_t])
56
57dnl XXX - This is UGLY.  Need a better way to homogenize the bitsized types,
58dnl including use of compiler primitive types via AC_CHECK_SIZEOF.
59dnl
60define([NB_CHECK_INTTYPE], [
61	AC_CHECK_TYPE(uint][$1][_t,, [
62		AC_CHECK_TYPE(u_int][$1][_t,
63			AC_DEFINE(uint][$1][_t, u_int][$1][_t),
64			AC_MSG_ERROR([cannot find a suitable type for uint][$1][_t]))
65	])
66	AC_CHECK_TYPE(u_int][$1][_t,, [
67		AC_CHECK_TYPE(uint][$1][_t,
68			AC_DEFINE(u_int][$1][_t, uint][$1][_t),
69			AC_MSG_ERROR([cannot find a suitable type for u_int][$1][_t]))
70	])
71])
72
73NB_CHECK_INTTYPE(8)
74NB_CHECK_INTTYPE(16)
75NB_CHECK_INTTYPE(32)
76NB_CHECK_INTTYPE(64)
77
78# Struct members.
79AC_CHECK_MEMBERS([DIR.dd_fd, struct dirent.d_namlen],,,
80[#include <sys/types.h>
81#include <dirent.h>])
82AC_CHECK_MEMBERS([struct stat.st_flags, struct stat.st_gen,
83	struct stat.st_mtimensec],,, [#include <sys/stat.h>])
84AC_CHECK_MEMBERS(struct statfs.f_iosize,,, [#include <sys/mount.h>])
85
86# Global variable decls.
87AC_CHECK_DECLS([optind, optreset],,, [
88#include <stdio.h>
89#include <stdlib.h>
90#include <unistd.h>
91])
92AC_CHECK_DECLS(sys_signame,,, [#include <signal.h>])
93
94# Library functions (where a .h check isn't enough).
95AC_FUNC_ALLOCA
96AC_CHECK_FUNCS(asprintf asnprintf basename dirfd dirname \
97	fgetln flock fparseln futimes getopt getopt_long \
98	isblank issetugid lchflags lchmod lchown lutimes mkstemp mkdtemp \
99	poll pread pwcache_userdb pwrite random setenv setgroupent \
100	setprogname setpassent snprintf strlcat strlcpy strsep \
101	strsuftoll strtoll \
102	user_from_uid vasprintf vasnprintf vsnprintf)
103
104AC_CHECK_DECLS([setgroupent, setpassent],,, [
105#include <sys/types.h>
106#include <grp.h>
107#include <pwd.h>
108])
109
110# regcomp() and regexec() are also names of functions in the old V8
111# regexp package.  To avoid them, we need to find out who has regfree().
112
113dnl # Cygwin: We *MUST* look at -lregex *before* the "no libs" condition.
114dnl # Thus AC_CHECK_LIB(regex...) comes first, and AC_SEARCHLIBS next.
115AC_CHECK_LIB(regex, regfree)
116AC_SEARCH_LIBS(regfree, rx posix)
117
118AC_OUTPUT
119