setjmp.S revision 287872 
1/*-
2 * Copyright (c) 1990 The Regents of the University of California.
3 * All rights reserved.
4 *
5 * This code is derived from software contributed to Berkeley by
6 * William Jolitz.
7 *
8 * Redistribution and use in source and binary forms, with or without
9 * modification, are permitted provided that the following conditions
10 * are met:
11 * 1. Redistributions of source code must retain the above copyright
12 *    notice, this list of conditions and the following disclaimer.
13 * 2. Redistributions in binary form must reproduce the above copyright
14 *    notice, this list of conditions and the following disclaimer in the
15 *    documentation and/or other materials provided with the distribution.
16 * 4. Neither the name of the University nor the names of its contributors
17 *    may be used to endorse or promote products derived from this software
18 *    without specific prior written permission.
19 *
20 * THIS SOFTWARE IS PROVIDED BY THE REGENTS AND CONTRIBUTORS ``AS IS'' AND
21 * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
22 * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
23 * ARE DISCLAIMED.  IN NO EVENT SHALL THE REGENTS OR CONTRIBUTORS BE LIABLE
24 * FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
25 * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
26 * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
27 * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
28 * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
29 * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
30 * SUCH DAMAGE.
31 */
32
33#if defined(LIBC_SCCS) && !defined(lint)
34	.asciz "@(#)setjmp.s	5.1 (Berkeley) 4/23/90"
35#endif /* LIBC_SCCS and not lint */
36#include <machine/asm.h>
37__FBSDID("$FreeBSD: releng/10.2/lib/libc/amd64/gen/setjmp.S 287872 2015-09-16 20:59:41Z delphij $");
38
39/*
40 * C library -- _setjmp, _longjmp
41 *
42 *	longjmp(a,v)
43 * will generate a "return(v)" from the last call to
44 *	setjmp(a)
45 * by restoring registers from the environment 'a'.
46 * The previous signal state is restored.
47 */
48
49#include "SYS.h"
50
51ENTRY(setjmp)
52	pushq	%rdi
53	movq	%rdi,%rcx
54	movq	$1,%rdi			/* SIG_BLOCK       */
55	movq	$0,%rsi			/* (sigset_t*)set  */
56	leaq	72(%rcx),%rdx		/* 9,10; (sigset_t*)oset */
57	/* stack is 16-byte aligned */
58	call	__libc_sigprocmask
59	popq	%rdi
60	movq	%rdi,%rcx
61	movq	0(%rsp),%rdx		/* retval */
62	movq	%rdx, 0(%rcx)		/* 0; retval */
63	movq	%rbx, 8(%rcx)		/* 1; rbx */
64	movq	%rsp,16(%rcx)		/* 2; rsp */
65	movq	%rbp,24(%rcx)		/* 3; rbp */
66	movq	%r12,32(%rcx)		/* 4; r12 */
67	movq	%r13,40(%rcx)		/* 5; r13 */
68	movq	%r14,48(%rcx)		/* 6; r14 */
69	movq	%r15,56(%rcx)		/* 7; r15 */
70	fnstcw	64(%rcx)		/* 8; fpu cw */
71	stmxcsr	68(%rcx)		/*    and mxcsr */
72	xorq	%rax,%rax
73	ret
74END(setjmp)
75
76	.weak CNAME(longjmp)
77	.set CNAME(longjmp),CNAME(__longjmp)
78ENTRY(__longjmp)
79	pushq	%rdi
80	pushq	%rsi
81	movq	%rdi,%rdx
82	movq	$3,%rdi			/* SIG_SETMASK     */
83	leaq	72(%rdx),%rsi		/* (sigset_t*)set  */
84	movq	$0,%rdx			/* (sigset_t*)oset */
85	subq	$0x8,%rsp		/* make the stack 16-byte aligned */
86	call	__libc_sigprocmask
87	addq	$0x8,%rsp
88	popq	%rsi
89	popq	%rdi			/* jmpbuf */
90	movq	%rdi,%rdx
91	/* Restore the mxcsr, but leave exception flags intact. */
92	stmxcsr	-4(%rsp)
93	movl	68(%rdx),%eax
94	andl	$0xffffffc0,%eax
95	movl	-4(%rsp),%edi
96	andl	$0x3f,%edi
97	xorl	%eax,%edi
98	movl	%edi,-4(%rsp)
99	ldmxcsr -4(%rsp)
100	movq	%rsi,%rax		/* retval */
101	movq	0(%rdx),%rcx
102	movq	8(%rdx),%rbx
103	movq	16(%rdx),%rsp
104	movq	24(%rdx),%rbp
105	movq	32(%rdx),%r12
106	movq	40(%rdx),%r13
107	movq	48(%rdx),%r14
108	movq	56(%rdx),%r15
109	fldcw	64(%rdx)
110	testq	%rax,%rax
111	jnz	1f
112	incq	%rax
1131:	movq	%rcx,0(%rsp)
114	ret
115END(__longjmp)
116
117	.section .note.GNU-stack,"",%progbits
118