configure.ac revision 1.16 
1#	$NetBSD: configure.ac,v 1.16 2002/04/18 21:05:22 tv Exp $
2#
3# Autoconf definition file for libnbcompat.
4#
5
6AC_INIT([libnbcompat], [noversion], [lib-bug-people@netbsd.org])
7AC_CONFIG_HEADERS(config.h)
8AC_CONFIG_FILES(defs.mk)
9
10AC_C_BIGENDIAN
11AC_HEADER_STDC
12
13# Confirm existence of zlib.  (This is available as a default install
14# option on many OS's; this could be added as a reachover build in the
15# future.)
16AC_CHECK_HEADER(zlib.h,,
17	AC_MSG_ERROR([zlib must be installed in a compiler-visible path]))
18AC_CHECK_LIB(z, gzdopen,,
19	AC_MSG_ERROR([zlib must be installed in a compiler-visible path]))
20
21# Make sure certain required headers are available.
22# These are not necessarily required by the code, but they are not
23# currently conditionalized.
24AC_CHECK_HEADERS(sys/ioctl.h sys/mman.h sys/mtio.h sys/param.h \
25	sys/stat.h sys/time.h sys/types.h sys/utsname.h sys/wait.h \
26	assert.h ctype.h errno.h fcntl.h grp.h limits.h locale.h \
27	netdb.h pwd.h signal.h stdarg.h stdio.h stdlib.h string.h \
28	unistd.h,,
29	AC_MSG_ERROR([standard system header file not found]))
30
31# Find headers that may not be available.
32AC_HEADER_DIRENT
33AC_CHECK_HEADERS(sys/endian.h sys/sysmacros.h sys/syslimits.h \
34	features.h malloc.h stddef.h stdint.h)
35AC_CHECK_HEADERS(machine/bswap.h sys/cdefs.h sys/featuretest.h \
36	err.h inttypes.h libgen.h paths.h util.h,,
37	[test -f include/$ac_header || touch include/$ac_header])
38AC_CHECK_HEADERS(rpc/types.h fts.h getopt.h md2.h md4.h md5.h netconfig.h \
39	rmd160.h sha1.h vis.h,,
40	[echo '#include "config.h"' >include/$ac_header.new
41	echo '#include "'$srcdir/../../include/$ac_header'"' >>include/$ac_header.new
42	if cmp include/$ac_header.new include/$ac_header >/dev/null 2>&1; then
43		rm -f include/$ac_header.new
44	else
45		mv -f include/$ac_header.new include/$ac_header
46	fi])
47
48# Typedefs.
49AC_TYPE_SIZE_T
50AC_CHECK_TYPES([id_t, long long, u_quad_t])
51
52dnl XXX - This is UGLY.  Need a better way to homogenize the bitsized types,
53dnl including use of compiler primitive types via AC_CHECK_SIZEOF.
54dnl
55define([NB_CHECK_INTTYPE], [
56	AC_CHECK_TYPE(uint][$1][_t,, [
57		AC_CHECK_TYPE(u_int][$1][_t,
58			AC_DEFINE(uint][$1][_t, u_int][$1][_t),
59			AC_MSG_ERROR([cannot find a suitable type for uint][$1][_t]))
60	])
61	AC_CHECK_TYPE(u_int][$1][_t,, [
62		AC_CHECK_TYPE(uint][$1][_t,
63			AC_DEFINE(u_int][$1][_t, uint][$1][_t),
64			AC_MSG_ERROR([cannot find a suitable type for u_int][$1][_t]))
65	])
66])
67
68NB_CHECK_INTTYPE(8)
69NB_CHECK_INTTYPE(16)
70NB_CHECK_INTTYPE(32)
71NB_CHECK_INTTYPE(64)
72
73# Struct members.
74AC_CHECK_MEMBERS([DIR.dd_fd, struct dirent.d_namlen],,,
75	[#include <dirent.h>])
76AC_CHECK_MEMBERS([struct stat.st_flags, struct stat.st_gen,
77	struct stat.st_mtimensec],,, [#include <sys/stat.h>])
78AC_CHECK_MEMBERS(struct statfs.f_iosize,,, [#include <sys/mount.h>])
79
80# Global variable decls.
81AC_CHECK_DECLS([optind, optreset],,, [
82#include <stdio.h>
83#include <stdlib.h>
84#include <unistd.h>
85])
86AC_CHECK_DECLS(sys_signame,,, [#include <signal.h>])
87
88# Library functions (where a .h check isn't enough).
89AC_SEARCH_LIBS(fparseln, util)
90AC_CHECK_FUNCS(asprintf asnprintf basename dirfd dirname \
91	fgetln flock fparseln futimes getopt getopt_long \
92	isblank issetugid lchmod lchown lutimes pread pwcache_userdb \
93	pwrite setenv setgroupent setprogname setpassent \
94	snprintf strlcat strlcpy strsep vasprintf vasnprintf vsnprintf)
95
96AC_CHECK_DECLS([setgroupent, setpassent],,, [
97#include <grp.h>
98#include <pwd.h>
99])
100
101# regcomp() and regexec() are also names of functions in the old V8
102# regexp package.  To avoid them, we need to find out who has regfree().
103
104dnl # Cygwin: We *MUST* look at -lregex *before* the "no libs" condition.
105dnl # Thus AC_CHECK_LIB(regex...) comes first, and AC_SEARCHLIBS next.
106AC_CHECK_LIB(regex, regfree)
107AC_SEARCH_LIBS(regfree, rx posix)
108
109AC_OUTPUT
110