acpi_wakecode.S revision 121641 
1/*-
2 * Copyright (c) 2001 Takanori Watanabe <takawata@jp.freebsd.org>
3 * Copyright (c) 2001 Mitsuru IWASAKI <iwasaki@jp.freebsd.org>
4 * All rights reserved.
5 *
6 * Redistribution and use in source and binary forms, with or without
7 * modification, are permitted provided that the following conditions
8 * are met:
9 * 1. Redistributions of source code must retain the above copyright
10 *    notice, this list of conditions and the following disclaimer.
11 * 2. Redistributions in binary form must reproduce the above copyright
12 *    notice, this list of conditions and the following disclaimer in the
13 *    documentation and/or other materials provided with the distribution.
14 *
15 * THIS SOFTWARE IS PROVIDED BY THE AUTHOR AND CONTRIBUTORS ``AS IS'' AND
16 * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
17 * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
18 * ARE DISCLAIMED.  IN NO EVENT SHALL THE AUTHOR OR CONTRIBUTORS BE LIABLE
19 * FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
20 * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
21 * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
22 * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
23 * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
24 * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
25 * SUCH DAMAGE.
26 */
27
28#include <machine/asm.h>
29__FBSDID("$FreeBSD: head/sys/i386/acpica/acpi_wakecode.S 121641 2003-10-29 03:30:45Z iwasaki $");
30
31#define LOCORE
32
33#include <machine/specialreg.h>
34
35	.align 4
36	.code16
37wakeup_16:
38	nop
39	cli
40
41	/* Set up segment registers for real mode */
42	movw	%cs,%ax
43	movw	%ax,%ds
44	movw	%ax,%ss
45
46#ifndef ACPI_NO_RESET_VIDEO
47	/*
48	 * Re-initialize video BIOS.  Restore DS and SS from CS in
49	 * case the BIOS modified them.
50	 */
51	lcall	$0xc000, $3
52	movw	%cs, %ax
53	movw	%ax, %ds
54	movw	%ax, %ss
55#endif
56
57	/* Load GDT for real mode */
58	lgdt	physical_gdt
59
60	/* Restore CR2, CR3 and CR4 */
61	mov	previous_cr2,%eax
62	mov	%eax,%cr2
63	mov	previous_cr3,%eax
64	mov	%eax,%cr3
65	mov	previous_cr4,%eax
66	mov	%eax,%cr4
67
68	/* Transfer some values to protected mode */
69#define NVALUES	9
70#define TRANSFER_STACK32(val, idx)	\
71	mov	val,%eax;		\
72	mov	%eax,wakeup_32stack+(idx+1)+(idx*4);
73
74	TRANSFER_STACK32(previous_ss,		(NVALUES - 9))
75	TRANSFER_STACK32(previous_fs,		(NVALUES - 8))
76	TRANSFER_STACK32(previous_ds,		(NVALUES - 7))
77	TRANSFER_STACK32(physical_gdt+2,	(NVALUES - 6))
78	TRANSFER_STACK32(where_to_recover,	(NVALUES - 5))
79	TRANSFER_STACK32(previous_idt+2,	(NVALUES - 4))
80	TRANSFER_STACK32(previous_ldt,		(NVALUES - 3))
81	TRANSFER_STACK32(previous_gdt+2,	(NVALUES - 2))
82	TRANSFER_STACK32(previous_tr,		(NVALUES - 1))
83	TRANSFER_STACK32(previous_cr0,		(NVALUES - 0))
84
85	mov	physical_esp,%esi	/* to be used in 32bit code */
86
87	/* Enable protected mode */
88	mov	%cr0,%eax
89	orl	$(CR0_PE),%eax
90	mov	%eax,%cr0
91
92wakeup_sw32:
93	/* Switch to protected mode by intersegmental jump */
94	ljmpl	$0x8,$0x12345678	/* Code location, to be replaced */
95
96	.code32
97wakeup_32:
98	/*
99	 * Switched to protected mode w/o paging
100	 *	%esi:	KERNEL stack pointer (physical address)
101	 */
102
103	nop
104
105	/* Set up segment registers for protected mode */
106	movw	$0x10,%ax		/* KDSEL to segment registers */
107	movw	%ax,%ds
108	movw	%ax,%es
109	movw	%ax,%gs
110	movw	%ax,%ss
111	movw	$0x18,%ax		/* KPSEL to %fs */
112	movw	%ax,%fs
113	movl	%esi,%esp		/* physical address stack pointer */
114
115wakeup_32stack:
116	/* Operands are overwritten in 16bit code */
117	pushl	$0xabcdef09		/* ss + dummy */
118	pushl	$0xabcdef08		/* fs + gs */
119	pushl	$0xabcdef07		/* ds + es */
120	pushl	$0xabcdef06		/* gdt:base (physical address) */
121	pushl	$0xabcdef05		/* recover address */
122	pushl	$0xabcdef04		/* idt:base */
123	pushl	$0xabcdef03		/* ldt + idt:limit */
124	pushl	$0xabcdef02		/* gdt:base */
125	pushl	$0xabcdef01		/* TR + gdt:limit */
126	pushl	$0xabcdef00		/* CR0 */
127
128	movl	%esp,%ebp
129#define CR0_REGISTER		0(%ebp)
130#define TASK_REGISTER		4(%ebp)
131#define PREVIOUS_GDT		6(%ebp)
132#define PREVIOUS_LDT		12(%ebp)
133#define PREVIOUS_IDT		14(%ebp)
134#define RECOVER_ADDR		20(%ebp)
135#define PHYSICAL_GDT_BASE	24(%ebp)
136#define PREVIOUS_DS		28(%ebp)
137#define PREVIOUS_ES		30(%ebp)
138#define PREVIOUS_FS		32(%ebp)
139#define PREVIOUS_GS		34(%ebp)
140#define PREVIOUS_SS		36(%ebp)
141
142	/* Fixup TSS type field */
143#define TSS_TYPEFIX_MASK	0xf9
144	xorl	%esi,%esi
145	movl	PHYSICAL_GDT_BASE,%ebx
146	movw	TASK_REGISTER,%si
147	leal	(%ebx,%esi),%eax	/* get TSS segment descriptor */
148	andb	$TSS_TYPEFIX_MASK,5(%eax)
149
150	/* Prepare to return to sleep/wakeup code point */
151	lgdt	PREVIOUS_GDT
152	lidt	PREVIOUS_IDT
153
154	xorl	%eax,%eax
155	movl	%eax,%ebx
156	movl	%eax,%ecx
157	movl	%eax,%edx
158	movl	%eax,%esi
159	movl	%eax,%edi
160	movl	PREVIOUS_DS,%ebx
161	movl	PREVIOUS_FS,%ecx
162	movl	PREVIOUS_SS,%edx
163	movw	TASK_REGISTER,%si
164	shll	$16,%esi
165	movw	PREVIOUS_LDT,%si
166	movl	RECOVER_ADDR,%edi
167
168	/* Enable paging and etc. */
169	movl	CR0_REGISTER,%eax
170	movl	%eax,%cr0
171
172	/* Flush the prefetch queue */
173	jmp	1f
1741:	jmp	1f
1751:
176	/*
177	 * Now that we are in kernel virtual memory addressing
178	 *	%ebx:	ds + es
179	 *	%ecx:	fs + gs
180	 *	%edx:	ss + dummy
181	 *	%esi:	LDTR + TR
182	 *	%edi:	recover address
183	 */
184
185	nop
186
187	movl	%esi,%eax		/* LDTR + TR */
188	lldt	%ax			/* load LDT register */
189	shrl	$16,%eax
190	ltr	%ax			/* load task register */
191
192	/* Restore segment registers */
193	movl	%ebx,%eax		/* ds + es */
194	movw	%ax,%ds
195	shrl	$16,%eax
196	movw	%ax,%es
197	movl	%ecx,%eax		/* fs + gs */
198	movw	%ax,%fs
199	shrl	$16,%eax
200	movw	%ax,%gs
201	movl	%edx,%eax		/* ss */
202	movw	%ax,%ss
203
204	/* Jump to acpi_restorecpu() */
205	jmp	*%edi
206
207/* used in real mode */
208physical_gdt:		.word 0
209			.long 0
210physical_esp:		.long 0
211previous_cr2:		.long 0
212previous_cr3:		.long 0
213previous_cr4:		.long 0
214
215/* transfer from real mode to protected mode */
216previous_cr0:		.long 0
217previous_tr:		.word 0
218previous_gdt:		.word 0
219			.long 0
220previous_ldt:		.word 0
221previous_idt:		.word 0
222			.long 0
223where_to_recover:	.long 0
224previous_ds:		.word 0
225previous_es:		.word 0
226previous_fs:		.word 0
227previous_gs:		.word 0
228previous_ss:		.word 0
229dummy:			.word 0
230