1------------------------------------------------------------------------------
2--                                                                          --
3--                         GNAT COMPILER COMPONENTS                         --
4--                                                                          --
5--                                N A M E T                                 --
6--                                                                          --
7--                                 S p e c                                  --
8--                                                                          --
9--          Copyright (C) 1992-2015, Free Software Foundation, Inc.         --
10--                                                                          --
11-- GNAT is free software;  you can  redistribute it  and/or modify it under --
12-- terms of the  GNU General Public License as published  by the Free Soft- --
13-- ware  Foundation;  either version 3,  or (at your option) any later ver- --
14-- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
15-- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
16-- or FITNESS FOR A PARTICULAR PURPOSE.                                     --
17--                                                                          --
18-- As a special exception under Section 7 of GPL version 3, you are granted --
19-- additional permissions described in the GCC Runtime Library Exception,   --
20-- version 3.1, as published by the Free Software Foundation.               --
21--                                                                          --
22-- You should have received a copy of the GNU General Public License and    --
23-- a copy of the GCC Runtime Library Exception along with this program;     --
24-- see the files COPYING3 and COPYING.RUNTIME respectively.  If not, see    --
25-- <http://www.gnu.org/licenses/>.                                          --
26--                                                                          --
27-- GNAT was originally developed  by the GNAT team at  New York University. --
28-- Extensive contributions were provided by Ada Core Technologies Inc.      --
29--                                                                          --
30------------------------------------------------------------------------------
31
32with Alloc;
33with Table;
34with Hostparm; use Hostparm;
35with System;   use System;
36with Types;    use Types;
37
38package Namet is
39
40--  WARNING: There is a C version of this package. Any changes to this
41--  source file must be properly reflected in the C header file namet.h
42--  which is created manually from namet.ads and namet.adb.
43
44--  This package contains routines for handling the names table. The table
45--  is used to store character strings for identifiers and operator symbols,
46--  as well as other string values such as unit names and file names.
47
48--  The forms of the entries are as follows:
49
50--    Identifiers        Stored with upper case letters folded to lower case.
51--                       Upper half (16#80# bit set) and wide characters are
52--                       stored in an encoded form (Uhh for upper half char,
53--                       Whhhh for wide characters, WWhhhhhhhh as provided by
54--                       the routine Store_Encoded_Character, where hh are hex
55--                       digits for the character code using lower case a-f).
56--                       Normally the use of U or W in other internal names is
57--                       avoided, but these letters may be used in internal
58--                       names (without this special meaning), if they appear
59--                       as the last character of the name, or they are
60--                       followed by an upper case letter (other than the WW
61--                       sequence), or an underscore.
62
63--    Operator symbols   Stored with an initial letter O, and the remainder
64--                       of the name is the lower case characters XXX where
65--                       the name is Name_Op_XXX, see Snames spec for a full
66--                       list of the operator names. Normally the use of O
67--                       in other internal names is avoided, but it may be
68--                       used in internal names (without this special meaning)
69--                       if it is the last character of the name, or if it is
70--                       followed by an upper case letter or an underscore.
71
72--    Character literals Character literals have names that are used only for
73--                       debugging and error message purposes. The form is an
74--                       upper case Q followed by a single lower case letter,
75--                       or by a Uxx/Wxxxx/WWxxxxxxx encoding as described for
76--                       identifiers. The Set_Character_Literal_Name procedure
77--                       should be used to construct these encodings. Normally
78--                       the use of O in other internal names is avoided, but
79--                       it may be used in internal names (without this special
80--                       meaning) if it is the last character of the name, or
81--                       if it is followed by an upper case letter or an
82--                       underscore.
83
84--    Unit names         Stored with upper case letters folded to lower case,
85--                       using Uhh/Whhhh/WWhhhhhhhh encoding as described for
86--                       identifiers, and a %s or %b suffix for specs/bodies.
87--                       See package Uname for further details.
88
89--    File names         Are stored in the form provided by Osint. Typically
90--                       they may include wide character escape sequences and
91--                       upper case characters (in non-encoded form). Casing
92--                       is also derived from the external environment. Note
93--                       that file names provided by Osint must generally be
94--                       consistent with the names from Fname.Get_File_Name.
95
96--    Other strings      The names table is also used as a convenient storage
97--                       location for other variable length strings such as
98--                       error messages etc. There are no restrictions on what
99--                       characters may appear for such entries.
100
101--  Note: the encodings Uhh (upper half characters), Whhhh (wide characters),
102--  WWhhhhhhhh (wide wide characters) and Qx (character literal names) are
103--  described in the spec, since they are visible throughout the system (e.g.
104--  in debugging output). However, no code should depend on these particular
105--  encodings, so it should be possible to change the encodings by making
106--  changes only to the Namet specification (to change these comments) and the
107--  body (which actually implements the encodings).
108
109--  The names are hashed so that a given name appears only once in the table,
110--  except that names entered with Name_Enter as opposed to Name_Find are
111--  omitted from the hash table.
112
113--  The first 26 entries in the names table (with Name_Id values in the range
114--  First_Name_Id .. First_Name_Id + 25) represent names which are the one
115--  character lower case letters in the range a-z, and these names are created
116--  and initialized by the Initialize procedure.
117
118--  Five values, one of type Int, one of type Byte, and three of type Boolean,
119--  are stored with each names table entry and subprograms are provided for
120--  setting and retrieving these associated values. The usage of these values
121--  is up to the client:
122
123--    In the compiler we have the following uses:
124
125--      The Int field is used to point to a chain of potentially visible
126--      entities (see Sem.Ch8 for details).
127
128--      The Byte field is used to hold the Token_Type value for reserved words
129--      (see Sem for details).
130
131--      The Boolean1 field is used to mark address clauses to optimize the
132--      performance of the Exp_Util.Following_Address_Clause function.
133
134--      The Boolean2 field is used to mark simple names that appear in
135--      Restriction[_Warning]s pragmas for No_Use_Of_Entity. This avoids most
136--      unnecessary searches of the No_Use_Of_Entity table.
137
138--      The Boolean3 field is not used
139
140--    In the binder, we have the following uses:
141
142--      The Int field is used in various ways depending on the name involved,
143--      see binder documentation for details.
144
145--      The Byte and Boolean fields are unused.
146
147--  Note that the value of the Int and Byte fields are initialized to zero,
148--  and the Boolean field is initialized to False, when a new Name table entry
149--  is created.
150
151   Name_Buffer : String (1 .. 4 * Max_Line_Length);
152   --  This buffer is used to set the name to be stored in the table for the
153   --  Name_Find call, and to retrieve the name for the Get_Name_String call.
154   --  The limit here is intended to be an infinite value that ensures that we
155   --  never overflow the buffer (names this long are too absurd to worry).
156
157   Name_Len : Natural := 0;
158   --  Length of name stored in Name_Buffer. Used as an input parameter for
159   --  Name_Find, and as an output value by Get_Name_String, or Write_Name.
160   --  Note: in normal usage, all users of Name_Buffer/Name_Len are expected
161   --  to initialize Name_Len appropriately. The reason we preinitialize to
162   --  zero here is that some circuitry (e.g. Osint.Write_Program_Name) does
163   --  a save/restore on Name_Len and Name_Buffer (1 .. Name_Len), and we do
164   --  not want some arbitrary junk value to result in saving an arbitrarily
165   --  long slice which would waste time and blow the stack.
166
167   -----------------------------
168   -- Types for Namet Package --
169   -----------------------------
170
171   --  Name_Id values are used to identify entries in the names table. Except
172   --  for the special values No_Name and Error_Name, they are subscript values
173   --  for the Names table defined in this package.
174
175   --  Note that with only a few exceptions, which are clearly documented, the
176   --  type Name_Id should be regarded as a private type. In particular it is
177   --  never appropriate to perform arithmetic operations using this type.
178
179   type Name_Id is range Names_Low_Bound .. Names_High_Bound;
180   for Name_Id'Size use 32;
181   --  Type used to identify entries in the names table
182
183   No_Name : constant Name_Id := Names_Low_Bound;
184   --  The special Name_Id value No_Name is used in the parser to indicate
185   --  a situation where no name is present (e.g. on a loop or block).
186
187   Error_Name : constant Name_Id := Names_Low_Bound +  1;
188   --  The special Name_Id value Error_Name is used in the parser to
189   --  indicate that some kind of error was encountered in scanning out
190   --  the relevant name, so it does not have a representable label.
191
192   subtype Error_Name_Or_No_Name is Name_Id range No_Name .. Error_Name;
193   --  Used to test for either error name or no name
194
195   First_Name_Id : constant Name_Id := Names_Low_Bound + 2;
196   --  Subscript of first entry in names table
197
198   ------------------------------
199   -- Name_Id Membership Tests --
200   ------------------------------
201
202   --  The following functions allow a convenient notation for testing whether
203   --  a Name_Id value matches any one of a list of possible values. In each
204   --  case True is returned if the given T argument is equal to any of the V
205   --  arguments. These essentially duplicate the Ada 2012 membership tests,
206   --  but we cannot use the latter (yet) in the compiler front end, because
207   --  of bootstrap considerations
208
209   function Nam_In
210     (T  : Name_Id;
211      V1 : Name_Id;
212      V2 : Name_Id) return Boolean;
213
214   function Nam_In
215     (T  : Name_Id;
216      V1 : Name_Id;
217      V2 : Name_Id;
218      V3 : Name_Id) return Boolean;
219
220   function Nam_In
221     (T  : Name_Id;
222      V1 : Name_Id;
223      V2 : Name_Id;
224      V3 : Name_Id;
225      V4 : Name_Id) return Boolean;
226
227   function Nam_In
228     (T  : Name_Id;
229      V1 : Name_Id;
230      V2 : Name_Id;
231      V3 : Name_Id;
232      V4 : Name_Id;
233      V5 : Name_Id) return Boolean;
234
235   function Nam_In
236     (T  : Name_Id;
237      V1 : Name_Id;
238      V2 : Name_Id;
239      V3 : Name_Id;
240      V4 : Name_Id;
241      V5 : Name_Id;
242      V6 : Name_Id) return Boolean;
243
244   function Nam_In
245     (T  : Name_Id;
246      V1 : Name_Id;
247      V2 : Name_Id;
248      V3 : Name_Id;
249      V4 : Name_Id;
250      V5 : Name_Id;
251      V6 : Name_Id;
252      V7 : Name_Id) return Boolean;
253
254   function Nam_In
255     (T  : Name_Id;
256      V1 : Name_Id;
257      V2 : Name_Id;
258      V3 : Name_Id;
259      V4 : Name_Id;
260      V5 : Name_Id;
261      V6 : Name_Id;
262      V7 : Name_Id;
263      V8 : Name_Id) return Boolean;
264
265   function Nam_In
266     (T  : Name_Id;
267      V1 : Name_Id;
268      V2 : Name_Id;
269      V3 : Name_Id;
270      V4 : Name_Id;
271      V5 : Name_Id;
272      V6 : Name_Id;
273      V7 : Name_Id;
274      V8 : Name_Id;
275      V9 : Name_Id) return Boolean;
276
277   function Nam_In
278     (T   : Name_Id;
279      V1  : Name_Id;
280      V2  : Name_Id;
281      V3  : Name_Id;
282      V4  : Name_Id;
283      V5  : Name_Id;
284      V6  : Name_Id;
285      V7  : Name_Id;
286      V8  : Name_Id;
287      V9  : Name_Id;
288      V10 : Name_Id) return Boolean;
289
290   function Nam_In
291     (T   : Name_Id;
292      V1  : Name_Id;
293      V2  : Name_Id;
294      V3  : Name_Id;
295      V4  : Name_Id;
296      V5  : Name_Id;
297      V6  : Name_Id;
298      V7  : Name_Id;
299      V8  : Name_Id;
300      V9  : Name_Id;
301      V10 : Name_Id;
302      V11 : Name_Id) return Boolean;
303
304   pragma Inline (Nam_In);
305   --  Inline all above functions
306
307   -----------------
308   -- Subprograms --
309   -----------------
310
311   procedure Finalize;
312   --  Called at the end of a use of the Namet package (before a subsequent
313   --  call to Initialize). Currently this routine is only used to generate
314   --  debugging output.
315
316   procedure Get_Name_String (Id : Name_Id);
317   --  Get_Name_String is used to retrieve the string associated with an entry
318   --  in the names table. The resulting string is stored in Name_Buffer and
319   --  Name_Len is set. It is an error to call Get_Name_String with one of the
320   --  special name Id values (No_Name or Error_Name).
321
322   function Get_Name_String (Id : Name_Id) return String;
323   --  This functional form returns the result as a string without affecting
324   --  the contents of either Name_Buffer or Name_Len. The lower bound is 1.
325
326   procedure Get_Unqualified_Name_String (Id : Name_Id);
327   --  Similar to the above except that qualification (as defined in unit
328   --  Exp_Dbug) is removed (including both preceding __ delimited names, and
329   --  also the suffixes used to indicate package body entities and to
330   --  distinguish between overloaded entities). Note that names are not
331   --  qualified until just before the call to gigi, so this routine is only
332   --  needed by processing that occurs after gigi has been called. This
333   --  includes all ASIS processing, since ASIS works on the tree written
334   --  after gigi has been called.
335
336   procedure Get_Name_String_And_Append (Id : Name_Id);
337   --  Like Get_Name_String but the resulting characters are appended to the
338   --  current contents of the entry stored in Name_Buffer, and Name_Len is
339   --  incremented to include the added characters.
340
341   procedure Get_Decoded_Name_String (Id : Name_Id);
342   --  Same calling sequence an interface as Get_Name_String, except that the
343   --  result is decoded, so that upper half characters and wide characters
344   --  appear as originally found in the source program text, operators have
345   --  their source forms (special characters and enclosed in quotes), and
346   --  character literals appear surrounded by apostrophes.
347
348   procedure Get_Unqualified_Decoded_Name_String (Id : Name_Id);
349   --  Similar to the above except that qualification (as defined in unit
350   --  Exp_Dbug) is removed (including both preceding __ delimited names, and
351   --  also the suffix used to indicate package body entities). Note that
352   --  names are not qualified until just before the call to gigi, so this
353   --  routine is only needed by processing that occurs after gigi has been
354   --  called. This includes all ASIS processing, since ASIS works on the tree
355   --  written after gigi has been called.
356
357   procedure Get_Decoded_Name_String_With_Brackets (Id : Name_Id);
358   --  This routine is similar to Decoded_Name, except that the brackets
359   --  notation (Uhh replaced by ["hh"], Whhhh replaced by ["hhhh"],
360   --  WWhhhhhhhh replaced by ["hhhhhhhh"]) is used for all non-lower half
361   --  characters, regardless of how Opt.Wide_Character_Encoding_Method is
362   --  set, and also in that characters in the range 16#80# .. 16#FF# are
363   --  converted to brackets notation in all cases. This routine can be used
364   --  when there is a requirement for a canonical representation not affected
365   --  by the character set options (e.g. in the binder generation of
366   --  symbols).
367
368   function Get_Name_Table_Byte (Id : Name_Id) return Byte;
369   pragma Inline (Get_Name_Table_Byte);
370   --  Fetches the Byte value associated with the given name
371
372   function Get_Name_Table_Int (Id : Name_Id) return Int;
373   pragma Inline (Get_Name_Table_Int);
374   --  Fetches the Int value associated with the given name
375
376   function Get_Name_Table_Boolean1 (Id : Name_Id) return Boolean;
377   function Get_Name_Table_Boolean2 (Id : Name_Id) return Boolean;
378   function Get_Name_Table_Boolean3 (Id : Name_Id) return Boolean;
379   --  Fetches the Boolean values associated with the given name
380
381   function Is_Operator_Name (Id : Name_Id) return Boolean;
382   --  Returns True if name given is of the form of an operator (that
383   --  is, it starts with an upper case O).
384
385   procedure Initialize;
386   --  This is a dummy procedure. It is retained for easy compatibility with
387   --  clients who used to call Initialize when this call was required. Now
388   --  initialization is performed automatically during package elaboration.
389   --  Note that this change fixes problems which existed prior to the change
390   --  of Initialize being called more than once. See also Reinitialize which
391   --  allows reinitialization of the tables.
392
393   procedure Lock;
394   --  Lock name tables before calling back end. We reserve some extra space
395   --  before locking to avoid unnecessary inefficiencies when we unlock.
396
397   procedure Reinitialize;
398   --  Clears the name tables and removes all existing entries from the table.
399
400   procedure Unlock;
401   --  Unlocks the name table to allow use of the extra space reserved by the
402   --  call to Lock. See gnat1drv for details of the need for this.
403
404   function Length_Of_Name (Id : Name_Id) return Nat;
405   pragma Inline (Length_Of_Name);
406   --  Returns length of given name in characters. This is the length of the
407   --  encoded name, as stored in the names table, the result is equivalent to
408   --  calling Get_Name_String and reading Name_Len, except that a call to
409   --  Length_Of_Name does not affect the contents of Name_Len and Name_Buffer.
410
411   function Name_Chars_Address return System.Address;
412   --  Return starting address of name characters table (used in Back_End call
413   --  to Gigi).
414
415   function Name_Find return Name_Id;
416   --  Name_Find is called with a string stored in Name_Buffer whose length is
417   --  in Name_Len (i.e. the characters of the name are in subscript positions
418   --  1 to Name_Len in Name_Buffer). It searches the names table to see if the
419   --  string has already been stored. If so the Id of the existing entry is
420   --  returned. Otherwise a new entry is created with its Name_Table_Int
421   --  fields set to zero/false. The contents of Name_Buffer and Name_Len are
422   --  not modified by this call. Note that it is permissible for Name_Len to
423   --  be set to zero to lookup the null name string.
424
425   function Name_Find_Str (S : String) return Name_Id;
426   --  Similar to Name_Find, except that the string is provided as an argument.
427   --  This call destroys the contents of Name_Buffer and Name_Len (by storing
428   --  the given string there.
429
430   function Name_Enter return Name_Id;
431   --  Name_Enter has the same calling interface as Name_Find. The difference
432   --  is that it does not search the table for an existing match, and also
433   --  subsequent Name_Find calls using the same name will not locate the
434   --  entry created by this call. Thus multiple calls to Name_Enter with the
435   --  same name will create multiple entries in the name table with different
436   --  Name_Id values. This is useful in the case of created names, which are
437   --  never expected to be looked up. Note: Name_Enter should never be used
438   --  for one character names, since these are efficiently located without
439   --  hashing by Name_Find in any case.
440
441   function Name_Entries_Address return System.Address;
442   --  Return starting address of Names table (used in Back_End call to Gigi)
443
444   function Name_Entries_Count return Nat;
445   --  Return current number of entries in the names table
446
447   function Is_OK_Internal_Letter (C : Character) return Boolean;
448   pragma Inline (Is_OK_Internal_Letter);
449   --  Returns true if C is a suitable character for using as a prefix or a
450   --  suffix of an internally generated name, i.e. it is an upper case letter
451   --  other than one of the ones used for encoding source names (currently
452   --  the set of reserved letters is O, Q, U, W) and also returns False for
453   --  the letter X, which is reserved for debug output (see Exp_Dbug).
454
455   function Is_Internal_Name (Id : Name_Id) return Boolean;
456   --  Returns True if the name is an internal name (i.e. contains a character
457   --  for which Is_OK_Internal_Letter is true, or if the name starts or ends
458   --  with an underscore. This call destroys the value of Name_Len and
459   --  Name_Buffer (it loads these as for Get_Name_String).
460   --
461   --  Note: if the name is qualified (has a double underscore), then only the
462   --  final entity name is considered, not the qualifying names. Consider for
463   --  example that the name:
464   --
465   --    pkg__B_1__xyz
466   --
467   --  is not an internal name, because the B comes from the internal name of
468   --  a qualifying block, but the xyz means that this was indeed a declared
469   --  identifier called "xyz" within this block and there is nothing internal
470   --  about that name.
471
472   function Is_Internal_Name return Boolean;
473   --  Like the form with an Id argument, except that the name to be tested is
474   --  passed in Name_Buffer and Name_Len (which are not affected by the call).
475   --  Name_Buffer (it loads these as for Get_Name_String).
476
477   function Is_Valid_Name (Id : Name_Id) return Boolean;
478   --  True if Id is a valid name -- points to a valid entry in the
479   --  Name_Entries table.
480
481   procedure Reset_Name_Table;
482   --  This procedure is used when there are multiple source files to reset
483   --  the name table info entries associated with current entries in the
484   --  names table. There is no harm in keeping the names entries themselves
485   --  from one compilation to another, but we can't keep the entity info,
486   --  since this refers to tree nodes, which are destroyed between each main
487   --  source file.
488
489   procedure Add_Char_To_Name_Buffer (C : Character);
490   pragma Inline (Add_Char_To_Name_Buffer);
491   --  Add given character to the end of the string currently stored in the
492   --  Name_Buffer, incrementing Name_Len.
493
494   procedure Add_Nat_To_Name_Buffer (V : Nat);
495   --  Add decimal representation of given value to the end of the string
496   --  currently stored in Name_Buffer, incrementing Name_Len as required.
497
498   procedure Add_Str_To_Name_Buffer (S : String);
499   --  Add characters of string S to the end of the string currently stored
500   --  in the Name_Buffer, incrementing Name_Len by the length of the string.
501
502   procedure Insert_Str_In_Name_Buffer (S : String; Index : Positive);
503   --  Inserts given string in name buffer, starting at Index. Any existing
504   --  characters at or past this location get moved beyond the inserted string
505   --  and Name_Len is incremented by the length of the string.
506
507   procedure Set_Character_Literal_Name (C : Char_Code);
508   --  This procedure sets the proper encoded name for the character literal
509   --  for the given character code. On return Name_Buffer and Name_Len are
510   --  set to reflect the stored name.
511
512   procedure Set_Name_Table_Int (Id : Name_Id; Val : Int);
513   pragma Inline (Set_Name_Table_Int);
514   --  Sets the Int value associated with the given name
515
516   procedure Set_Name_Table_Byte (Id : Name_Id; Val : Byte);
517   pragma Inline (Set_Name_Table_Byte);
518   --  Sets the Byte value associated with the given name
519
520   procedure Set_Name_Table_Boolean1 (Id : Name_Id; Val : Boolean);
521   procedure Set_Name_Table_Boolean2 (Id : Name_Id; Val : Boolean);
522   procedure Set_Name_Table_Boolean3 (Id : Name_Id; Val : Boolean);
523   --  Sets the Boolean value associated with the given name
524
525   procedure Store_Encoded_Character (C : Char_Code);
526   --  Stores given character code at the end of Name_Buffer, updating the
527   --  value in Name_Len appropriately. Lower case letters and digits are
528   --  stored unchanged. Other 8-bit characters are stored using the Uhh
529   --  encoding (hh = hex code), other 16-bit wide character values are stored
530   --  using the Whhhh (hhhh = hex code) encoding, and other 32-bit wide wide
531   --  character values are stored using the WWhhhhhhhh (hhhhhhhh = hex code).
532   --  Note that this procedure does not fold upper case letters (they are
533   --  stored using the Uhh encoding). If folding is required, it must be done
534   --  by the caller prior to the call.
535
536   procedure Tree_Read;
537   --  Initializes internal tables from current tree file using the relevant
538   --  Table.Tree_Read routines. Note that Initialize should not be called if
539   --  Tree_Read is used. Tree_Read includes all necessary initialization.
540
541   procedure Tree_Write;
542   --  Writes out internal tables to current tree file using the relevant
543   --  Table.Tree_Write routines.
544
545   procedure Get_Last_Two_Chars (N : Name_Id; C1, C2 : out Character);
546   --  Obtains last two characters of a name. C1 is last but one character
547   --  and C2 is last character. If name is less than two characters long,
548   --  then both C1 and C2 are set to ASCII.NUL on return.
549
550   procedure Write_Name (Id : Name_Id);
551   --  Write_Name writes the characters of the specified name using the
552   --  standard output procedures in package Output. No end of line is
553   --  written, just the characters of the name. On return Name_Buffer and
554   --  Name_Len are set as for a call to Get_Name_String. The name is written
555   --  in encoded form (i.e. including Uhh, Whhh, Qx, _op as they appear in
556   --  the name table). If Id is Error_Name, or No_Name, no text is output.
557
558   procedure Write_Name_Decoded (Id : Name_Id);
559   --  Like Write_Name, except that the name written is the decoded name, as
560   --  described for Get_Decoded_Name_String, and the resulting value stored
561   --  in Name_Len and Name_Buffer is the decoded name.
562
563   ------------------------------
564   -- File and Unit Name Types --
565   ------------------------------
566
567   --  These are defined here in Namet rather than Fname and Uname to avoid
568   --  problems with dependencies, and to avoid dragging in Fname and Uname
569   --  into many more files, but it would be cleaner to move to Fname/Uname.
570
571   type File_Name_Type is new Name_Id;
572   --  File names are stored in the names table and this type is used to
573   --  indicate that a Name_Id value is being used to hold a simple file name
574   --  (which does not include any directory information).
575
576   No_File : constant File_Name_Type := File_Name_Type (No_Name);
577   --  Constant used to indicate no file is present (this is used for example
578   --  when a search for a file indicates that no file of the name exists).
579
580   Error_File_Name : constant File_Name_Type := File_Name_Type (Error_Name);
581   --  The special File_Name_Type value Error_File_Name is used to indicate
582   --  a unit name where some previous processing has found an error.
583
584   subtype Error_File_Name_Or_No_File is
585     File_Name_Type range No_File .. Error_File_Name;
586   --  Used to test for either error file name or no file
587
588   type Path_Name_Type is new Name_Id;
589   --  Path names are stored in the names table and this type is used to
590   --  indicate that a Name_Id value is being used to hold a path name (that
591   --  may contain directory information).
592
593   No_Path : constant Path_Name_Type := Path_Name_Type (No_Name);
594   --  Constant used to indicate no path name is present
595
596   type Unit_Name_Type is new Name_Id;
597   --  Unit names are stored in the names table and this type is used to
598   --  indicate that a Name_Id value is being used to hold a unit name, which
599   --  terminates in %b for a body or %s for a spec.
600
601   No_Unit_Name : constant Unit_Name_Type := Unit_Name_Type (No_Name);
602   --  Constant used to indicate no file name present
603
604   Error_Unit_Name : constant Unit_Name_Type := Unit_Name_Type (Error_Name);
605   --  The special Unit_Name_Type value Error_Unit_Name is used to indicate
606   --  a unit name where some previous processing has found an error.
607
608   subtype Error_Unit_Name_Or_No_Unit_Name is
609     Unit_Name_Type range No_Unit_Name .. Error_Unit_Name;
610
611   ------------------------
612   -- Debugging Routines --
613   ------------------------
614
615   procedure wn (Id : Name_Id);
616   pragma Export (Ada, wn);
617   --  This routine is intended for debugging use only (i.e. it is intended to
618   --  be called from the debugger). It writes the characters of the specified
619   --  name using the standard output procedures in package Output, followed by
620   --  a new line. The name is written in encoded form (i.e. including Uhh,
621   --  Whhh, Qx, _op as they appear in the name table). If Id is Error_Name,
622   --  No_Name, or invalid an appropriate string is written (<Error_Name>,
623   --  <No_Name>, <invalid name>). Unlike Write_Name, this call does not affect
624   --  the contents of Name_Buffer or Name_Len.
625
626   ---------------------------
627   -- Table Data Structures --
628   ---------------------------
629
630   --  The following declarations define the data structures used to store
631   --  names. The definitions are in the private part of the package spec,
632   --  rather than the body, since they are referenced directly by gigi.
633
634private
635
636   --  This table stores the actual string names. Although logically there is
637   --  no need for a terminating character (since the length is stored in the
638   --  name entry table), we still store a NUL character at the end of every
639   --  name (for convenience in interfacing to the C world).
640
641   package Name_Chars is new Table.Table (
642     Table_Component_Type => Character,
643     Table_Index_Type     => Int,
644     Table_Low_Bound      => 0,
645     Table_Initial        => Alloc.Name_Chars_Initial,
646     Table_Increment      => Alloc.Name_Chars_Increment,
647     Table_Name           => "Name_Chars");
648
649   type Name_Entry is record
650      Name_Chars_Index : Int;
651      --  Starting location of characters in the Name_Chars table minus one
652      --  (i.e. pointer to character just before first character). The reason
653      --  for the bias of one is that indexes in Name_Buffer are one's origin,
654      --  so this avoids unnecessary adds and subtracts of 1.
655
656      Name_Len : Short;
657      --  Length of this name in characters
658
659      Byte_Info : Byte;
660      --  Byte value associated with this name
661
662      Boolean1_Info : Boolean;
663      Boolean2_Info : Boolean;
664      Boolean3_Info : Boolean;
665      --  Boolean values associated with the name
666
667      Name_Has_No_Encodings : Boolean;
668      --  This flag is set True if the name entry is known not to contain any
669      --  special character encodings. This is used to speed up repeated calls
670      --  to Get_Decoded_Name_String. A value of False means that it is not
671      --  known whether the name contains any such encodings.
672
673      Hash_Link : Name_Id;
674      --  Link to next entry in names table for same hash code
675
676      Int_Info : Int;
677      --  Int Value associated with this name
678
679   end record;
680
681   for Name_Entry use record
682      Name_Chars_Index      at  0 range 0 .. 31;
683      Name_Len              at  4 range 0 .. 15;
684      Byte_Info             at  6 range 0 .. 7;
685      Boolean1_Info         at  7 range 0 .. 0;
686      Boolean2_Info         at  7 range 1 .. 1;
687      Boolean3_Info         at  7 range 2 .. 2;
688      Name_Has_No_Encodings at  7 range 3 .. 7;
689      Hash_Link             at  8 range 0 .. 31;
690      Int_Info              at 12 range 0 .. 31;
691   end record;
692
693   for Name_Entry'Size use 16 * 8;
694   --  This ensures that we did not leave out any fields
695
696   --  This is the table that is referenced by Name_Id entries.
697   --  It contains one entry for each unique name in the table.
698
699   package Name_Entries is new Table.Table (
700     Table_Component_Type => Name_Entry,
701     Table_Index_Type     => Name_Id'Base,
702     Table_Low_Bound      => First_Name_Id,
703     Table_Initial        => Alloc.Names_Initial,
704     Table_Increment      => Alloc.Names_Increment,
705     Table_Name           => "Name_Entries");
706
707end Namet;
708