WebAssemblyInstrControl.td revision 341825 
1//===- WebAssemblyInstrControl.td-WebAssembly control-flow ------*- tablegen -*-
2//
3//                     The LLVM Compiler Infrastructure
4//
5// This file is distributed under the University of Illinois Open Source
6// License. See LICENSE.TXT for details.
7//
8//===----------------------------------------------------------------------===//
9///
10/// \file
11/// WebAssembly control-flow code-gen constructs.
12///
13//===----------------------------------------------------------------------===//
14
15let Defs = [ARGUMENTS] in {
16
17let isBranch = 1, isTerminator = 1, hasCtrlDep = 1 in {
18// The condition operand is a boolean value which WebAssembly represents as i32.
19defm BR_IF : I<(outs), (ins bb_op:$dst, I32:$cond),
20               (outs), (ins bb_op:$dst),
21               [(brcond I32:$cond, bb:$dst)],
22                "br_if   \t$dst, $cond", "br_if   \t$dst", 0x0d>;
23let isCodeGenOnly = 1 in
24defm BR_UNLESS : I<(outs), (ins bb_op:$dst, I32:$cond),
25                   (outs), (ins bb_op:$dst), []>;
26let isBarrier = 1 in {
27defm BR   : NRI<(outs), (ins bb_op:$dst),
28                [(br bb:$dst)],
29                "br      \t$dst", 0x0c>;
30} // isBarrier = 1
31} // isBranch = 1, isTerminator = 1, hasCtrlDep = 1
32
33} // Defs = [ARGUMENTS]
34
35def : Pat<(brcond (i32 (setne I32:$cond, 0)), bb:$dst),
36          (BR_IF bb_op:$dst, I32:$cond)>;
37def : Pat<(brcond (i32 (seteq I32:$cond, 0)), bb:$dst),
38          (BR_UNLESS bb_op:$dst, I32:$cond)>;
39
40let Defs = [ARGUMENTS] in {
41
42// TODO: SelectionDAG's lowering insists on using a pointer as the index for
43// jump tables, so in practice we don't ever use BR_TABLE_I64 in wasm32 mode
44// currently.
45// Set TSFlags{0} to 1 to indicate that the variable_ops are immediates.
46// Set TSFlags{1} to 1 to indicate that the immediates represent labels.
47// FIXME: this can't inherit from I<> since there is no way to inherit from a
48// multiclass and still have the let statements.
49let isTerminator = 1, hasCtrlDep = 1, isBarrier = 1 in {
50def BR_TABLE_I32 : NI<(outs), (ins I32:$index, variable_ops),
51                      [(WebAssemblybr_table I32:$index)], 0,
52                      "br_table \t$index", 0x0e> {
53  let TSFlags{0} = 1;
54  let TSFlags{1} = 1;
55}
56def BR_TABLE_I32_S : NI<(outs), (ins I32:$index),
57                        [], 1,
58                        "br_table \t$index", 0x0e> {
59  let TSFlags{0} = 1;
60  let TSFlags{1} = 1;
61}
62def BR_TABLE_I64 : NI<(outs), (ins I64:$index, variable_ops),
63                      [(WebAssemblybr_table I64:$index)], 0,
64                      "br_table \t$index"> {
65  let TSFlags{0} = 1;
66  let TSFlags{1} = 1;
67}
68def BR_TABLE_I64_S : NI<(outs), (ins I64:$index),
69                        [], 1,
70                        "br_table \t$index"> {
71  let TSFlags{0} = 1;
72  let TSFlags{1} = 1;
73}
74} // isTerminator = 1, hasCtrlDep = 1, isBarrier = 1
75
76// This is technically a control-flow instruction, since all it affects is the
77// IP.
78defm NOP : NRI<(outs), (ins), [], "nop", 0x01>;
79
80// Placemarkers to indicate the start or end of a block or loop scope.
81// These use/clobber VALUE_STACK to prevent them from being moved into the
82// middle of an expression tree.
83let Uses = [VALUE_STACK], Defs = [VALUE_STACK] in {
84defm BLOCK     : NRI<(outs), (ins Signature:$sig), [], "block   \t$sig", 0x02>;
85defm LOOP      : NRI<(outs), (ins Signature:$sig), [], "loop    \t$sig", 0x03>;
86
87// END_BLOCK, END_LOOP, and END_FUNCTION are represented with the same opcode in
88// wasm.
89defm END_BLOCK : NRI<(outs), (ins), [], "end_block", 0x0b>;
90defm END_LOOP  : NRI<(outs), (ins), [], "end_loop", 0x0b>;
91let isTerminator = 1, isBarrier = 1 in
92defm END_FUNCTION : NRI<(outs), (ins), [], "end_function", 0x0b>;
93} // Uses = [VALUE_STACK], Defs = [VALUE_STACK]
94
95multiclass RETURN<WebAssemblyRegClass vt> {
96  defm RETURN_#vt : I<(outs), (ins vt:$val), (outs), (ins),
97                      [(WebAssemblyreturn vt:$val)],
98                      "return  \t$val", "return", 0x0f>;
99  // Equivalent to RETURN_#vt, for use at the end of a function when wasm
100  // semantics return by falling off the end of the block.
101  let isCodeGenOnly = 1 in
102  defm FALLTHROUGH_RETURN_#vt : I<(outs), (ins vt:$val), (outs), (ins), []>;
103}
104
105multiclass SIMD_RETURN<ValueType vt> {
106  defm RETURN_#vt : SIMD_I<(outs), (ins V128:$val), (outs), (ins),
107                           [(WebAssemblyreturn (vt V128:$val))],
108                           "return  \t$val", "return", 0x0f>;
109  // Equivalent to RETURN_#vt, for use at the end of a function when wasm
110  // semantics return by falling off the end of the block.
111  let isCodeGenOnly = 1 in
112  defm FALLTHROUGH_RETURN_#vt : SIMD_I<(outs), (ins V128:$val), (outs), (ins),
113                                       []>;
114}
115
116let isTerminator = 1, hasCtrlDep = 1, isBarrier = 1 in {
117
118let isReturn = 1 in {
119  defm "": RETURN<I32>;
120  defm "": RETURN<I64>;
121  defm "": RETURN<F32>;
122  defm "": RETURN<F64>;
123  defm "": RETURN<EXCEPT_REF>;
124  defm "": SIMD_RETURN<v16i8>;
125  defm "": SIMD_RETURN<v8i16>;
126  defm "": SIMD_RETURN<v4i32>;
127  defm "": SIMD_RETURN<v4f32>;
128
129  defm RETURN_VOID : NRI<(outs), (ins), [(WebAssemblyreturn)], "return", 0x0f>;
130
131  // This is to RETURN_VOID what FALLTHROUGH_RETURN_#vt is to RETURN_#vt.
132  let isCodeGenOnly = 1 in
133  defm FALLTHROUGH_RETURN_VOID : NRI<(outs), (ins), []>;
134} // isReturn = 1
135
136defm UNREACHABLE : NRI<(outs), (ins), [(trap)], "unreachable", 0x00>;
137} // isTerminator = 1, hasCtrlDep = 1, isBarrier = 1
138
139//===----------------------------------------------------------------------===//
140// Exception handling instructions
141//===----------------------------------------------------------------------===//
142
143let Predicates = [HasExceptionHandling] in {
144
145// Throwing an exception: throw / rethrow
146let isTerminator = 1, hasCtrlDep = 1, isBarrier = 1 in {
147defm THROW_I32 : I<(outs), (ins i32imm:$tag, I32:$val),
148                   (outs), (ins i32imm:$tag),
149                   [(int_wasm_throw imm:$tag, I32:$val)],
150                   "throw   \t$tag, $val", "throw   \t$tag",
151                   0x08>;
152defm THROW_I64 : I<(outs), (ins i32imm:$tag, I64:$val),
153                   (outs), (ins i32imm:$tag),
154                   [(int_wasm_throw imm:$tag, I64:$val)],
155                   "throw   \t$tag, $val", "throw   \t$tag",
156                   0x08>;
157defm RETHROW : NRI<(outs), (ins bb_op:$dst), [], "rethrow \t$dst", 0x09>;
158let isCodeGenOnly = 1 in
159// This is used when the destination for rethrow is the caller function. This
160// will be converted to a rethrow in CFGStackify.
161defm RETHROW_TO_CALLER : NRI<(outs), (ins), [], "rethrow">;
162} // isTerminator = 1, hasCtrlDep = 1, isBarrier = 1
163
164// Region within which an exception is caught: try / end_try
165let Uses = [VALUE_STACK], Defs = [VALUE_STACK] in {
166defm TRY     : NRI<(outs), (ins Signature:$sig), [], "try     \t$sig", 0x06>;
167defm END_TRY : NRI<(outs), (ins), [], "end_try", 0x0b>;
168} // Uses = [VALUE_STACK], Defs = [VALUE_STACK]
169
170// Catching an exception: catch / catch_all
171let hasCtrlDep = 1 in {
172defm CATCH_I32 : I<(outs I32:$dst), (ins i32imm:$tag),
173                   (outs), (ins i32imm:$tag),
174                   [(set I32:$dst, (int_wasm_catch imm:$tag))],
175                   "i32.catch   \t$dst, $tag", "i32.catch   \t$tag", 0x07>;
176defm CATCH_I64 : I<(outs I64:$dst), (ins i32imm:$tag),
177                   (outs), (ins i32imm:$tag),
178                   [(set I64:$dst, (int_wasm_catch imm:$tag))],
179                   "i64.catch   \t$dst, $tag", "i64.catch   \t$tag", 0x07>;
180defm CATCH_ALL : NRI<(outs), (ins), [], "catch_all", 0x05>;
181}
182
183// Pseudo instructions: cleanupret / catchret
184// They are not return instructions in wasm, but setting 'isReturn' to true as
185// in X86 is necessary for computing EH scope membership.
186let isTerminator = 1, hasSideEffects = 1, isBarrier = 1, hasCtrlDep = 1,
187    isCodeGenOnly = 1, isReturn = 1 in {
188  defm CLEANUPRET : NRI<(outs), (ins), [(cleanupret)], "", 0>;
189  defm CATCHRET : NRI<(outs), (ins bb_op:$dst, bb_op:$from),
190                   [(catchret bb:$dst, bb:$from)], "", 0>;
191}
192}
193
194} // Defs = [ARGUMENTS]
195