memcmp.S revision 1849 
1/*
2 * Copyright (c) 1993 Winning Strategies, Inc.
3 * All rights reserved.
4 *
5 * Redistribution and use in source and binary forms, with or without
6 * modification, are permitted provided that the following conditions
7 * are met:
8 * 1. Redistributions of source code must retain the above copyright
9 *    notice, this list of conditions and the following disclaimer.
10 * 2. Redistributions in binary form must reproduce the above copyright
11 *    notice, this list of conditions and the following disclaimer in the
12 *    documentation and/or other materials provided with the distribution.
13 * 3. All advertising materials mentioning features or use of this software
14 *    must display the following acknowledgement:
15 *      This product includes software developed by Winning Strategies, Inc.
16 * 4. The name of the author may not be used to endorse or promote products
17 *    derived from this software without specific prior written permission
18 *
19 * THIS SOFTWARE IS PROVIDED BY THE AUTHOR ``AS IS'' AND ANY EXPRESS OR
20 * IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED WARRANTIES
21 * OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE DISCLAIMED.
22 * IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR ANY DIRECT, INDIRECT,
23 * INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT
24 * NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
25 * DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
26 * THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
27 * (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF
28 * THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
29 *
30 *	$Id: memcmp.S,v 1.3 1994/03/31 14:10:59 davidg Exp $
31 */
32
33#if defined(LIBC_RCS) && !defined(lint)
34        .asciz "$Id: memcmp.S,v 1.3 1994/03/31 14:10:59 davidg Exp $"
35#endif /* LIBC_RCS and not lint */
36
37#include "DEFS.h"
38
39/*
40 * memcmp (void *b1, void *b2, size_t len)
41 *
42 * Written by:
43 *	J.T. Conklin (jtc@wimsey.com), Winning Strategies, Inc.
44 */
45
46ENTRY(memcmp)
47	pushl	%edi
48	pushl	%esi
49	movl	12(%esp),%edi
50	movl	16(%esp),%esi
51	cld				/* set compare direction forward */
52
53	movl	20(%esp),%ecx		/* compare by words */
54	shrl	$2,%ecx
55	repe
56	cmpsl
57	jne	L5			/* do we match so far? */
58
59	movl	20(%esp),%ecx		/* compare remainder by bytes */
60	andl	$3,%ecx
61	repe
62	cmpsb
63	jne	L6			/* do we match? */
64
65	xorl	%eax,%eax		/* we match, return zero	*/
66	popl	%esi
67	popl	%edi
68	ret
69
70L5:	movl	$4,%ecx			/* We know that one of the next	*/
71	subl	%ecx,%edi		/* four pairs of bytes do not	*/
72	subl	%ecx,%esi		/* match.			*/
73	repe
74	cmpsb
75L6:	movzbl  -1(%edi),%eax		/* Perform unsigned comparison	*/
76        movzbl  -1(%esi),%edx
77        subl    %edx,%eax
78	popl	%esi
79	popl	%edi
80	ret
81