memmove.S revision 1849 
1/*-
2 * Copyright (c) 1990 The Regents of the University of California.
3 * All rights reserved.
4 *
5 * This code is derived from software contributed to Berkeley by
6 *
7 * Redistribution and use in source and binary forms, with or without
8 * modification, are permitted provided that the following conditions
9 * are met:
10 * 1. Redistributions of source code must retain the above copyright
11 *    notice, this list of conditions and the following disclaimer.
12 * 2. Redistributions in binary form must reproduce the above copyright
13 *    notice, this list of conditions and the following disclaimer in the
14 *    documentation and/or other materials provided with the distribution.
15 * 3. All advertising materials mentioning features or use of this software
16 *    must display the following acknowledgement:
17 *	This product includes software developed by the University of
18 *	California, Berkeley and its contributors.
19 * 4. Neither the name of the University nor the names of its contributors
20 *    may be used to endorse or promote products derived from this software
21 *    without specific prior written permission.
22 *
23 * THIS SOFTWARE IS PROVIDED BY THE REGENTS AND CONTRIBUTORS ``AS IS'' AND
24 * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
25 * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
26 * ARE DISCLAIMED.  IN NO EVENT SHALL THE REGENTS OR CONTRIBUTORS BE LIABLE
27 * FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
28 * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
29 * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
30 * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
31 * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
32 * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
33 * SUCH DAMAGE.
34 *
35 *	$Id: memmove.S,v 1.2 1994/03/31 14:11:00 davidg Exp $
36 */
37
38#if defined(LIBC_RCS) && !defined(lint)
39        .asciz "$Id: memmove.S,v 1.2 1994/03/31 14:11:00 davidg Exp $"
40#endif /* LIBC_RCS and not lint */
41
42#include "DEFS.h"
43
44	/*
45	 * (ov)bcopy (src,dst,cnt)
46	 *  ws@tools.de     (Wolfgang Solfrank, TooLs GmbH) +49-228-985800
47	 */
48
49ALTENTRY(memcpy)
50ENTRY(memmove)
51	pushl	%esi
52	pushl	%edi
53	movl	12(%esp),%edi
54	movl	16(%esp),%esi
55	movl	20(%esp),%ecx
56	cmpl	%esi,%edi	/* potentially overlapping? */
57	jnb	1f
58	cld			/* nope, copy forwards. */
59	shrl	$2,%ecx		/* copy by words */
60	rep
61	movsl
62	movl	20(%esp),%ecx
63	andl	$3,%ecx		/* any bytes left? */
64	rep
65	movsb
66	movl	12(%esp),%eax
67	popl	%edi
68	popl	%esi
69	ret
701:
71	addl	%ecx,%edi	/* copy backwards. */
72	addl	%ecx,%esi
73	std
74	andl	$3,%ecx		/* any fractional bytes? */
75	decl	%edi
76	decl	%esi
77	rep
78	movsb
79	movl	20(%esp),%ecx	/* copy remainder by words */
80	shrl	$2,%ecx
81	subl	$3,%esi
82	subl	$3,%edi
83	rep
84	movsl
85	movl	12(%esp),%eax
86	popl	%edi
87	popl	%esi
88	cld
89	ret
90