divsi3.S revision 309124 
1/*===-- divsi3.S - 32-bit signed integer divide ---------------------------===//
2 *
3 *                     The LLVM Compiler Infrastructure
4 *
5 * This file is dual licensed under the MIT and the University of Illinois Open
6 * Source Licenses. See LICENSE.TXT for details.
7 *
8 *===----------------------------------------------------------------------===//
9 *
10 * This file implements the __divsi3 (32-bit signed integer divide) function
11 * for the ARM architecture as a wrapper around the unsigned routine.
12 *
13 *===----------------------------------------------------------------------===*/
14
15#include "../assembly.h"
16
17#define ESTABLISH_FRAME \
18    push   {r4, r7, lr}    ;\
19    add     r7,     sp, #4
20#define CLEAR_FRAME_AND_RETURN \
21    pop    {r4, r7, pc}
22
23	.syntax unified
24	.text
25#if __ARM_ARCH_ISA_THUMB == 2
26	.thumb
27#endif
28
29	.p2align 3
30// Ok, APCS and AAPCS agree on 32 bit args, so it's safe to use the same routine.
31DEFINE_AEABI_FUNCTION_ALIAS(__aeabi_idiv, __divsi3)
32
33@ int __divsi3(int divident, int divisor)
34@   Calculate and return the quotient of the (signed) division.
35
36#if __ARM_ARCH_ISA_THUMB == 2
37DEFINE_COMPILERRT_THUMB_FUNCTION(__divsi3)
38#else
39DEFINE_COMPILERRT_FUNCTION(__divsi3)
40#endif
41#if __ARM_ARCH_EXT_IDIV__
42   tst     r1,r1
43   beq     LOCAL_LABEL(divzero)
44   sdiv    r0, r0, r1
45   bx      lr
46LOCAL_LABEL(divzero):
47   mov     r0,#0
48   bx      lr
49#else
50ESTABLISH_FRAME
51//  Set aside the sign of the quotient.
52    eor     r4,     r0, r1
53//  Take absolute value of a and b via abs(x) = (x^(x >> 31)) - (x >> 31).
54    eor     r2,     r0, r0, asr #31
55    eor     r3,     r1, r1, asr #31
56    sub     r0,     r2, r0, asr #31
57    sub     r1,     r3, r1, asr #31
58//  abs(a) / abs(b)
59    bl      SYMBOL_NAME(__udivsi3)
60//  Apply sign of quotient to result and return.
61    eor     r0,     r0, r4, asr #31
62    sub     r0,     r0, r4, asr #31
63    CLEAR_FRAME_AND_RETURN
64#endif
65END_COMPILERRT_FUNCTION(__divsi3)
66
67NO_EXEC_STACK_DIRECTIVE
68
69