setjmp.S revision 287872 
1/*-
2 * Copyright (c) 1990 The Regents of the University of California.
3 * All rights reserved.
4 *
5 * This code is derived from software contributed to Berkeley by
6 * William Jolitz.
7 *
8 * Redistribution and use in source and binary forms, with or without
9 * modification, are permitted provided that the following conditions
10 * are met:
11 * 1. Redistributions of source code must retain the above copyright
12 *    notice, this list of conditions and the following disclaimer.
13 * 2. Redistributions in binary form must reproduce the above copyright
14 *    notice, this list of conditions and the following disclaimer in the
15 *    documentation and/or other materials provided with the distribution.
16 * 4. Neither the name of the University nor the names of its contributors
17 *    may be used to endorse or promote products derived from this software
18 *    without specific prior written permission.
19 *
20 * THIS SOFTWARE IS PROVIDED BY THE REGENTS AND CONTRIBUTORS ``AS IS'' AND
21 * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
22 * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
23 * ARE DISCLAIMED.  IN NO EVENT SHALL THE REGENTS OR CONTRIBUTORS BE LIABLE
24 * FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
25 * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
26 * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
27 * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
28 * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
29 * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
30 * SUCH DAMAGE.
31 */
32
33#if defined(LIBC_SCCS) && !defined(lint)
34	.asciz "@(#)setjmp.s	5.1 (Berkeley) 4/23/90"
35#endif /* LIBC_SCCS and not lint */
36#include <machine/asm.h>
37__FBSDID("$FreeBSD: releng/10.2/lib/libc/i386/gen/setjmp.S 287872 2015-09-16 20:59:41Z delphij $");
38
39/*
40 * C library -- _setjmp, _longjmp
41 *
42 *	longjmp(a,v)
43 * will generate a "return(v)" from the last call to
44 *	setjmp(a)
45 * by restoring registers from the environment 'a'.
46 * The previous signal state is restored.
47 */
48
49#include "SYS.h"
50
51ENTRY(setjmp)
52	movl	4(%esp),%ecx
53	leal	28(%ecx), %eax
54	pushl	%eax			/* (sigset_t*)oset */
55	pushl	$0			/* (sigset_t*)set  */
56	pushl	$1			/* SIG_BLOCK       */
57	call	__libc_sigprocmask
58	addl	$12,%esp
59	movl	4(%esp),%ecx
60	movl	0(%esp),%edx
61	movl	%edx, 0(%ecx)
62	movl	%ebx, 4(%ecx)
63	movl	%esp, 8(%ecx)
64	movl	%ebp,12(%ecx)
65	movl	%esi,16(%ecx)
66	movl	%edi,20(%ecx)
67	fnstcw	24(%ecx)
68	xorl	%eax,%eax
69	ret
70END(setjmp)
71
72	.weak CNAME(longjmp)
73	.set CNAME(longjmp),CNAME(__longjmp)
74ENTRY(__longjmp)
75	movl	4(%esp),%edx
76	pushl	$0			/* (sigset_t*)oset */
77	leal	28(%edx), %eax
78	pushl	%eax			/* (sigset_t*)set  */
79	pushl	$3			/* SIG_SETMASK     */
80	call	__libc_sigprocmask
81	addl	$12,%esp
82	movl	4(%esp),%edx
83	movl	8(%esp),%eax
84	movl	0(%edx),%ecx
85	movl	4(%edx),%ebx
86	movl	8(%edx),%esp
87	movl	12(%edx),%ebp
88	movl	16(%edx),%esi
89	movl	20(%edx),%edi
90	fldcw	24(%edx)
91	testl	%eax,%eax
92	jnz	1f
93	incl	%eax
941:	movl	%ecx,0(%esp)
95	ret
96END(__longjmp)
97
98	.section .note.GNU-stack,"",%progbits
99