e_exp.S revision 23577 
1/*
2 * Copyright (c) 1993,94 Winning Strategies, Inc.
3 * All rights reserved.
4 *
5 * Redistribution and use in source and binary forms, with or without
6 * modification, are permitted provided that the following conditions
7 * are met:
8 * 1. Redistributions of source code must retain the above copyright
9 *    notice, this list of conditions and the following disclaimer.
10 * 2. Redistributions in binary form must reproduce the above copyright
11 *    notice, this list of conditions and the following disclaimer in the
12 *    documentation and/or other materials provided with the distribution.
13 * 3. All advertising materials mentioning features or use of this software
14 *    must display the following acknowledgement:
15 *      This product includes software developed by Winning Strategies, Inc.
16 * 4. The name of the author may not be used to endorse or promote products
17 *    derived from this software without specific prior written permission.
18 *
19 * THIS SOFTWARE IS PROVIDED BY THE AUTHOR ``AS IS'' AND ANY EXPRESS OR
20 * IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED WARRANTIES
21 * OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE DISCLAIMED.
22 * IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR ANY DIRECT, INDIRECT,
23 * INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT
24 * NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
25 * DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
26 * THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
27 * (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF
28 * THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
29 */
30
31/*
32 * Written by:
33 *	J.T. Conklin (jtc@wimsey.com), Winning Strategies, Inc.
34 */
35
36#include <machine/asm.h>
37
38RCSID("$Id: e_exp.S,v 1.6 1997/02/22 15:08:46 peter Exp $")
39
40/* e^x = 2^(x * log2(e)) */
41ENTRY(__ieee754_exp)
42	/*
43	 * If x is +-Inf, then the subtraction would give Inf-Inf = NaN.
44	 * Avoid this.  Also avoid it if x is NaN for convenience.
45	 */
46	movl	8(%esp),%eax
47	andl	$0x7fffffff,%eax
48	cmpl	$0x7ff00000,%eax
49	jae	x_Inf_or_NaN
50
51	fldl	4(%esp)
52
53	/*
54	 * Ensure that the rounding mode is to nearest (to give the smallest
55	 * possible fraction) and that the precision is as high as possible.
56	 * We may as well mask interrupts if we switch the mode.
57	 */
58	fstcw	4(%esp)
59	movl	4(%esp),%eax
60	andl	$0x0300,%eax
61	cmpl	$0x0300,%eax		/* RC == 0 && PC == 3? */
62	je	1f			/* jump if mode is good */
63	movl	$0x137f,8(%esp)
64	fldcw	8(%esp)
651:
66	fldl2e
67	fmulp				/* x * log2(e) */
68	fstl	%st(1)
69	frndint				/* int(x * log2(e)) */
70	fstl	%st(2)
71	fsubrp				/* fract(x * log2(e)) */
72	f2xm1				/* 2^(fract(x * log2(e))) - 1 */
73	fld1
74	faddp				/* 2^(fract(x * log2(e))) */
75	fscale				/* e^x */
76	fstpl	%st(1)
77	je	1f
78	fldcw	4(%esp)
791:
80	ret
81
82x_Inf_or_NaN:
83	/*
84	 * Return 0 if x is -Inf.  Otherwise just return x, although the
85	 * C version would return (x + x) (Real Indefinite) if x is a NaN.
86	 */
87	cmpl	$0xfff00000,8(%esp)
88	jne	x_not_minus_Inf
89	cmpl	$0,4(%esp)
90	jne	x_not_minus_Inf
91	fldz
92	ret
93
94x_not_minus_Inf:
95	fldl	4(%esp)
96	ret
97