1<?xml version="1.0"?>
2<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
3                version="1.0">
4
5<xsl:import href="docbook.xsl"/>
6
7<xsl:param name="show.revisionflag" select="'1'"/>
8
9<xsl:template name="user.head.content">
10<style type="text/css">
11<xsl:text>
12div.added    { background-color: yellow; }
13div.deleted  { text-decoration: line-through;
14               background-color: #FF7F7F; }
15div.changed  { background-color: lime; }
16div.off      {  }
17
18span.added   { background-color: yellow; }
19span.deleted { text-decoration: line-through;
20               background-color: #FF7F7F; }
21span.changed { background-color: lime; }
22span.off     {  }
23</xsl:text>
24</style>
25</xsl:template>
26
27<xsl:template match="*[@revisionflag]">
28  <xsl:choose>
29    <xsl:when test="local-name(.) = 'para'
30                    or local-name(.) = 'section'
31                    or local-name(.) = 'sect1'
32                    or local-name(.) = 'sect2'
33                    or local-name(.) = 'sect3'
34                    or local-name(.) = 'sect4'
35                    or local-name(.) = 'sect5'
36                    or local-name(.) = 'chapter'
37                    or local-name(.) = 'preface'
38                    or local-name(.) = 'itemizedlist'
39                    or local-name(.) = 'varlistentry'
40                    or local-name(.) = 'glossary'
41                    or local-name(.) = 'bibliography'
42                    or local-name(.) = 'index'
43                    or local-name(.) = 'appendix'">
44      <div class='{@revisionflag}'>
45	<xsl:apply-imports/>
46      </div>
47    </xsl:when>
48    <xsl:when test="local-name(.) = 'phrase'
49                    or local-name(.) = 'ulink'
50                    or local-name(.) = 'link'
51                    or local-name(.) = 'filename'
52                    or local-name(.) = 'literal'
53                    or local-name(.) = 'member'
54                    or local-name(.) = 'glossterm'
55                    or local-name(.) = 'quote'
56                    or local-name(.) = 'emphasis'
57                    or local-name(.) = 'command'
58                    or local-name(.) = 'xref'">
59      <span class='{@revisionflag}'>
60	<xsl:apply-imports/>
61      </span>
62    </xsl:when>
63    <xsl:when test="local-name(.) = 'listitem'
64                    or local-name(.) = 'title'">
65      <!-- nop; these are handled directly in the stylesheet -->
66      <xsl:apply-imports/>
67    </xsl:when>
68    <xsl:otherwise>
69      <xsl:message>
70	<xsl:text>Revisionflag on unexpected element: </xsl:text>
71	<xsl:value-of select="local-name(.)"/>
72	<xsl:text> (Assuming block)</xsl:text>
73      </xsl:message>
74      <div class='{@revisionflag}'>
75	<xsl:apply-imports/>
76      </div>
77    </xsl:otherwise>
78  </xsl:choose>
79</xsl:template>
80
81</xsl:stylesheet>
82