bzero.S revision 81586 
1/*
2 * Copyright (c) 1993 Winning Strategies, Inc.
3 * All rights reserved.
4 *
5 * Redistribution and use in source and binary forms, with or without
6 * modification, are permitted provided that the following conditions
7 * are met:
8 * 1. Redistributions of source code must retain the above copyright
9 *    notice, this list of conditions and the following disclaimer.
10 * 2. Redistributions in binary form must reproduce the above copyright
11 *    notice, this list of conditions and the following disclaimer in the
12 *    documentation and/or other materials provided with the distribution.
13 * 3. All advertising materials mentioning features or use of this software
14 *    must display the following acknowledgement:
15 *      This product includes software developed by Winning Strategies, Inc.
16 * 4. The name of the author may not be used to endorse or promote products
17 *    derived from this software withough specific prior written permission
18 *
19 * THIS SOFTWARE IS PROVIDED BY THE AUTHOR ``AS IS'' AND ANY EXPRESS OR
20 * IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED WARRANTIES
21 * OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE DISCLAIMED.
22 * IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR ANY DIRECT, INDIRECT,
23 * INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT
24 * NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
25 * DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
26 * THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
27 * (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF
28 * THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
29 */
30
31#if defined(LIBC_RCS) && !defined(lint)
32	.text
33        .asciz "$FreeBSD: head/lib/libc/i386/string/bzero.S 81586 2001-08-13 14:06:34Z ru $"
34#endif /* LIBC_RCS and not lint */
35
36#include "DEFS.h"
37
38/*
39 * bzero (void *b, size_t len)
40 *	write len zero bytes to the string b.
41 *
42 * Written by:
43 *	J.T. Conklin (jtc@wimsey.com), Winning Strategies, Inc.
44 */
45
46ENTRY(bzero)
47	pushl	%edi
48	pushl	%ebx
49	movl	12(%esp),%edi
50	movl	16(%esp),%ecx
51
52	cld				/* set fill direction forward */
53	xorl	%eax,%eax		/* set fill data to 0 */
54
55	/*
56	 * if the string is too short, it's really not worth the overhead
57	 * of aligning to word boundries, etc.  So we jump to a plain
58	 * unaligned set.
59	 */
60	cmpl	$0x0f,%ecx
61	jle	L1
62
63	movl	%edi,%edx		/* compute misalignment */
64	negl	%edx
65	andl	$3,%edx
66	movl	%ecx,%ebx
67	subl	%edx,%ebx
68
69	movl	%edx,%ecx		/* zero until word aligned */
70	rep
71	stosb
72
73	movl	%ebx,%ecx		/* zero by words */
74	shrl	$2,%ecx
75	rep
76	stosl
77
78	movl	%ebx,%ecx
79	andl	$3,%ecx			/* zero remainder by bytes */
80L1:	rep
81	stosb
82
83	popl	%ebx
84	popl	%edi
85	ret
86