memset.S revision 1849 
1/*
2 * Copyright (c) 1993 Winning Strategies, Inc.
3 * All rights reserved.
4 *
5 * Redistribution and use in source and binary forms, with or without
6 * modification, are permitted provided that the following conditions
7 * are met:
8 * 1. Redistributions of source code must retain the above copyright
9 *    notice, this list of conditions and the following disclaimer.
10 * 2. Redistributions in binary form must reproduce the above copyright
11 *    notice, this list of conditions and the following disclaimer in the
12 *    documentation and/or other materials provided with the distribution.
13 * 3. All advertising materials mentioning features or use of this software
14 *    must display the following acknowledgement:
15 *      This product includes software developed by Winning Strategies, Inc.
16 * 4. The name of the author may not be used to endorse or promote products
17 *    derived from this software without specific prior written permission
18 *
19 * THIS SOFTWARE IS PROVIDED BY THE AUTHOR ``AS IS'' AND ANY EXPRESS OR
20 * IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED WARRANTIES
21 * OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE DISCLAIMED.
22 * IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR ANY DIRECT, INDIRECT,
23 * INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT
24 * NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
25 * DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
26 * THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
27 * (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF
28 * THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
29 *
30 *	$Id: memset.S,v 1.2 1994/03/31 14:11:01 davidg Exp $
31 */
32
33#if defined(LIBC_RCS) && !defined(lint)
34        .asciz "$Id: memset.S,v 1.2 1994/03/31 14:11:01 davidg Exp $"
35#endif /* LIBC_RCS and not lint */
36
37#include "DEFS.h"
38
39/*
40 * memset(void *b, int c, size_t len)
41 *	write len bytes of value c (converted to an unsigned char) to
42 *	the string b.
43 *
44 * Written by:
45 *	J.T. Conklin (jtc@wimsey.com), Winning Strategies, Inc.
46 */
47
48ENTRY(memset)
49	pushl	%edi
50	pushl	%ebx
51	movl	12(%esp),%edi
52	movzbl	16(%esp),%eax		/* unsigned char, zero extend */
53	movl	20(%esp),%ecx
54	pushl	%edi			/* push address of buffer */
55
56	cld				/* set fill direction forward */
57
58	/*
59	 * if the string is too short, it's really not worth the overhead
60	 * of aligning to word boundries, etc.  So we jump to a plain
61	 * unaligned set.
62	 */
63	cmpl	$0x0f,%ecx
64	jle	L1
65
66	movb	%al,%ah			/* copy char to all bytes in word */
67	movl	%eax,%edx
68	sall	$16,%eax
69	orl	%edx,%eax
70
71	movl	%edi,%edx		/* compute misalignment */
72	negl	%edx
73	andl	$3,%edx
74	movl	%ecx,%ebx
75	subl	%edx,%ebx
76
77	movl	%edx,%ecx		/* set until word aligned */
78	rep
79	stosb
80
81	movl	%ebx,%ecx
82	shrl	$2,%ecx			/* set by words */
83	rep
84	stosl
85
86	movl	%ebx,%ecx		/* set remainder by bytes */
87	andl	$3,%ecx
88L1:	rep
89	stosb
90
91	popl	%eax			/* pop address of buffer */
92	popl	%ebx
93	popl	%edi
94	ret
95