memset.S revision 21673 
1/*
2 * Copyright (c) 1993 Winning Strategies, Inc.
3 * All rights reserved.
4 *
5 * Redistribution and use in source and binary forms, with or without
6 * modification, are permitted provided that the following conditions
7 * are met:
8 * 1. Redistributions of source code must retain the above copyright
9 *    notice, this list of conditions and the following disclaimer.
10 * 2. Redistributions in binary form must reproduce the above copyright
11 *    notice, this list of conditions and the following disclaimer in the
12 *    documentation and/or other materials provided with the distribution.
13 * 3. All advertising materials mentioning features or use of this software
14 *    must display the following acknowledgement:
15 *      This product includes software developed by Winning Strategies, Inc.
16 * 4. The name of the author may not be used to endorse or promote products
17 *    derived from this software without specific prior written permission
18 *
19 * THIS SOFTWARE IS PROVIDED BY THE AUTHOR ``AS IS'' AND ANY EXPRESS OR
20 * IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED WARRANTIES
21 * OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE DISCLAIMED.
22 * IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR ANY DIRECT, INDIRECT,
23 * INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT
24 * NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
25 * DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
26 * THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
27 * (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF
28 * THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
29 *
30 *	$FreeBSD: head/lib/libc/i386/string/memset.S 21673 1997-01-14 07:20:47Z jkh $
31 */
32
33#if defined(LIBC_RCS) && !defined(lint)
34	.text
35        .asciz "$FreeBSD: head/lib/libc/i386/string/memset.S 21673 1997-01-14 07:20:47Z jkh $"
36#endif /* LIBC_RCS and not lint */
37
38#include "DEFS.h"
39
40/*
41 * memset(void *b, int c, size_t len)
42 *	write len bytes of value c (converted to an unsigned char) to
43 *	the string b.
44 *
45 * Written by:
46 *	J.T. Conklin (jtc@wimsey.com), Winning Strategies, Inc.
47 */
48
49ENTRY(memset)
50	pushl	%edi
51	pushl	%ebx
52	movl	12(%esp),%edi
53	movzbl	16(%esp),%eax		/* unsigned char, zero extend */
54	movl	20(%esp),%ecx
55	pushl	%edi			/* push address of buffer */
56
57	cld				/* set fill direction forward */
58
59	/*
60	 * if the string is too short, it's really not worth the overhead
61	 * of aligning to word boundries, etc.  So we jump to a plain
62	 * unaligned set.
63	 */
64	cmpl	$0x0f,%ecx
65	jle	L1
66
67	movb	%al,%ah			/* copy char to all bytes in word */
68	movl	%eax,%edx
69	sall	$16,%eax
70	orl	%edx,%eax
71
72	movl	%edi,%edx		/* compute misalignment */
73	negl	%edx
74	andl	$3,%edx
75	movl	%ecx,%ebx
76	subl	%edx,%ebx
77
78	movl	%edx,%ecx		/* set until word aligned */
79	rep
80	stosb
81
82	movl	%ebx,%ecx
83	shrl	$2,%ecx			/* set by words */
84	rep
85	stosl
86
87	movl	%ebx,%ecx		/* set remainder by bytes */
88	andl	$3,%ecx
89L1:	rep
90	stosb
91
92	popl	%eax			/* pop address of buffer */
93	popl	%ebx
94	popl	%edi
95	ret
96