WebAssemblyInstrControl.td revision 344779 
1//===- WebAssemblyInstrControl.td-WebAssembly control-flow ------*- tablegen -*-
2//
3//                     The LLVM Compiler Infrastructure
4//
5// This file is distributed under the University of Illinois Open Source
6// License. See LICENSE.TXT for details.
7//
8//===----------------------------------------------------------------------===//
9///
10/// \file
11/// WebAssembly control-flow code-gen constructs.
12///
13//===----------------------------------------------------------------------===//
14
15let isBranch = 1, isTerminator = 1, hasCtrlDep = 1 in {
16// The condition operand is a boolean value which WebAssembly represents as i32.
17defm BR_IF : I<(outs), (ins bb_op:$dst, I32:$cond),
18               (outs), (ins bb_op:$dst),
19               [(brcond I32:$cond, bb:$dst)],
20                "br_if   \t$dst, $cond", "br_if   \t$dst", 0x0d>;
21let isCodeGenOnly = 1 in
22defm BR_UNLESS : I<(outs), (ins bb_op:$dst, I32:$cond),
23                   (outs), (ins bb_op:$dst), []>;
24let isBarrier = 1 in {
25defm BR   : NRI<(outs), (ins bb_op:$dst),
26                [(br bb:$dst)],
27                "br      \t$dst", 0x0c>;
28} // isBarrier = 1
29} // isBranch = 1, isTerminator = 1, hasCtrlDep = 1
30
31def : Pat<(brcond (i32 (setne I32:$cond, 0)), bb:$dst),
32          (BR_IF bb_op:$dst, I32:$cond)>;
33def : Pat<(brcond (i32 (seteq I32:$cond, 0)), bb:$dst),
34          (BR_UNLESS bb_op:$dst, I32:$cond)>;
35
36// A list of branch targets enclosed in {} and separated by comma.
37// Used by br_table only.
38def BrListAsmOperand : AsmOperandClass { let Name = "BrList"; }
39let OperandNamespace = "WebAssembly" in {
40let OperandType = "OPERAND_BRLIST" in {
41def brlist : Operand<i32> {
42  let ParserMatchClass = BrListAsmOperand;
43  let PrintMethod = "printBrList";
44}
45} // OPERAND_BRLIST
46} // OperandNamespace = "WebAssembly"
47
48// TODO: SelectionDAG's lowering insists on using a pointer as the index for
49// jump tables, so in practice we don't ever use BR_TABLE_I64 in wasm32 mode
50// currently.
51let isTerminator = 1, hasCtrlDep = 1, isBarrier = 1 in {
52defm BR_TABLE_I32 : I<(outs), (ins I32:$index, variable_ops),
53                      (outs), (ins brlist:$brl),
54                      [(WebAssemblybr_table I32:$index)],
55                      "br_table \t$index", "br_table \t$brl",
56                      0x0e>;
57defm BR_TABLE_I64 : I<(outs), (ins I64:$index, variable_ops),
58                      (outs), (ins brlist:$brl),
59                      [(WebAssemblybr_table I64:$index)],
60                      "br_table \t$index", "br_table \t$brl",
61                      0x0e>;
62} // isTerminator = 1, hasCtrlDep = 1, isBarrier = 1
63
64// This is technically a control-flow instruction, since all it affects is the
65// IP.
66defm NOP : NRI<(outs), (ins), [], "nop", 0x01>;
67
68// Placemarkers to indicate the start or end of a block or loop scope.
69// These use/clobber VALUE_STACK to prevent them from being moved into the
70// middle of an expression tree.
71let Uses = [VALUE_STACK], Defs = [VALUE_STACK] in {
72defm BLOCK : NRI<(outs), (ins Signature:$sig), [], "block   \t$sig", 0x02>;
73defm LOOP  : NRI<(outs), (ins Signature:$sig), [], "loop    \t$sig", 0x03>;
74
75defm IF : I<(outs), (ins Signature:$sig, I32:$cond),
76            (outs), (ins Signature:$sig),
77            [], "if    \t$sig, $cond", "if    \t$sig", 0x04>;
78defm ELSE : NRI<(outs), (ins), [], "else", 0x05>;
79
80// END_BLOCK, END_LOOP, END_IF and END_FUNCTION are represented with the same
81// opcode in wasm.
82defm END_BLOCK : NRI<(outs), (ins), [], "end_block", 0x0b>;
83defm END_LOOP  : NRI<(outs), (ins), [], "end_loop", 0x0b>;
84defm END_IF    : NRI<(outs), (ins), [], "end_if", 0x0b>;
85let isTerminator = 1, isBarrier = 1 in
86defm END_FUNCTION : NRI<(outs), (ins), [], "end_function", 0x0b>;
87} // Uses = [VALUE_STACK], Defs = [VALUE_STACK]
88
89multiclass RETURN<WebAssemblyRegClass vt> {
90  defm RETURN_#vt : I<(outs), (ins vt:$val), (outs), (ins),
91                      [(WebAssemblyreturn vt:$val)],
92                      "return  \t$val", "return", 0x0f>;
93  // Equivalent to RETURN_#vt, for use at the end of a function when wasm
94  // semantics return by falling off the end of the block.
95  let isCodeGenOnly = 1 in
96  defm FALLTHROUGH_RETURN_#vt : I<(outs), (ins vt:$val), (outs), (ins), []>;
97}
98
99multiclass SIMD_RETURN<ValueType vt> {
100  defm RETURN_#vt : I<(outs), (ins V128:$val), (outs), (ins),
101                      [(WebAssemblyreturn (vt V128:$val))],
102                      "return  \t$val", "return", 0x0f>,
103                    Requires<[HasSIMD128]>;
104  // Equivalent to RETURN_#vt, for use at the end of a function when wasm
105  // semantics return by falling off the end of the block.
106  let isCodeGenOnly = 1 in
107  defm FALLTHROUGH_RETURN_#vt : I<(outs), (ins V128:$val), (outs), (ins),
108                                  []>,
109                                Requires<[HasSIMD128]>;
110}
111
112let isTerminator = 1, hasCtrlDep = 1, isBarrier = 1 in {
113
114let isReturn = 1 in {
115  defm "": RETURN<I32>;
116  defm "": RETURN<I64>;
117  defm "": RETURN<F32>;
118  defm "": RETURN<F64>;
119  defm "": RETURN<EXCEPT_REF>;
120  defm "": SIMD_RETURN<v16i8>;
121  defm "": SIMD_RETURN<v8i16>;
122  defm "": SIMD_RETURN<v4i32>;
123  defm "": SIMD_RETURN<v2i64>;
124  defm "": SIMD_RETURN<v4f32>;
125  defm "": SIMD_RETURN<v2f64>;
126
127  defm RETURN_VOID : NRI<(outs), (ins), [(WebAssemblyreturn)], "return", 0x0f>;
128
129  // This is to RETURN_VOID what FALLTHROUGH_RETURN_#vt is to RETURN_#vt.
130  let isCodeGenOnly = 1 in
131  defm FALLTHROUGH_RETURN_VOID : NRI<(outs), (ins), []>;
132} // isReturn = 1
133
134defm UNREACHABLE : NRI<(outs), (ins), [(trap)], "unreachable", 0x00>;
135} // isTerminator = 1, hasCtrlDep = 1, isBarrier = 1
136
137//===----------------------------------------------------------------------===//
138// Exception handling instructions
139//===----------------------------------------------------------------------===//
140
141let Predicates = [HasExceptionHandling] in {
142
143// Throwing an exception: throw / rethrow
144let isTerminator = 1, hasCtrlDep = 1, isBarrier = 1 in {
145defm THROW_I32 : I<(outs), (ins event_op:$tag, I32:$val),
146                   (outs), (ins event_op:$tag),
147                   [(WebAssemblythrow (WebAssemblywrapper texternalsym:$tag),
148                                      I32:$val)],
149                   "throw   \t$tag, $val", "throw   \t$tag",
150                   0x08>;
151defm THROW_I64 : I<(outs), (ins event_op:$tag, I64:$val),
152                   (outs), (ins event_op:$tag),
153                   [(WebAssemblythrow (WebAssemblywrapper texternalsym:$tag),
154                                      I64:$val)],
155                   "throw   \t$tag, $val", "throw   \t$tag",
156                   0x08>;
157defm RETHROW : NRI<(outs), (ins bb_op:$dst), [], "rethrow \t$dst", 0x09>;
158let isCodeGenOnly = 1 in
159// This is used when the destination for rethrow is the caller function. This
160// will be converted to a rethrow in CFGStackify.
161defm RETHROW_TO_CALLER : NRI<(outs), (ins), [], "rethrow">;
162} // isTerminator = 1, hasCtrlDep = 1, isBarrier = 1
163
164// Region within which an exception is caught: try / end_try
165let Uses = [VALUE_STACK], Defs = [VALUE_STACK] in {
166defm TRY     : NRI<(outs), (ins Signature:$sig), [], "try     \t$sig", 0x06>;
167defm END_TRY : NRI<(outs), (ins), [], "end_try", 0x0b>;
168} // Uses = [VALUE_STACK], Defs = [VALUE_STACK]
169
170// Catching an exception: catch / catch_all
171let hasCtrlDep = 1, hasSideEffects = 1 in {
172defm CATCH_I32 : I<(outs I32:$dst), (ins i32imm:$tag),
173                   (outs), (ins i32imm:$tag),
174                   [(set I32:$dst, (int_wasm_catch imm:$tag))],
175                   "i32.catch   \t$dst, $tag", "i32.catch   \t$tag", 0x07>;
176defm CATCH_I64 : I<(outs I64:$dst), (ins i32imm:$tag),
177                   (outs), (ins i32imm:$tag),
178                   [(set I64:$dst, (int_wasm_catch imm:$tag))],
179                   "i64.catch   \t$dst, $tag", "i64.catch   \t$tag", 0x07>;
180defm CATCH_ALL : NRI<(outs), (ins), [], "catch_all", 0x05>;
181}
182
183// Pseudo instructions: cleanupret / catchret
184let isTerminator = 1, hasSideEffects = 1, isBarrier = 1, hasCtrlDep = 1,
185    isCodeGenOnly = 1, isEHScopeReturn = 1 in {
186  defm CLEANUPRET : NRI<(outs), (ins), [(cleanupret)], "", 0>;
187  defm CATCHRET : NRI<(outs), (ins bb_op:$dst, bb_op:$from),
188                   [(catchret bb:$dst, bb:$from)], "", 0>;
189}
190}
191