sigsetjmp.S revision 55837 
1/*-
2 * Copyright (c) 1990 The Regents of the University of California.
3 * All rights reserved.
4 *
5 * This code is derived from software contributed to Berkeley by
6 * William Jolitz.
7 *
8 * Redistribution and use in source and binary forms, with or without
9 * modification, are permitted provided that the following conditions
10 * are met:
11 * 1. Redistributions of source code must retain the above copyright
12 *    notice, this list of conditions and the following disclaimer.
13 * 2. Redistributions in binary form must reproduce the above copyright
14 *    notice, this list of conditions and the following disclaimer in the
15 *    documentation and/or other materials provided with the distribution.
16 * 3. All advertising materials mentioning features or use of this software
17 *    must display the following acknowledgement:
18 *	This product includes software developed by the University of
19 *	California, Berkeley and its contributors.
20 * 4. Neither the name of the University nor the names of its contributors
21 *    may be used to endorse or promote products derived from this software
22 *    without specific prior written permission.
23 *
24 * THIS SOFTWARE IS PROVIDED BY THE REGENTS AND CONTRIBUTORS ``AS IS'' AND
25 * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
26 * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
27 * ARE DISCLAIMED.  IN NO EVENT SHALL THE REGENTS OR CONTRIBUTORS BE LIABLE
28 * FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
29 * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
30 * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
31 * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
32 * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
33 * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
34 * SUCH DAMAGE.
35 *
36 * $FreeBSD: head/lib/libc/amd64/gen/sigsetjmp.S 55837 2000-01-12 09:23:48Z jasone $
37 */
38
39#if defined(LIBC_RCS) && !defined(lint)
40	.text
41	.asciz "$FreeBSD: head/lib/libc/amd64/gen/sigsetjmp.S 55837 2000-01-12 09:23:48Z jasone $"
42#endif /* LIBC_RCS and not lint */
43
44#include "DEFS.h"
45#include "SYS.h"
46
47/*-
48 * TODO:
49 *	Rename sigsetjmp to __sigsetjmp and siglongjmp to __siglongjmp,
50 *	remove the other *jmp functions and define everything in terms
51 *	of the renamed functions.  This requires compiler support for
52 *	the renamed functions (introduced in gcc-2.5.3; previous versions
53 *	only supported *jmp with 0 or 1 leading underscores).
54 *
55 *	Use sigprocmask() instead of sigblock() and sigsetmask(), and
56 *	check for and handle errors.
57 *
58 *	Restore _all_ the registers and the signal mask atomically.  Can
59 *	use sigreturn() if sigreturn() works.
60 */
61
62ALTENTRY(sigsetjmp)
63ALTENTRY(_libc_sigsetjmp)
64ENTRY(__sigsetjmp)
65	movl	8(%esp),%eax
66	movl	4(%esp),%ecx
67	movl	%eax,44(%ecx)
68	testl	%eax,%eax
69	jz	2f
70	PIC_PROLOGUE
71	leal	28(%ecx), %eax
72	pushl	%eax			/* (sigset_t*)oset */
73	pushl	$0			/* (sigset_t*)set  */
74	pushl	$1			/* SIG_BLOCK       */
75#ifdef _THREAD_SAFE
76	call	PIC_PLT(CNAME(_thread_sys_sigprocmask))
77#else
78	call	PIC_PLT(CNAME(sigprocmask))
79#endif
80	addl	$12,%esp
81	PIC_EPILOGUE
82	movl	4(%esp),%ecx
832:	movl	0(%esp),%edx
84	movl	%edx, 0(%ecx)
85	movl	%ebx, 4(%ecx)
86	movl	%esp, 8(%ecx)
87	movl	%ebp,12(%ecx)
88	movl	%esi,16(%ecx)
89	movl	%edi,20(%ecx)
90	fnstcw	24(%ecx)
91	xorl	%eax,%eax
92	ret
93
94ALTENTRY(siglongjmp)
95ALTENTRY(_libc_siglongjmp)
96ENTRY(__siglongjmp)
97	movl	4(%esp),%edx
98	cmpl	$0,44(%edx)
99	jz	2f
100	PIC_PROLOGUE
101	pushl	$0			/* (sigset_t*)oset */
102	leal	28(%edx), %eax
103	pushl	%eax			/* (sigset_t*)set  */
104	pushl	$3			/* SIG_SETMASK     */
105#ifdef _THREAD_SAFE
106	call	PIC_PLT(CNAME(_thread_sys_sigprocmask))
107#else
108	call	PIC_PLT(CNAME(sigprocmask))
109#endif
110	addl	$12,%esp
111	PIC_EPILOGUE
112	movl	4(%esp),%edx
1132:	movl	8(%esp),%eax
114	movl	0(%edx),%ecx
115	movl	4(%edx),%ebx
116	movl	8(%edx),%esp
117	movl	12(%edx),%ebp
118	movl	16(%edx),%esi
119	movl	20(%edx),%edi
120	fninit
121	fldcw	24(%edx)
122	testl	%eax,%eax
123	jnz	1f
124	incl	%eax
1251:	movl	%ecx,0(%esp)
126	ret
127