1/*-
2 * Copyright (c) 2005 Olivier Houchard
3 * All rights reserved.
4 *
5 * Redistribution and use in source and binary forms, with or without
6 * modification, are permitted provided that the following conditions
7 * are met:
8 * 1. Redistributions of source code must retain the above copyright
9 *    notice, this list of conditions and the following disclaimer.
10 * 2. Redistributions in binary form must reproduce the above copyright
11 *    notice, this list of conditions and the following disclaimer in the
12 *    documentation and/or other materials provided with the distribution.
13 *
14 * THIS SOFTWARE IS PROVIDED BY THE AUTHOR AND CONTRIBUTORS ``AS IS'' AND
15 * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
16 * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
17 * ARE DISCLAIMED.  IN NO EVENT SHALL THE AUTHOR OR CONTRIBUTORS BE LIABLE
18 * FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
19 * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
20 * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
21 * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
22 * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
23 * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
24 * SUCH DAMAGE.
25 */
26
27#include <machine/asm.h>
28__FBSDID("$FreeBSD$");
29
30.syntax	unified
31
32ENTRY(strlen)
33	mov	r1, #0
34	/* Check that the pointer is aligned on 32 bits. */
35	ands	r3, r0, #3
36	beq	.Loop
37	sub	r0, r0, r3
38	ldr	r2, [r0]
39	add	r0, r0, #4
40	cmp	r3, #2
41	blt	.Ldo_3
42	bgt	.Ldo_1
43	/* So that the N bit is set. */
44	cmp	r3, #0
45	b	.Ldo_2
46
47.Loop:
48	ldr	r2, [r0]
49	add	r0, r0, #4
50#ifndef __ARMEB__
51	ands	r3, r2, #0x000000ff
52#else
53	ands	r3, r2, #0xff000000
54#endif
55	addne	r1, r1, #1
56.Ldo_3:
57#ifndef __ARMEB__
58	andsne    r3, r2, #0x0000ff00
59#else
60  	andsne    r3, r2, #0x00ff0000
61#endif
62	addne     r1, r1, #1
63.Ldo_2:
64#ifndef __ARMEB__
65	andsne    r3, r2, #0x00ff0000
66#else
67	andsne    r3, r2, #0x0000ff00
68#endif
69	addne	r1, r1, #1
70.Ldo_1:
71#ifndef __ARMEB__
72	andsne	r3, r2, #0xff000000
73#else
74	andsne	r3, r2, #0x000000ff
75#endif
76	addne	r1, r1, #1
77	bne	.Loop
78.Lexit:
79	mov	r0, r1
80	RET
81END(strlen)
82