setjmp.S revision 129202 
1/*	$NetBSD: setjmp.S,v 1.5 2003/04/05 23:08:51 bjh21 Exp $	*/
2
3/*
4 * Copyright (c) 1997 Mark Brinicombe
5 * All rights reserved.
6 *
7 * Redistribution and use in source and binary forms, with or without
8 * modification, are permitted provided that the following conditions
9 * are met:
10 * 1. Redistributions of source code must retain the above copyright
11 *    notice, this list of conditions and the following disclaimer.
12 * 2. Redistributions in binary form must reproduce the above copyright
13 *    notice, this list of conditions and the following disclaimer in the
14 *    documentation and/or other materials provided with the distribution.
15 * 3. All advertising materials mentioning features or use of this software
16 *    must display the following acknowledgement:
17 *	This product includes software developed by Mark Brinicombe
18 * 4. Neither the name of the University nor the names of its contributors
19 *    may be used to endorse or promote products derived from this software
20 *    without specific prior written permission.
21 *
22 * THIS SOFTWARE IS PROVIDED BY THE AUTHOR AND CONTRIBUTORS ``AS IS'' AND
23 * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
24 * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
25 * ARE DISCLAIMED.  IN NO EVENT SHALL THE AUTHOR OR CONTRIBUTORS BE LIABLE
26 * FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
27 * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
28 * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
29 * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
30 * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
31 * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
32 * SUCH DAMAGE.
33 */
34
35#include <machine/asm.h>
36__FBSDID("$FreeBSD: head/lib/libc/arm/gen/setjmp.S 129202 2004-05-14 12:04:31Z cognet $");
37/*
38 * C library -- setjmp, longjmp
39 *
40 *	longjmp(a,v)
41 * will generate a "return(v)" from the last call to
42 *	setjmp(a)
43 * by restoring registers from the stack.
44 * The previous signal state is restored.
45 */
46
47#define SOFTFLOAT /* XXX */
48ENTRY(setjmp)
49	/* Block all signals and retrieve the old signal mask */
50	stmfd	sp!, {r0, r14}
51	mov	r0, #0x00000000
52
53	bl	PIC_SYM(_C_LABEL(sigblock), PLT)
54	mov	r1, r0
55
56	ldmfd	sp!, {r0, r14}
57
58	/* Store signal mask */
59	str	r1, [r0, #(25 * 4)]
60
61	ldr	r1, .Lsetjmp_magic
62	str	r1, [r0], #4
63
64#ifdef SOFTFLOAT
65	add	r0, r0, #52
66#else
67	/* Store fp registers */
68	sfm	f4, 4, [r0], #48
69	/* Store fpsr */
70	rfs	r1
71	str	r1, [r0], #0x0004
72#endif	/*SOFTFLOAT*/
73	/* Store integer registers */
74        stmia	r0, {r4-r14}
75        mov	r0, #0x00000000
76        mov	r15, r14
77
78.Lsetjmp_magic:
79	.word	_JB_MAGIC_SETJMP
80
81
82.weak _C_LABEL(longjmp)
83.set _C_LABEL(longjmp), _C_LABEL(__longjmp)
84ENTRY(__longjmp)
85	ldr	r2, .Lsetjmp_magic
86	ldr	r3, [r0]
87	teq	r2, r3
88	bne	botch
89
90	/* Fetch signal mask */
91	ldr	r2, [r0, #(25 * 4)]
92
93	/* Set signal mask */
94	stmfd	sp!, {r0, r1, r14}
95	sub	sp, sp, #4	/* align the stack */
96
97	mov	r0, r2
98	bl	PIC_SYM(_C_LABEL(sigsetmask), PLT)
99
100	add	sp, sp, #4	/* unalign the stack */
101	ldmfd	sp!, {r0, r1, r14}
102
103	add	r0, r0, #4
104#ifdef SOFTFLOAT
105	add	r0, r0, #52
106#else
107	/* Restore fp registers */
108	lfm	f4, 4, [r0], #48
109	/* Restore FPSR */
110	ldr	r4, [r0], #0x0004
111	wfs	r4
112#endif	/* SOFTFLOAT */
113	/* Restore integer registers */
114        ldmia	r0, {r4-r14}
115
116	/* Validate sp and r14 */
117	teq	sp, #0
118	teqne	r14, #0
119	beq	botch
120
121	/* Set return value */
122
123	mov	r0, r1
124	teq	r0, #0x00000000
125	moveq	r0, #0x00000001
126	mov	r15, r14
127
128	/* validation failed, die die die. */
129botch:
130	bl	PIC_SYM(_C_LABEL(longjmperror), PLT)
131	bl	PIC_SYM(_C_LABEL(abort), PLT)
132	b	. - 8		/* Cannot get here */
133