1/*-
2 * Copyright (c) 1990 The Regents of the University of California.
3 * All rights reserved.
4 *
5 * This code is derived from software contributed to Berkeley by
6 * William Jolitz.
7 *
8 * Redistribution and use in source and binary forms, with or without

--- 19 unchanged lines hidden (view full) ---

28 * FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
29 * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
30 * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
31 * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
32 * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
33 * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
34 * SUCH DAMAGE.
35 *
36 * $Id: setjmp.S,v 1.4 1996/01/22 00:00:53 julian Exp $
37 */
38
39#if defined(LIBC_RCS) && !defined(lint)
40 .text
41 .asciz "$Id: setjmp.S,v 1.4 1996/01/22 00:00:53 julian Exp $"
42#endif /* LIBC_RCS and not lint */
43
44/*
45 * C library -- _setjmp, _longjmp
46 *
47 * longjmp(a,v)
48 * will generate a "return(v)" from the last call to
49 * setjmp(a)

--- 4 unchanged lines hidden (view full) ---

54#include "DEFS.h"
55#include "SYS.h"
56
57#ifdef _THREAD_SAFE
58ENTRY(_thread_sys_setjmp)
59#else
60ENTRY(setjmp)
61#endif
62 PIC_PROLOGUE
63 pushl $0
64#ifdef _THREAD_SAFE
65 call PIC_PLT(CNAME(_thread_sys_sigblock))
66#else
67 call PIC_PLT(CNAME(sigblock))
68#endif
69 popl %edx
70 PIC_EPILOGUE
71 movl 4(%esp),%ecx
72 movl 0(%esp),%edx
73 movl %edx, 0(%ecx)
74 movl %ebx, 4(%ecx)
75 movl %esp, 8(%ecx)
76 movl %ebp,12(%ecx)
77 movl %esi,16(%ecx)
78 movl %edi,20(%ecx)
79 movl %eax,24(%ecx)
80 fnstcw 28(%ecx)
81 xorl %eax,%eax
82 ret
83
84#ifdef _THREAD_SAFE
85ENTRY(_thread_sys_longjmp)
86#else
87ENTRY(longjmp)
88#endif
89 movl 4(%esp),%edx
90 PIC_PROLOGUE
91 pushl 24(%edx)
92#ifdef _THREAD_SAFE
93 call PIC_PLT(CNAME(_thread_sys_sigsetmask))
94#else
95 call PIC_PLT(CNAME(sigsetmask)) /* XXX this is not reentrant */
96#endif
97 popl %eax
98 PIC_EPILOGUE
99 movl 4(%esp),%edx
100 movl 8(%esp),%eax
101 movl 0(%edx),%ecx
102 movl 4(%edx),%ebx
103 movl 8(%edx),%esp
104 movl 12(%edx),%ebp
105 movl 16(%edx),%esi
106 movl 20(%edx),%edi
107 fninit
108 fldcw 28(%edx)
109 testl %eax,%eax
110 jnz 1f
111 incl %eax
1121: movl %ecx,0(%esp)
113 ret