rtld_start.S revision 38816 
1/*-
2 * Copyright 1996-1998 John D. Polstra.
3 * All rights reserved.
4 *
5 * Redistribution and use in source and binary forms, with or without
6 * modification, are permitted provided that the following conditions
7 * are met:
8 * 1. Redistributions of source code must retain the above copyright
9 *    notice, this list of conditions and the following disclaimer.
10 * 2. Redistributions in binary form must reproduce the above copyright
11 *    notice, this list of conditions and the following disclaimer in the
12 *    documentation and/or other materials provided with the distribution.
13 *
14 * THIS SOFTWARE IS PROVIDED BY THE AUTHOR ``AS IS'' AND ANY EXPRESS OR
15 * IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED WARRANTIES
16 * OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE DISCLAIMED.
17 * IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR ANY DIRECT, INDIRECT,
18 * INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT
19 * NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
20 * DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
21 * THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
22 * (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF
23 * THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
24 *
25 *      $Id: rtld_start.S,v 1.1.1.1 1998/03/07 19:24:35 jdp Exp $
26 */
27
28	.text
29	.align	4
30	.globl	.rtld_start
31	.type	.rtld_start,@function
32.rtld_start:
33	xorl	%ebp,%ebp		# Clear frame pointer for good form
34	movl	%esp,%eax		# Save initial stack pointer
35	subl	$8,%esp			# A place to store exit procedure addr
36	movl	%esp,%ebx		# save address of exit proc
37	movl	%esp,%ecx		# construct address of obj_main
38	addl	$4,%ecx
39	pushl	%ecx			# Pass address of obj_main
40	pushl	%ebx			# Pass address of exit proc
41	pushl	%eax			# Pass initial stack pointer to rtld
42	call	_rtld@PLT		# Call rtld(sp); returns entry point
43	addl	$12,%esp		# Remove arguments from stack
44	popl	%edx			# Get exit procedure address
45	addl	$4,%esp			# Ignore obj_main
46/*
47 * At this point, %eax contains the entry point of the main program, and
48 * %edx contains a pointer to a termination function that should be
49 * registered with atexit().  (crt1.o registers it.)
50 */
51.globl .rtld_goto_main
52.rtld_goto_main:	# This symbol exists just to make debugging easier.
53	jmp	*%eax			# Enter main program
54
55
56/*
57 * Binder entry point.  Control is transferred to here by code in the PLT.
58 * On entry, there are two arguments on the stack.  In ascending address
59 * order, they are (1) "obj", a pointer to the calling object's Obj_Entry,
60 * and (2) "reloff", the byte offset of the appropriate relocation entry
61 * in the PLT relocation table.
62 *
63 * We are careful to preserve all registers, even the the caller-save
64 * registers.  That is because this code may be invoked by low-level
65 * assembly-language code that is not ABI-compliant.
66 */
67	.align	4
68	.globl	_rtld_bind_start
69	.type	_rtld_bind_start,@function
70_rtld_bind_start:
71	pushf				# Save eflags
72	pushl	%eax			# Save %eax
73	pushl	%edx			# Save %edx
74	pushl	%ecx			# Save %ecx
75	pushl	20(%esp)		# Copy reloff argument
76	pushl	20(%esp)		# Copy obj argument
77
78	call	_rtld_bind@PLT		# Transfer control to the binder
79	/* Now %eax contains the entry point of the function being called. */
80
81	addl	$8,%esp			# Discard binder arguments
82	movl	%eax,20(%esp)		# Store target over obj argument
83	popl	%ecx			# Restore %ecx
84	popl	%edx			# Restore %edx
85	popl	%eax			# Restore %eax
86	popf				# Restore eflags
87	leal	4(%esp),%esp		# Discard reloff, do not change eflags
88	ret				# "Return" to target address
89