swab.S revision 5780 
1/*
2 * Copyright (c) 1993,94 Winning Strategies, Inc.
3 * All rights reserved.
4 *
5 * Redistribution and use in source and binary forms, with or without
6 * modification, are permitted provided that the following conditions
7 * are met:
8 * 1. Redistributions of source code must retain the above copyright
9 *    notice, this list of conditions and the following disclaimer.
10 * 2. Redistributions in binary form must reproduce the above copyright
11 *    notice, this list of conditions and the following disclaimer in the
12 *    documentation and/or other materials provided with the distribution.
13 * 3. All advertising materials mentioning features or use of this software
14 *    must display the following acknowledgement:
15 *      This product includes software developed by Winning Strategies, Inc.
16 * 4. The name of the author may not be used to endorse or promote products
17 *    derived from this software without specific prior written permission
18 *
19 * THIS SOFTWARE IS PROVIDED BY THE AUTHOR ``AS IS'' AND ANY EXPRESS OR
20 * IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED WARRANTIES
21 * OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE DISCLAIMED.
22 * IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR ANY DIRECT, INDIRECT,
23 * INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT
24 * NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
25 * DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
26 * THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
27 * (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF
28 * THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
29 *
30 *	$Id: swab.S,v 1.7 1994/03/12 01:40:09 jtc Exp $
31 */
32
33#if defined(LIBC_SCCS)
34	.asciz "$Id$"
35#endif
36
37#include "DEFS.h"
38
39/*
40 * void
41 * swab (const void *src, void *dst, size_t len)
42 *	copy len bytes from src to dst, swapping adjacent bytes
43 *
44 * On the i486, this code is negligibly faster than the code generated
45 * by gcc at about half the size.  If my i386 databook is correct, it
46 * should be considerably faster than the gcc code on a i386.
47 *
48 * Written by:
49 *	J.T. Conklin (jtc@wimsey.com), Winning Strategies, Inc.
50 */
51
52ENTRY(swab)
53	pushl	%esi
54	pushl	%edi
55	movl	12(%esp),%esi
56	movl	16(%esp),%edi
57	movl	20(%esp),%ecx
58
59	cld				# set direction forward
60
61	shrl	$1,%ecx
62	testl	$7,%ecx			# copy first group of 1 to 7 words
63	jz	L2			# while swaping alternate bytes.
64	.align	2,0x90
65L1:	lodsw
66	rorw	$8,%ax
67	stosw
68	decl	%ecx
69	testl	$7,%ecx
70	jnz	L1
71
72L2:	shrl	$3,%ecx			# copy remainder 8 words at a time
73	jz	L4			# while swapping alternate bytes.
74	.align	2,0x90
75L3:	lodsw
76	rorw	$8,%ax
77	stosw
78	lodsw
79	rorw	$8,%ax
80	stosw
81	lodsw
82	rorw	$8,%ax
83	stosw
84	lodsw
85	rorw	$8,%ax
86	stosw
87	lodsw
88	rorw	$8,%ax
89	stosw
90	lodsw
91	rorw	$8,%ax
92	stosw
93	lodsw
94	rorw	$8,%ax
95	stosw
96	lodsw
97	rorw	$8,%ax
98	stosw
99	decl	%ecx
100	jnz	L3
101
102L4:	popl	%edi
103	popl	%esi
104	ret
105