setjmp.S revision 225736 
1/*-
2 * Copyright (c) 1990 The Regents of the University of California.
3 * All rights reserved.
4 *
5 * This code is derived from software contributed to Berkeley by
6 * William Jolitz.
7 *
8 * Redistribution and use in source and binary forms, with or without
9 * modification, are permitted provided that the following conditions
10 * are met:
11 * 1. Redistributions of source code must retain the above copyright
12 *    notice, this list of conditions and the following disclaimer.
13 * 2. Redistributions in binary form must reproduce the above copyright
14 *    notice, this list of conditions and the following disclaimer in the
15 *    documentation and/or other materials provided with the distribution.
16 * 4. Neither the name of the University nor the names of its contributors
17 *    may be used to endorse or promote products derived from this software
18 *    without specific prior written permission.
19 *
20 * THIS SOFTWARE IS PROVIDED BY THE REGENTS AND CONTRIBUTORS ``AS IS'' AND
21 * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
22 * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
23 * ARE DISCLAIMED.  IN NO EVENT SHALL THE REGENTS OR CONTRIBUTORS BE LIABLE
24 * FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
25 * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
26 * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
27 * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
28 * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
29 * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
30 * SUCH DAMAGE.
31 */
32
33#if defined(LIBC_SCCS) && !defined(lint)
34	.asciz "@(#)setjmp.s	5.1 (Berkeley) 4/23/90"
35#endif /* LIBC_SCCS and not lint */
36#include <machine/asm.h>
37__FBSDID("$FreeBSD: stable/9/lib/libc/amd64/gen/setjmp.S 217106 2011-01-07 16:08:40Z kib $");
38
39/*
40 * C library -- _setjmp, _longjmp
41 *
42 *	longjmp(a,v)
43 * will generate a "return(v)" from the last call to
44 *	setjmp(a)
45 * by restoring registers from the environment 'a'.
46 * The previous signal state is restored.
47 */
48
49#include "SYS.h"
50
51ENTRY(setjmp)
52	pushq	%rdi
53	movq	%rdi,%rcx
54	movq	$1,%rdi			/* SIG_BLOCK       */
55	movq	$0,%rsi			/* (sigset_t*)set  */
56	leaq	72(%rcx),%rdx		/* 9,10; (sigset_t*)oset */
57	call	PIC_PLT(CNAME(_sigprocmask))
58	popq	%rdi
59	movq	%rdi,%rcx
60	movq	0(%rsp),%rdx		/* retval */
61	movq	%rdx, 0(%rcx)		/* 0; retval */
62	movq	%rbx, 8(%rcx)		/* 1; rbx */
63	movq	%rsp,16(%rcx)		/* 2; rsp */
64	movq	%rbp,24(%rcx)		/* 3; rbp */
65	movq	%r12,32(%rcx)		/* 4; r12 */
66	movq	%r13,40(%rcx)		/* 5; r13 */
67	movq	%r14,48(%rcx)		/* 6; r14 */
68	movq	%r15,56(%rcx)		/* 7; r15 */
69	fnstcw	64(%rcx)		/* 8; fpu cw */
70	stmxcsr	68(%rcx)		/*    and mxcsr */
71	xorq	%rax,%rax
72	ret
73END(setjmp)
74
75	.weak CNAME(longjmp)
76	.set CNAME(longjmp),CNAME(__longjmp)
77ENTRY(__longjmp)
78	pushq	%rdi
79	pushq	%rsi
80	movq	%rdi,%rdx
81	movq	$3,%rdi			/* SIG_SETMASK     */
82	leaq	72(%rdx),%rsi		/* (sigset_t*)set  */
83	movq	$0,%rdx			/* (sigset_t*)oset */
84	call	PIC_PLT(CNAME(_sigprocmask))
85	popq	%rsi
86	popq	%rdi			/* jmpbuf */
87	movq	%rdi,%rdx
88	/* Restore the mxcsr, but leave exception flags intact. */
89	stmxcsr	-4(%rsp)
90	movl	68(%rdx),%eax
91	andl	$0xffffffc0,%eax
92	movl	-4(%rsp),%edi
93	andl	$0x3f,%edi
94	xorl	%eax,%edi
95	movl	%edi,-4(%rsp)
96	ldmxcsr -4(%rsp)
97	movq	%rsi,%rax		/* retval */
98	movq	0(%rdx),%rcx
99	movq	8(%rdx),%rbx
100	movq	16(%rdx),%rsp
101	movq	24(%rdx),%rbp
102	movq	32(%rdx),%r12
103	movq	40(%rdx),%r13
104	movq	48(%rdx),%r14
105	movq	56(%rdx),%r15
106	fldcw	64(%rdx)
107	testq	%rax,%rax
108	jnz	1f
109	incq	%rax
1101:	movq	%rcx,0(%rsp)
111	ret
112END(__longjmp)
113
114	.section .note.GNU-stack,"",%progbits
115