MAKEDEV.awk revision 1.14 
1#!/usr/bin/awk -
2#
3#	$NetBSD: MAKEDEV.awk,v 1.14 2004/03/18 22:51:59 enami Exp $
4#
5# Copyright (c) 2003 The NetBSD Foundation, Inc.
6# All rights reserved.
7#
8# This code is derived from software contributed to The NetBSD Foundation
9# by Jaromir Dolecek.
10#
11# Redistribution and use in source and binary forms, with or without
12# modification, are permitted provided that the following conditions
13# are met:
14# 1. Redistributions of source code must retain the above copyright
15#    notice, this list of conditions and the following disclaimer.
16# 2. Redistributions in binary form must reproduce the above copyright
17#    notice, this list of conditions and the following disclaimer in the
18#    documentation and/or other materials provided with the distribution.
19# 3. All advertising materials mentioning features or use of this software
20#    must display the following acknowledgement:
21#        This product includes software developed by the NetBSD
22#        Foundation, Inc. and its contributors.
23# 4. Neither the name of The NetBSD Foundation nor the names of its
24#    contributors may be used to endorse or promote products derived
25#    from this software without specific prior written permission.
26#
27# THIS SOFTWARE IS PROVIDED BY THE NETBSD FOUNDATION, INC. AND CONTRIBUTORS
28# ``AS IS'' AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED
29# TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR
30# PURPOSE ARE DISCLAIMED.  IN NO EVENT SHALL THE FOUNDATION OR CONTRIBUTORS
31# BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR
32# CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF
33# SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS
34# INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN
35# CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE)
36# ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE
37# POSSIBILITY OF SUCH DAMAGE.
38#
39
40# Script to generate platform MAKEDEV script from MI template, MD
41# MAKEDEV.conf and MD/MI major lists
42#
43# Uses environment variables MACHINE/MACHINE_ARCH to select
44# appropriate files, and NETBSDSRCDIR to get root of source tree.
45
46BEGIN {
47	# top of source tree, used to find major number list in kernel
48	# sources
49	machine = ENVIRON["MACHINE"]
50	maarch = ENVIRON["MACHINE_ARCH"]
51	srcdir = ENVIRON["NETBSDSRCDIR"]
52	if (!machine || !maarch || !srcdir) {
53		print "ERROR: 'MACHINE', 'MACHINE_ARCH' and 'NETBSDSRCDIR' must be set in environment" > "/dev/stderr"
54		exit 1
55	}
56	top = srcdir "/sys/"
57	if (system("test -d '" top "'") != 0) {
58		print "ERROR: can't find top of kernel source tree ('" top "' not a directory)" > "/dev/stderr"
59		exit 1
60	}
61
62
63	# file with major definitions
64	majors[0] = "conf/majors"
65	if ((maarch == "arm" || maarch == "armeb") && system("test -f '" top "arch/" machine "/conf/majors." machine "'") != 0)
66		majors[1] = "arch/arm/conf/majors.arm32";
67	else if (machine == "evbsh5") {
68		majors[1] = "arch/evbsh5/conf/majors.evbsh5";
69		majors[2] = "arch/sh5/conf/majors.sh5";
70	} else if (machine == "sbmips")
71		majors[1] = "arch/evbmips/conf/majors.evbmips";
72	else
73		majors[1] = "arch/" machine "/conf/majors." machine;
74
75	# process all files with majors and fill the chr[] and blk[]
76	# arrays, used in template processing
77	for (m in majors) {
78		file = top majors[m]
79		if (system("test -f '" file "'") != 0) {
80			print "ERROR: can't find majors file '" file "'" > "/dev/stderr"
81			exit 1
82		}
83		while (getline < file) {
84			if ($1 == "device-major") {
85				if ($3 == "char") {
86					chr[$2] = $4
87					if ($5 == "block")
88						blk[$2] = $6
89				} else if ($3 == "block")
90					blk[$2] = $4
91			}
92		}
93		close(file)
94	}
95
96	# read MD config file for MD device targets
97	cfgfile = srcdir "/etc/etc." machine "/MAKEDEV.conf"
98	if (system("test -f '" cfgfile "'") != 0) {
99		print "ERROR: no platform MAKEDEV.conf - '" cfgfile "' doesn't exist" > "/dev/stderr"
100		exit 1
101	}
102	# skip first two lines
103	getline CONFRCSID < cfgfile	# RCS Id
104	getline < cfgfile		# blank line
105	MDDEV = 0		# MD device targets
106	while (getline < cfgfile) {
107		if (MDDEV)
108			MDDEV = MDDEV "\n" $0
109		else
110			MDDEV = $0
111	}
112	close(cfgfile)
113
114	# determine number of partitions used by platform
115	# there are three variants in tree:
116	# 1. MAXPARTITIONS = 8
117	# 2. MAXPARTITIONS = 16 with no back compat mapping
118	# 3. MAXPARTITIONS = 16 with back compat with old limit of 8
119	# currently all archs, which moved from 8->16 use same
120	# scheme for mapping disk minors, high minor offset
121	# if this changes, the below needs to be adjusted and
122	# additional makedisk_p16foo needs to be added
123	incdir = machine
124	diskpartitions = 0
125	diskbackcompat = 0
126	while (1) {
127		inc = top "arch/" incdir "/include/disklabel.h"
128		if (system("test -f '" inc "'") != 0) {
129			print "ERROR: can't find kernel include file '" inc "'" > "/dev/stderr"
130			exit 1
131		}
132		incdir = 0
133		while (getline < inc) {
134			if ($1 == "#define" && $2 == "MAXPARTITIONS")
135				diskpartitions = $3
136			else if ($1 == "#define" && $2 == "OLDMAXPARTITIONS")
137				diskbackcompat = $3
138			else if ($1 == "#define" && $2 == "RAW_PART")
139				RAWDISK_OFF = $3
140			else if ($1 == "#include" && $2 ~ "<.*/disklabel.h>") {
141				# wrapper, switch to the right file
142				incdir = substr($2, 2)
143				sub("/.*", "", incdir)
144				break;
145			}
146		}
147		close(inc)
148
149		if (diskpartitions)
150			break;
151
152		if (!incdir) {
153			print "ERROR: can't determine MAXPARTITIONS from include file '" inc "'" > "/dev/stderr"
154			exit 1
155		}
156	}
157	MKDISK = "makedisk_p" diskpartitions	# routine to create disk devs
158	DISKMINOROFFSET = diskpartitions
159	if (diskbackcompat) {
160		MKDISK = MKDISK "high"
161		DISKMINOROFFSET = diskbackcompat
162	}
163	RAWDISK_NAME = sprintf("%c", 97 + RAWDISK_OFF)		# a+offset
164
165	# read etc/master.passwd for user name->UID mapping
166	idfile = srcdir "/etc/master.passwd"
167	if (system("test -f '" idfile "'") != 0) {
168		print "ERROR: can't find password file '" idfile "'" > "/dev/stderr"
169		exit 1
170	}
171	oldFS=FS
172	FS=":"
173	while (getline < idfile) {
174		uid[$1] = $3
175	}
176	close(idfile)
177	FS=oldFS
178
179	# read etc/group for group name->GID mapping
180	idfile = srcdir "/etc/group"
181	if (system("test -f '" idfile "'") != 0) {
182		print "ERROR: can't find group file '" idfile "'" > "/dev/stderr"
183		exit 1
184	}
185	oldFS=FS
186	FS=":"
187	while (getline < idfile) {
188		gid[$1] = $3
189	}
190	close(idfile)
191	FS=oldFS
192
193	# initially no substitutions
194	devsubst = 0
195	deventry = ""
196}
197
198/%MI_DEVICES_BEGIN%/ {
199	devsubst = 1;
200	next
201}
202
203/%MI_DEVICES_END%/ {
204	devsubst = 0;
205	next
206}
207
208# output 'Generated from' lines
209/\$[N]etBSD/ {
210	print "#"
211	print "# Generated from:"
212
213	# MAKEDEV.awk (this script) RCS Id
214	ARCSID = "$NetBSD: MAKEDEV.awk,v 1.14 2004/03/18 22:51:59 enami Exp $"
215	gsub(/\$/, "", ARCSID)
216	print "#	" ARCSID
217	
218	# MAKEDEV.tmpl RCS Id
219	gsub(/\$/, "")
220	print $0
221
222	# MD MAKEDEV.conf RCS Id
223	# strip leading hash and insert machine subdirectory name
224	gsub(/\$/, "", CONFRCSID)
225	sub(/^\# /, "", CONFRCSID)
226	sub(/MAKEDEV.conf/, "etc." machine "/MAKEDEV.conf", CONFRCSID)
227	print "#	" CONFRCSID
228
229	next # don't print the RCS Id line again
230}
231
232# filter the 'PLEASE RUN ...' paragraph
233/^\#   PLEASE RUN/, /^\#\#\#\#\#\#/ {
234	next
235}
236 
237# filter the device list
238/^\# Tapes/,/^$/ {
239	next
240}
241
242# filter the two unneeded makedisk_p* routines, leave only
243# the one used
244/^makedisk_p8\(\) \{/, /^\}/ {
245	if (MKDISK != "makedisk_p8")
246		next;
247}
248/^makedisk_p16\(\) \{/, /^\}/ {
249	if (MKDISK != "makedisk_p16")
250		next;
251}
252/^makedisk_p16high\(\) \{/, /^\}/ {
253	if (MKDISK != "makedisk_p16high")
254		next;
255}
256
257# special cases aside, handle normal line
258{
259	sub(/^%MD_DEVICES%/, MDDEV)
260	sub(/%MKDISK%/, MKDISK)
261	sub(/%DISKMINOROFFSET%/, DISKMINOROFFSET)
262	sub(/%RAWDISK_OFF%/, RAWDISK_OFF)
263	sub(/%RAWDISK_NAME%/, RAWDISK_NAME)
264	parsed = ""
265	line = $0
266	while (match(line, /%[gu]id_[a-z]*%/)) {
267		typ = substr(line, RSTART + 1, 3);
268		nam = substr(line, RSTART + 5, RLENGTH - 6);
269		if (typ == "uid") {
270			if (!(nam in uid)) {
271				print "ERROR unmatched uid in `" $0 "'" > \
272				    "/dev/stderr"
273				exit 1
274			} else
275				id = uid[nam];
276		} else {
277			if (!(nam in gid)) {
278				print "ERROR unmatched gid in `" $0 "'" > \
279				    "/dev/stderr"
280				exit 1
281			} else
282				id = gid[nam];
283		}
284		parsed = parsed substr(line, 0, RSTART - 1) id
285		line = substr(line, RSTART + RLENGTH)
286	}
287	$0 = parsed line
288
289	# if device substitutions are not active, do nothing more
290	if (!devsubst) {
291		print
292		next
293	}
294}
295
296# first line of device entry
297/^[a-z].*\)$/ {
298	if (length(deventry) > 0) {
299		# We have a previous entry to print. Replace all known
300		# character and block devices. If no unknown character
301		# or block device definition remains within the entry,
302		# print it to output, otherwise scrap it.
303		parsed = ""
304		while (match(deventry, /%[a-z]*_(blk|chr)%/)) {
305			nam = substr(deventry, RSTART + 1, RLENGTH - 6);
306			typ = substr(deventry, RSTART + RLENGTH - 4, 3);
307			if (typ == "blk") {
308				if (!(nam in blk)) {
309					deventry = $0
310					next
311				} else
312					dev = blk[nam];
313			} else {
314				if (!(nam in chr)) {
315					deventry = $0
316					next
317				} else
318					dev = chr[nam];
319			}
320			parsed = parsed substr(deventry, 0, RSTART - 1) dev
321			deventry = substr(deventry, RSTART + RLENGTH)
322		}
323
324		print parsed deventry
325	}
326	deventry = $0
327	next
328}
329
330# template line within device substitution section - just keep appending
331# to the current entry
332{
333	deventry = deventry "\n" $0
334}
335