dtparser.y revision 220658 
1%{
2/******************************************************************************
3 *
4 * Module Name: dtparser.y - Bison input file for table compiler parser
5 *
6 *****************************************************************************/
7
8/*
9 * Copyright (C) 2000 - 2011, Intel Corp.
10 * All rights reserved.
11 *
12 * Redistribution and use in source and binary forms, with or without
13 * modification, are permitted provided that the following conditions
14 * are met:
15 * 1. Redistributions of source code must retain the above copyright
16 *    notice, this list of conditions, and the following disclaimer,
17 *    without modification.
18 * 2. Redistributions in binary form must reproduce at minimum a disclaimer
19 *    substantially similar to the "NO WARRANTY" disclaimer below
20 *    ("Disclaimer") and any redistribution must be conditioned upon
21 *    including a substantially similar Disclaimer requirement for further
22 *    binary redistribution.
23 * 3. Neither the names of the above-listed copyright holders nor the names
24 *    of any contributors may be used to endorse or promote products derived
25 *    from this software without specific prior written permission.
26 *
27 * Alternatively, this software may be distributed under the terms of the
28 * GNU General Public License ("GPL") version 2 as published by the Free
29 * Software Foundation.
30 *
31 * NO WARRANTY
32 * THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
33 * "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
34 * LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTIBILITY AND FITNESS FOR
35 * A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT
36 * HOLDERS OR CONTRIBUTORS BE LIABLE FOR SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
37 * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
38 * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
39 * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT,
40 * STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING
41 * IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE
42 * POSSIBILITY OF SUCH DAMAGES.
43 */
44
45#define YYDEBUG 1
46#define YYERROR_VERBOSE 1
47
48#include "aslcompiler.h"
49#include "dtcompiler.h"
50
51#define _COMPONENT          ACPI_COMPILER
52        ACPI_MODULE_NAME    ("dtparser")
53
54UINT64                  DtParserResult;    /* Global for expression return value */
55
56int DtParserlex (void);
57int DtParserparse (void);
58extern char*            DtParsertext;
59extern void             DtParsererror (char const * msg);
60#define YYFLAG          -32768
61
62%}
63
64%union
65{
66     UINT64                 value;
67     UINT32                 op;
68}
69
70%type  <value>  Expression
71
72%token <op>     EXPOP_EOF
73%token <op>     EXPOP_NEW_LINE
74%token <op>     EXPOP_NUMBER
75%token <op>     EXPOP_HEX_NUMBER
76%token <op>     EXPOP_DECIMAL_NUMBER
77%token <op>     EXPOP_LABEL
78%token <op>     EXPOP_PAREN_OPEN
79%token <op>     EXPOP_PAREN_CLOSE
80
81%left <op>      EXPOP_LOGICAL_OR
82%left <op>      EXPOP_LOGICAL_AND
83%left <op>      EXPOP_OR
84%left <op>      EXPOP_XOR
85%left <op>      EXPOP_AND
86%left <op>      EXPOP_EQUAL EXPOP_NOT_EQUAL
87%left <op>      EXPOP_GREATER EXPOP_LESS EXPOP_GREATER_EQUAL EXPOP_LESS_EQUAL
88%left <op>      EXPOP_SHIFT_RIGHT EXPOP_SHIFT_LEFT
89%left <op>      EXPOP_ADD EXPOP_SUBTRACT
90%left <op>      EXPOP_MULTIPLY EXPOP_DIVIDE EXPOP_MODULO
91%right <op>     EXPOP_ONES_COMPLIMENT EXPOP_LOGICAL_NOT
92
93%%
94
95/*
96 *  Operator precedence rules (from K&R)
97 *
98 *  1)      ( )
99 *  2)      ! ~ (unary operators that are supported here)
100 *  3)      *   /   %
101 *  4)      +   -
102 *  5)      >>  <<
103 *  6)      <   >   <=  >=
104 *  7)      ==  !=
105 *  8)      &
106 *  9)      ^
107 *  10)     |
108 *  11)     &&
109 *  12)     ||
110 */
111Value
112    : Expression EXPOP_NEW_LINE                     { DtParserResult=$1; return 0; } /* End of line (newline) */
113    | Expression EXPOP_EOF                          { DtParserResult=$1; return 0; } /* End of string (0) */
114    ;
115
116Expression
117
118      /* Unary operators */
119
120    : EXPOP_LOGICAL_NOT         Expression          { $$ = DtDoOperator ($2, EXPOP_LOGICAL_NOT,     $2);}
121    | EXPOP_ONES_COMPLIMENT     Expression          { $$ = DtDoOperator ($2, EXPOP_ONES_COMPLIMENT, $2);}
122
123      /* Binary operators */
124
125    | Expression EXPOP_MULTIPLY         Expression  { $$ = DtDoOperator ($1, EXPOP_MULTIPLY,        $3);}
126    | Expression EXPOP_DIVIDE           Expression  { $$ = DtDoOperator ($1, EXPOP_DIVIDE,          $3);}
127    | Expression EXPOP_MODULO           Expression  { $$ = DtDoOperator ($1, EXPOP_MODULO,          $3);}
128    | Expression EXPOP_ADD              Expression  { $$ = DtDoOperator ($1, EXPOP_ADD,             $3);}
129    | Expression EXPOP_SUBTRACT         Expression  { $$ = DtDoOperator ($1, EXPOP_SUBTRACT,        $3);}
130    | Expression EXPOP_SHIFT_RIGHT      Expression  { $$ = DtDoOperator ($1, EXPOP_SHIFT_RIGHT,     $3);}
131    | Expression EXPOP_SHIFT_LEFT       Expression  { $$ = DtDoOperator ($1, EXPOP_SHIFT_LEFT,      $3);}
132    | Expression EXPOP_GREATER          Expression  { $$ = DtDoOperator ($1, EXPOP_GREATER,         $3);}
133    | Expression EXPOP_LESS             Expression  { $$ = DtDoOperator ($1, EXPOP_LESS,            $3);}
134    | Expression EXPOP_GREATER_EQUAL    Expression  { $$ = DtDoOperator ($1, EXPOP_GREATER_EQUAL,   $3);}
135    | Expression EXPOP_LESS_EQUAL       Expression  { $$ = DtDoOperator ($1, EXPOP_LESS_EQUAL,      $3);}
136    | Expression EXPOP_EQUAL            Expression  { $$ = DtDoOperator ($1, EXPOP_EQUAL,           $3);}
137    | Expression EXPOP_NOT_EQUAL        Expression  { $$ = DtDoOperator ($1, EXPOP_NOT_EQUAL,       $3);}
138    | Expression EXPOP_AND              Expression  { $$ = DtDoOperator ($1, EXPOP_AND,             $3);}
139    | Expression EXPOP_XOR              Expression  { $$ = DtDoOperator ($1, EXPOP_XOR,             $3);}
140    | Expression EXPOP_OR               Expression  { $$ = DtDoOperator ($1, EXPOP_OR,              $3);}
141    | Expression EXPOP_LOGICAL_AND      Expression  { $$ = DtDoOperator ($1, EXPOP_LOGICAL_AND,     $3);}
142    | Expression EXPOP_LOGICAL_OR       Expression  { $$ = DtDoOperator ($1, EXPOP_LOGICAL_OR,      $3);}
143
144      /* Parentheses: '(' Expression ')' */
145
146    | EXPOP_PAREN_OPEN          Expression
147        EXPOP_PAREN_CLOSE                           { $$ = $2;}
148
149      /* Label references (prefixed with $) */
150
151    | EXPOP_LABEL                                   { $$ = DtResolveLabel (DtParsertext);}
152
153      /* Default base for a non-prefixed integer is 16 */
154
155    | EXPOP_NUMBER                                  { UtStrtoul64 (DtParsertext, 16, &$$);}
156
157      /* Standard hex number (0x1234) */
158
159    | EXPOP_HEX_NUMBER                              { UtStrtoul64 (DtParsertext, 16, &$$);}
160
161      /* TBD: Decimal number with prefix (0d1234) - Not supported by UtStrtoul64 at this time */
162
163    | EXPOP_DECIMAL_NUMBER                          { UtStrtoul64 (DtParsertext, 10, &$$);}
164    ;
165%%
166
167/*
168 * Local support functions, including parser entry point
169 */
170extern DT_FIELD                 *Gbl_CurrentField;
171#define PR_FIRST_PARSE_OPCODE   EXPOP_EOF
172#define PR_YYTNAME_START        3
173
174#ifdef _USE_BERKELEY_YACC
175#define yytname DtParsername
176#endif
177
178
179/******************************************************************************
180 *
181 * FUNCTION:    DtParsererror
182 *
183 * PARAMETERS:  Message             - Parser-generated error message
184 *
185 * RETURN:      None
186 *
187 * DESCRIPTION: Handler for parser errors
188 *
189 *****************************************************************************/
190
191void
192DtParsererror (
193    char const              *Message)
194{
195    DtError (ASL_ERROR, ASL_MSG_SYNTAX,
196        Gbl_CurrentField, (char *) Message);
197}
198
199
200/******************************************************************************
201 *
202 * FUNCTION:    DtGetOpName
203 *
204 * PARAMETERS:  ParseOpcode         - Parser token (EXPOP_*)
205 *
206 * RETURN:      Pointer to the opcode name
207 *
208 * DESCRIPTION: Get the ascii name of the parse opcode for debug output
209 *
210 *****************************************************************************/
211
212char *
213DtGetOpName (
214    UINT32                  ParseOpcode)
215{
216
217    /*
218     * First entries (PR_YYTNAME_START) in yytname are special reserved names.
219     * Ignore first 6 characters of name (EXPOP_)
220     */
221    return ((char *) yytname
222        [(ParseOpcode - PR_FIRST_PARSE_OPCODE) + PR_YYTNAME_START] + 6);
223}
224
225
226/******************************************************************************
227 *
228 * FUNCTION:    DtEvaluateExpression
229 *
230 * PARAMETERS:  ExprString          - Expression to be evaluated. Must be
231 *                                    terminated by either a newline or a NUL
232 *                                    string terminator
233 *
234 * RETURN:      64-bit value for the expression
235 *
236 * DESCRIPTION: Main entry point for the DT expression parser
237 *
238 *****************************************************************************/
239
240UINT64
241DtEvaluateExpression (
242    char                    *ExprString)
243{
244
245    DbgPrint (ASL_DEBUG_OUTPUT,
246        "**** Input expression: %s  (Base 16)\n", ExprString);
247
248    /* Point lexer to the input string */
249
250    if (DtInitLexer (ExprString))
251    {
252        DtError (ASL_ERROR, ASL_MSG_COMPILER_INTERNAL,
253            Gbl_CurrentField, "Could not initialize lexer");
254        return (0);
255    }
256
257    /* Parse/Evaluate the input string (value returned in DtParserResult) */
258
259    DtParserparse ();
260    DtTerminateLexer ();
261
262    DbgPrint (ASL_DEBUG_OUTPUT,
263        "**** Parser returned value: %u (%8.8X%8.8X)\n",
264        (UINT32) DtParserResult, ACPI_FORMAT_UINT64 (DtParserResult));
265
266    return (DtParserResult);
267}
268