1# Configure template for GNU shar utilities.
2# Copyright (C) 1994 Free Software Foundation, Inc.
3# Process this file with autoconf to produce a configure script.
4
5# FIXME: AC_HAVE_HEADERS(sys/time.h)
6# FIXME: AC_HAVE_FUNCS(gethostname getwd)
7
8AC_INIT(src/shar.c)
9AC_CONFIG_HEADER(config.h)
10AC_ARG_PROGRAM
11
12PACKAGE=sharutils
13VERSION=4.2.1
14ALL_LINGUAS="de fr ja_JP.EUC nl pt sv"
15PROGRAMS="shar unshar"
16SCRIPTS="mail-files mailshar"
17MAN1PAGES="shar unshar"
18MAN5PAGES=
19AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE")
20AC_DEFINE_UNQUOTED(VERSION, "$VERSION")
21AC_SUBST(PACKAGE)
22AC_SUBST(VERSION)
23AC_SUBST(PROGRAMS)
24AC_SUBST(SCRIPTS)
25AC_SUBST(MAN1PAGES)
26AC_SUBST(MAN5PAGES)
27
28changequote(,)dnl
29case $VERSION in
30  [0-9]*.[0-9]*.[0-9]*) DIST_ALPHA="README-alpha";;
31  *) DIST_ALPHA=;;
32esac
33changequote([, ])dnl
34AC_SUBST(DIST_ALPHA)
35
36AC_PROG_CC
37fp_PROG_INSTALL
38AC_PROG_MAKE_SET
39AC_PROG_RANLIB
40
41dnl FIXME: Check that it is GNU diff indeed.
42# Carefully avoid gdiff for X as found on SGI systems.
43if (DISPLAY= gdiff /dev/null /dev/null) 2> /dev/null; then
44  AC_PATH_PROGS(DIFF, gnudiff diffgnu gdiff diff, no)
45else
46  AC_PATH_PROGS(DIFF, gnudiff diffgnu diff, no)
47fi
48
49dnl FIXME: Check that mailer accepts -s.
50PATH_save="$PATH"; PATH="$PATH:/usr/sbin:/usr/ucb:/usr/bin:/bin"
51AC_PATH_PROGS(MAILER, Mail mailx elm mush mail, no)
52PATH="$PATH_save"
53
54dnl FIXME: Check that perl was found.
55AC_PATH_PROG(PERL, perl, no)
56
57AC_PATH_PROGS(SH, bash sh, no)
58
59dnl FIXME: Check that it is GNU tar indeed.
60AC_PATH_PROGS(TAR, gnutar targnu gtar tar, tar)
61
62test $ac_cv_path_PERL = no || SCRIPTS="$SCRIPTS remsync"
63
64AC_AIX
65AC_ISC_POSIX
66AC_MINIX
67AC_C_CROSS
68if test $cross_compiling = no; then
69  AC_C_CHAR_UNSIGNED
70fi
71fp_C_PROTOTYPES
72AC_C_CONST
73AC_C_INLINE
74AC_C_BIGENDIAN
75
76AC_CHECK_HEADERS(limits.h locale.h memory.h string.h sys/wait.h unistd.h)
77AC_HEADER_DIRENT
78AC_HEADER_STAT
79AC_HEADER_STDC
80AC_STRUCT_TIMEZONE
81AC_TYPE_SIZE_T
82
83AC_CHECK_FUNCS(basename fchmod getcwd isascii memcpy strchr strerror uname)
84AC_FUNC_ALLOCA
85AC_FUNC_CLOSEDIR_VOID
86AC_FUNC_STRFTIME
87AC_FUNC_VPRINTF
88AC_REPLACE_FUNCS(memset mktime stpcpy strftime)
89test "$ac_cv_func_basename" = yes || LIBOBJS="$LIBOBJS basename.o"
90
91AC_MSG_CHECKING(for /etc/systemid)
92if test -f /etc/systemid; then
93  AC_MSG_RESULT(yes)
94  AC_DEFINE(HAVE_ETC_SYSTEMID)
95else
96  AC_MSG_RESULT(no)
97fi
98
99AC_MSG_CHECKING(if uuencode and uudecode are wanted)
100AC_ARG_ENABLE(uucode,
101[  --disable-uucode        disable installation of uuencode and uudecode],
102[if test "$enableval" = yes; then
103  AC_MSG_RESULT(yes)
104  PROGRAMS="$PROGRAMS uudecode uuencode"
105  # uuencode.1 should install first, for uudecode.1 will be a link to it.
106  MAN1PAGES="$MAN1PAGES uuencode uudecode"
107  MAN5PAGES="$MAN5PAGES uuencode"
108else
109  AC_MSG_RESULT(no)
110fi], [
111  AC_MSG_RESULT(yes)
112  PROGRAMS="$PROGRAMS uudecode uuencode"
113  # uuencode.1 should install first, for uudecode.1 will be a link to it.
114  MAN1PAGES="$MAN1PAGES uuencode uudecode"
115  MAN5PAGES="$MAN5PAGES uuencode"
116])
117
118ud_GNU_GETTEXT
119fp_WITH_DMALLOC
120
121# sharutils is somewhat special about internationalization in that it
122# always requires the GNU .mo files installed.
123if test "x$CATOBJEXT" = "x.mo" || test "x$CATOBJEXT" = "x.cat"; then
124  new_CATALOGS=""
125  for cat in $CATALOGS; do
126    lang=`echo $cat | sed "s/\(.*\)\..*/\1/"`
127    new_CATALOGS="$new_CATALOGS $cat $lang.gmo"
128  done
129  CATALOGS="$new_CATALOGS"
130fi
131
132AC_LINK_FILES($nls_cv_header_libgt, $nls_cv_header_intl)
133
134AC_OUTPUT([Makefile src/mail-files src/mailshar src/remsync contrib/Makefile \
135	   lib/Makefile intl/Makefile intl/po2tbl.sed src/Makefile \
136	   po/Makefile.in doc/Makefile checks/Makefile],
137[sed -e "/POTFILES =/r po/POTFILES" po/Makefile.in > po/Makefile; \
138 test -z "$CONFIG_HEADERS" || echo timestamp > stamp-h])
139